R_ServiceOrderTemplateTP

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata:
{
  ignorePropagatedAnnotations: true
}

@EndUserText.label: 'Service Order Template - TP'
@ObjectModel: {
  sapObjectNodeType.name: 'ServiceOrderTemplate',
  semanticKey: ['ServiceOrderTemplate'],
  representativeKey: 'ServiceOrderTemplate',
   usageType: {dataClass:      #TRANSACTIONAL,
                serviceQuality: #C,
                sizeCategory:   #L}
}
define root view entity R_ServiceOrderTemplateTP
  as select from I_ServiceDocumentEnhcd
  composition [0..*] of R_ServiceOrderTemplateItemTP as _ServiceOrderTemplateItemTP
  composition [0..*] of R_SrvcOrdTmplRefObjectTP     as _SrvcOrdTmplReferenceObjectTP
  composition [0..*] of R_SrvcOrdTmplUserStatusTP    as _SrvcOrdTmplUserStatusTP
  composition [0..*] of R_SrvcOrdTmplPartnerTP       as _SrvcOrdTmplPartnerTP
  composition [0..*] of R_SrvcOrdTmplLongTextTP      as _SrvcOrdTmplLongTextTP
  composition [0..*] of R_SrvcOrdTmplAppointmentTP   as _SrvcOrdTmplAppointmentTP
  composition [0..*] of R_SrvcOrdTmplDurationTP      as _SrvcOrdTmplDurationTP
   //! Extensibility support

  association [0..1] to E_ServiceDocument           as _Extension             on  $projection.ServiceObjectType = _Extension.ServiceCategory
                                                                              and $projection.ServiceOrderTemplate      = _Extension.ServiceOrder
  association [0..1] to I_StatusObjectUUIDStatus     as _SrvcOrdTmplStatus on  $projection.ServiceOrderTemplateUUID = _SrvcOrdTmplStatus.StatusObjectUUID
                                                                           and (
                                                                              _SrvcOrdTmplStatus.StatusCode         = 'I1002'
                                                                              or _SrvcOrdTmplStatus.StatusCode      = 'I1003'
                                                                              or _SrvcOrdTmplStatus.StatusCode      = 'I1004'
                                                                              or _SrvcOrdTmplStatus.StatusCode      = 'I1005'
                                                                            )
                                                                           and _SrvcOrdTmplStatus.StatusIsActive    = 'X'
{

  key ServiceDocument                            as ServiceOrderTemplate,
      @ObjectModel.foreignKey.association: '_ServiceObjType'
      ServiceObjectType,
      @ObjectModel.foreignKey.association: '_ServiceDocumentType'
      ServiceDocumentType                        as ServiceOrderTemplateType,
      ServiceDocumentUUID                        as ServiceOrderTemplateUUID,
      ServiceDocumentDescription                 as SrvcOrdTmplDescription,
      @ObjectModel.foreignKey.association: '_ServiceDocumentPriority'
      ServiceDocumentPriority,
      SrvcDocTmplValdtyStartDateTime,
      SrvcDocTmplValdtyEndDateTime,
      @Feature: 'BF:API_FULLSCOPE'
      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit_2'
      SalesGroupOrgUnitID,
      @Feature: 'BF:API_FULLSCOPE'
      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit_2'
      SalesOfficeOrgUnitID,
      @Feature: 'BF:API_FULLSCOPE'
      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit_2'
      SalesOrganizationOrgUnitID,
      @Feature: 'BF:API_FULLSCOPE'
      @ObjectModel.foreignKey.association: '_SalesGroup'
      SalesGroup,
      @ObjectModel.foreignKey.association: '_SalesOffice'
      SalesOffice,
      @ObjectModel.foreignKey.association: '_Division'
      Division,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrganization,
      ServiceDocCreationDateTime,
      ServiceDocChangedDateTime,
      ServiceDocumentCreatedByUser,
      ServiceDocumentChangedByUser,
      @Feature: 'BF:API_FULLSCOPE'
      @ObjectModel.sapObjectNodeTypeReference: 'EnterpriseServiceOrganization'
      EnterpriseServiceOrganization,
      ServiceDocumentTemplateType,
      SrvcDocTemplateSearchTermText,
      Language,
      // Status

      cast( case _SrvcOrdTmplStatus.StatusCode
      when 'I1002' then 'X'
      else ' '
      end       as   xfeld preserving type     ) as SrvcOrdTmplIsNew,
      cast( case _SrvcOrdTmplStatus.StatusCode
      when 'I1003' then 'X'
      else ' '
      end      as   xfeld preserving type     )  as SrvcOrdTmplIsInProcess,
      cast( case _SrvcOrdTmplStatus.StatusCode
      when 'I1004' then 'X'
      else ' '
      end      as   xfeld preserving type     )  as SrvcOrdTmplIsReleased,
      cast( case _SrvcOrdTmplStatus.StatusCode
      when 'I1005' then 'X'
      else ' '
      end     as   xfeld preserving type     )   as SrvcOrdTmplIsCompleted,
      // Associations

      _ServiceObjType,
      _ServiceDocumentType,
      _ServiceDocumentPriority,
      _SalesOrganizationOrgUnit_2,
      _SalesGroupOrgUnit_2,
      _SalesOfficeOrgUnit_2,
      _DistributionChannel,
      _Division,
      _SalesOffice,
      _SalesGroup,
      _SalesOrganization,
      _ServiceOrderTemplateItemTP,
      _SrvcOrdTmplReferenceObjectTP,
      _SrvcOrdTmplStatus,
      _SrvcOrdTmplUserStatusTP,
      _SrvcOrdTmplPartnerTP,
      _SrvcOrdTmplLongTextTP,
      _SrvcOrdTmplAppointmentTP,
      _SrvcOrdTmplDurationTP

}
where

      ServiceObjectType           = 'BUS2000116'
  and ServiceDocumentIsQuotation  is initial
  and ServiceDocumentTemplateType is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENTENHCD",
"I_STATUSOBJECTUUIDSTATUS"
],
"ASSOCIATED":
[
"I_CUSTMGMTBUSOBJTYPE",
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_SALESGROUP",
"I_SALESOFFICE",
"I_SALESORGANIZATION",
"I_SERVICEDOCUMENTPRIORITY",
"I_SERVICEDOCUMENTTYPE",
"I_SRVCMGMTORGANIZATIONUNIT",
"I_STATUSOBJECTUUIDSTATUS",
"R_SERVICEORDERTEMPLATEITEMTP",
"R_SRVCORDTMPLAPPOINTMENTTP",
"R_SRVCORDTMPLDURATIONTP",
"R_SRVCORDTMPLLONGTEXTTP",
"R_SRVCORDTMPLPARTNERTP",
"R_SRVCORDTMPLREFOBJECTTP",
"R_SRVCORDTMPLUSERSTATUSTP"
],
"BASE":
[
"I_SERVICEDOCUMENTENHCD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/