R_SrvcOrdTmplPartnerAddressTP

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata:
{
  ignorePropagatedAnnotations: true
}
@EndUserText.label: 'Partner Address For Srvc Ord Tmpl - TP'
@ObjectModel: {
   usageType: {dataClass:      #TRANSACTIONAL,
                serviceQuality: #C,
                sizeCategory:   #L}
}
define view entity R_SrvcOrdTmplPartnerAddressTP
  as select from I_SrvcDocPartnerAddress as PartnerAddress
    inner join   I_ServiceDocument       as ServiceOrderTemplate on  PartnerAddress.ServiceDocument                   = ServiceOrderTemplate.ServiceDocument
                                                                 and PartnerAddress.ServiceDocumentItem               = '000000'
                                                                 and ServiceOrderTemplate.ServiceObjectType           = 'BUS2000116'
                                                                 and ServiceOrderTemplate.ServiceDocumentIsQuotation  is initial
                                                                 and ServiceOrderTemplate.ServiceDocumentTemplateType is not initial
                                                                 and ServiceOrderTemplate.SrvcDocIsMaintServiceOrder  is initial
  association        to parent R_SrvcOrdTmplPartnerTP as _SrvcOrdTmplPartnerTP   on  $projection.ServiceOrderTemplate    = _SrvcOrdTmplPartnerTP.ServiceOrderTemplate
                                                                                 and $projection.CustMgmtPartnerFunction = _SrvcOrdTmplPartnerTP.CustMgmtPartnerFunction
                                                                                 and $projection.CustMgmtBusinessPartner = _SrvcOrdTmplPartnerTP.CustMgmtBusinessPartner
  association [0..1] to R_ServiceOrderTemplateTP      as _ServiceOrderTemplateTP on  $projection.ServiceOrderTemplate = _ServiceOrderTemplateTP.ServiceOrderTemplate

{
      @ObjectModel.foreignKey.association: '_ServiceOrderTemplateTP'
  key PartnerAddress.ServiceDocument as ServiceOrderTemplate,
  key PartnerAddress.CustMgmtPartnerFunction,
  key PartnerAddress.CustMgmtBusinessPartner,
      PartnerAddress.CityName,
      PartnerAddress.CorrespondenceLanguage,
      PartnerAddress.Country,
      PartnerAddress.DistrictName,
      PartnerAddress.EmailAddress,
      PartnerAddress.FaxAreaCodeSubscriberNumber,
      PartnerAddress.FaxExtensionNumber,
      PartnerAddress.FaxNumberCountry,
      PartnerAddress.FormOfAddress,
      PartnerAddress.HouseNumber,
      PartnerAddress.MobileNumber,
      PartnerAddress.MobilePhoneCountry,
      PartnerAddress.OrganizationName1,
      PartnerAddress.OrganizationName2,
      PartnerAddress.OrganizationName3,
      PartnerAddress.OrganizationName4,
      PartnerAddress.PersonFamilyName,
      PartnerAddress.PersonGivenName,
      PartnerAddress.PhoneExtensionNumber,
      PartnerAddress.PhoneNumber,
      //      PhoneNumberCountry,

      PartnerAddress.POBox,
      PartnerAddress.POBoxPostalCode,
      PartnerAddress.PostalCode,
      PartnerAddress.Region,
      PartnerAddress.StreetName,
      PartnerAddress.StreetPrefixName1,
      PartnerAddress.StreetPrefixName2,
      PartnerAddress.StreetSuffixName1,
      PartnerAddress.StreetSuffixName2,
      PartnerAddress.TaxJurisdiction,
      PartnerAddress.TransportZone,

      //Associations

      _SrvcOrdTmplPartnerTP,
      _ServiceOrderTemplateTP
}
where
  PartnerAddress.ServiceDocumentItem is initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENT",
"I_SRVCDOCPARTNERADDRESS"
],
"ASSOCIATED":
[
"R_SERVICEORDERTEMPLATETP",
"R_SRVCORDTMPLPARTNERTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/