R_ServiceContractItemTP

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata:
{
  ignorePropagatedAnnotations: true
}
@EndUserText.label: 'Service Contract Item - TP'
@ObjectModel: {
  semanticKey: ['ServiceContractItem'],
  representativeKey: 'ServiceContractItem',
  usageType: {dataClass:      #TRANSACTIONAL,
              serviceQuality: #C,
              sizeCategory:   #L}
}
define view entity R_ServiceContractItemTP
  as select from I_ServiceDocumentItemEnhcd

  association        to parent R_ServiceContractTP    as _ServiceContractTP          on  $projection.ServiceContract = _ServiceContractTP.ServiceContract

  association [0..1] to I_StatusObjectUUIDStatus      as _SrvcOrdItmStatus           on  $projection.ServiceContractItemUUID = _SrvcOrdItmStatus.StatusObjectUUID
                                                                                     and (
                                                                                        _SrvcOrdItmStatus.StatusCode         = 'I1002'
                                                                                        or _SrvcOrdItmStatus.StatusCode      = 'I1003'
                                                                                        or _SrvcOrdItmStatus.StatusCode      = 'I1004'
                                                                                        or _SrvcOrdItmStatus.StatusCode      = 'I1005'
                                                                                      )
                                                                                     and _SrvcOrdItmStatus.StatusIsActive    = 'X'

  association [0..1] to I_CustMgmtExtRefID            as _ExtRefServiceContract      on  _ExtRefServiceContract.CustMgmtObjectType   = 'BUS2000112'
                                                                                     and $projection.ServiceContract                 = _ExtRefServiceContract.CustMgmtDocument
                                                                                     and _ExtRefServiceContract.CustMgmtExtRefIDType = '0003'

  association [0..1] to I_CustMgmtExtRefID            as _ExtRefServiceContractItem  on  _ExtRefServiceContractItem.CustMgmtObjectType   = 'BUS2000112'
                                                                                     and $projection.ServiceContract                     = _ExtRefServiceContractItem.CustMgmtDocument
                                                                                     and $projection.ServiceContractItem                 = _ExtRefServiceContractItem.CustMgmtDocumentItem
                                                                                     and _ExtRefServiceContractItem.CustMgmtExtRefIDType = '0004'

  association [0..1] to I_CustMgmtExtRefID            as _ExtRefServiceQtan          on  _ExtRefServiceQtan.CustMgmtObjectType   = 'BUS2000112'
                                                                                     and $projection.ServiceContract             = _ExtRefServiceQtan.CustMgmtDocument
                                                                                     and _ExtRefServiceQtan.CustMgmtExtRefIDType = '0009'

  association [0..1] to I_CustMgmtExtRefID            as _ExtRefServiceQtanItem      on  _ExtRefServiceQtanItem.CustMgmtObjectType   = 'BUS2000112'
                                                                                     and $projection.ServiceContract                 = _ExtRefServiceQtanItem.CustMgmtDocument
                                                                                     and $projection.ServiceContractItem             = _ExtRefServiceQtanItem.CustMgmtDocumentItem
                                                                                     and _ExtRefServiceQtanItem.CustMgmtExtRefIDType = '0010'
  
  association [0..1] to I_CustMgmtExtRefID            as _ExtRefLegalContract        on  _ExtRefLegalContract.CustMgmtObjectType   = 'BUS2000112'                                                                                     
                                                                                     and $projection.ServiceContract               = _ExtRefLegalContract.CustMgmtDocument                                                                                     
                                                                                     and _ExtRefLegalContract.CustMgmtExtRefIDType = '0021'
  
  association [0..1] to I_CustMgmtExtRefID            as _ExtRefLegalContractItem      on  _ExtRefLegalContractItem.CustMgmtObjectType   = 'BUS2000112'  
                                                                                     and $projection.ServiceContract                     = _ExtRefLegalContractItem.CustMgmtDocument
                                                                                     and $projection.ServiceContractItem                 = _ExtRefLegalContractItem.CustMgmtDocumentItem
                                                                                     and _ExtRefLegalContractItem.CustMgmtExtRefIDType   = '0022'

  association [0..1] to R_SrvcDocItemDocumentFlow     as _RefServiceTemplate         on  $projection.ServiceContract                     = _RefServiceTemplate.ServiceDocument
                                                                                     and $projection.ServiceContractItem                 = _RefServiceTemplate.ServiceDocumentItem
                                                                                     and _RefServiceTemplate.PrdcssrSuccssrDocObjectType = 'BUS2000112'
                                                                                     and _RefServiceTemplate.ServiceDocumentTemplateType is not initial
                                                                                     and _RefServiceTemplate.ServiceObjectType           = 'BUS2000112'

  association [0..1] to I_CustMgmtDateRule            as _SettlementPeriodRule       on  $projection.SettlementPeriodRuleUUID = _SettlementPeriodRule.CustMgmtDateRuleUUID

  association [0..1] to I_CustMgmtDateRule            as _BillingPlanBillingDateRule on  $projection.BillingPlanBillingDateRuleUUID = _BillingPlanBillingDateRule.CustMgmtDateRuleUUID

  // association [0..1] to I_ServiceDocumentItemEnhcd     as _ChgProcSourceItem        on  $projection.SrvcTransChgProcSourceItemUUID = _ChgProcSourceItem.ServiceDocumentItemUUID


  composition [0..*] of R_SrvcContrItemPartnerTP      as _SrvcContrItmPartnerTP
  composition [0..*] of R_SrvcContrItemPriceElementTP as _SrvcContrItmPriceElementTP
  composition [0..*] of R_SrvcContrItemUserStatusTP   as _SrvcContrItemUserStatusTP
  composition [0..*] of R_SrvcContrItmFUPBillgDocTP   as _SrvcContrItmFUPBillgDocTP
  composition [0..*] of R_SrvcContrItmFUPSrvcOrdTP    as _SrvcContrItmFUPSrvcOrdTP
  composition [0..*] of R_SrvcContrItemRefObjectTP    as _SrvcContrItemRefObjectTP
  composition [0..*] of R_SrvcContrItemProductTP      as _SrvcContrItemProductTP
  composition [0..*] of R_SrvcContrItmBillgReqItemTP  as _SrvcContrItmBillgReqItemTP
  composition [0..*] of R_SrvcContrItemDurationTP     as _SrvcContrItemDurationTP
  composition [0..*] of R_SrvcContrItemAppointmentTP  as _SrvcContrItemAppointmentTP
  composition [0..*] of R_SrvcContrItemLongTextTP     as _SrvcContrItemLongTextTP


  //  association [1..1] to R_ServiceContractTP           as _ServiceContract             on  _ServiceContract.ServiceObjectType = 'BUS2000112'

  //                                                                                      and $projection.ServiceContract         = _ServiceContract.ServiceContract


  association [0..1] to I_WBSElementBasicData         as _WBSElement                 on  _WBSElement.WBSElementInternalID = I_ServiceDocumentItemEnhcd.WBSElementInternalID

  association [0..1] to E_ServiceDocumentItem         as _Extension                  on  $projection.ServiceObjectType   = _Extension.ServiceCategory
                                                                                     and $projection.ServiceContract     = _Extension.ServiceOrderItem
                                                                                     and $projection.ServiceContractItem = _Extension.ServiceLineExternalID
{

      // Administrative fields

      @ObjectModel.foreignKey.association: '_ServiceDocument'
  key ServiceDocument                                                                as ServiceContract,
  key cast(ServiceDocumentItem as crms4_number_int preserving type)                  as ServiceContractItem,
      @ObjectModel.foreignKey.association: '_ServiceObjType'
      ServiceObjectType,
      _ParentServiceDocItem_2.ServiceDocumentItem                                    as ParentServiceContractItem,
      ServiceDocItemCategory                                                         as ServiceContractItemCategory,
      ServiceDocumentItemUUID                                                        as ServiceContractItemUUID,
      ServiceDocumentItemDescription                                                 as ServiceContractItemDescription,
      Language,
      ServiceDocItemCreationDateTime,
      ServiceDocItemChangedDateTime,
      ServiceDocItemCreatedByUser,
      ServiceDocItemChangedByUser,


      // Item Fields

      @ObjectModel.foreignKey.association: '_Product'
      Product,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      ServiceDocumentItemQuantity                                                    as Quantity,
      ServiceDocItemQuantityUnit                                                     as QuantityUnit,

      // Partners

      SoldToParty,
      ShipToParty,
      BillToParty,
      PayerParty,
      @ObjectModel.foreignKey.association: '_ContactPerson'
      ContactPerson                                                                  as ContactPersonBusinessPartnerId,
      @ObjectModel.foreignKey.association: '_RespEmployee'
      ResponsibleEmployee                                                            as RespEmployeeBusinessPartnerId,

      // Billing Relevant Fields

      @ObjectModel.foreignKey.association: '_PaymentTerms'
      PaymentTerms,
      PaymentMethod,
      SEPAMandate,
      @ObjectModel.foreignKey.association: '_SrvcSEPAMandateRelevance'
      SrvcSEPAMandateRelevance,

      // Organizational Data

      //RespyMgmtServiceTeam,

      //_ServiceTeamHeader.RespyMgmtGlobalTeamID                                             as RespyMgmtGlobalTeamID,

      SalesOrganization,
      DistributionChannel,
      Division,
      SalesOffice,
      SalesGroup,

      // Status

      cast( case _SrvcOrdItmStatus.StatusCode
      when 'I1002' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                          as ServiceContractItemIsNew,
      cast( case _SrvcOrdItmStatus.StatusCode
      when 'I1003' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                          as ServiceContractItemIsInProcess,
      cast( case _SrvcOrdItmStatus.StatusCode
      when 'I1004' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                          as ServiceContractItemIsReleased,
      cast( case _SrvcOrdItmStatus.StatusCode
      when 'I1005' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                          as ServiceContractItemIsCompleted,
      ServiceDocumentItemStatus                                                      as ServiceContractItemStatus,
      ServiceDocItemBillingStatus                                                    as ServiceContrItemBillingStatus,
      @Semantics.booleanIndicator
      ServiceDocumentItemIsRejected                                                  as ServiceContractItemIsRejected,
      @Semantics.booleanIndicator
      ServiceDocumentItemHasError                                                    as ServiceContractItemHasError,
      SrvcDocItemTransferStatus,
      SrvcDocItemCreditStatus                                                        as SrvcContrItemCreditStatus,

      // Dates and Durations

      @Semantics.dateTime:true
      ServiceContrItemStartDateTime,
      @Semantics.dateTime:true
      ServiceContrItemEndDateTime,
      @Semantics: { quantity : {unitOfMeasure: 'SrvcContrItemRnwlDurationUnit'} }
      SrvcContrItemRnwlDuration                                                      as SrvcContrItemRnwlDuration,
      SrvcContrItemRnwlDurationUnit                                                  as SrvcContrItemRnwlDurationUnit,
      @Semantics: { quantity : {unitOfMeasure: 'SrvcContrItemExtnDurationUnit'} }
      SrvcContrItemExtensionDuration                                                 as SrvcContrItemExtensionDuration,
      SrvcContrItemExtnDurationUnit                                                  as SrvcContrItemExtnDurationUnit,

      ResponseProfile,
      ServiceProfile,

      ProfitCenter,

      // Pricing

      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocItemGrossAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocumentItemNetAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocumentItemTaxAmount,
      TransactionCurrency,

      //Cancellation

      ServiceDocumentItemCanclnParty                                                 as ServiceContractItemCanclnParty,
      ServiceDocumentItmCanclnReason                                                 as ServiceContractItmCanclnReason,
      cast( case ServiceDocumentItemCanclnParty
      when '' then 0
      else ServiceContrItemEndDateTime
      end as timestamp preserving type     )                                         as SrvcContrItemCanclnDateTime,

      // Item - Billing Plan

      SettlementPeriodRuleUUID,
      _SettlementPeriodRule.CustMgmtDateRuleName                                     as SettlementPeriodRule,
      BillingPlanBillingDateRuleUUID,
      _BillingPlanBillingDateRule.CustMgmtDateRuleName                               as SrvcMgmtBillgPlanBillgDateRule,
      BillingBlockReason,
      BillingPlanPriceDateRule,
      BillingPlanIsFinalized,
      ContractAccount,

      // Reference Documents

      _ExtRefServiceContract.CustMgmtExtRefID                                        as SrvcContrExternalReference,
      _ExtRefServiceContractItem.CustMgmtExtRefID                                    as SrvcContrItmExternalReference,

      _ExtRefServiceQtan.CustMgmtExtRefID                                            as ServiceQtanExtReference,
      _ExtRefServiceQtanItem.CustMgmtExtRefID                                        as ServiceQtanItemExtReference,
      
      _ExtRefLegalContract.CustMgmtExtRefID                                          as LegalContractExtReference,
      _ExtRefLegalContractItem.CustMgmtExtRefID                                      as LegalContractItemExtReference,
      
      cast( _RefServiceTemplate.CustMgmtPrdcssrTransactionKey as crmt_object_id_db ) as RefServiceContractTemplate,
      cast( _RefServiceTemplate.BusinessTransactionDocItem as crms4_number_int )     as RefServiceContractTemplateItem,

      //Inheritance of Complex set in RAP

      SrvcDocItmPartReferenceItem, //For Item Partner

      SrvcDocItmApptRefObjectUUID, //For Item Appointment UUID

      //SrvcDocItmApptReferenceItem,//For Appointment and Duration


      _WBSElement.WBSElementExternalID,

      //Associations

      _ServiceDocument,
      //      _ServiceContract,

      _ServiceContractTP,
      _SrvcContrItmPartnerTP,
      _SrvcContrItmPriceElementTP,
      _SrvcContrItemUserStatusTP,

      _ServiceObjType,


      _ExtRefServiceContract,
      _ExtRefServiceContractItem,


      _Product,
      _ContactPerson,
      _RespEmployee,
      _PaymentTerms,
      _SrvcSEPAMandateRelevance,
      _SrvcContrItmFUPBillgDocTP,
      _SrvcContrItmFUPSrvcOrdTP,
      _SrvcContrItemRefObjectTP,
      _SrvcContrItemProductTP,
      _SrvcContrItmBillgReqItemTP,
      _SrvcContrItemDurationTP,
      _SrvcContrItemAppointmentTP,
      _SrvcContrItemLongTextTP,
      _BaseUnit,
      _SrvcContrItemExtnDurationUnit,
      _SrvcContrItemRnwlDurationUnit

}
where
  ServiceObjectType = 'BUS2000112' //Service Contract

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTMGMTDATERULE",
"I_CUSTMGMTEXTREFID",
"I_SERVICEDOCUMENTITEMENHCD",
"I_STATUSOBJECTUUIDSTATUS",
"I_WBSELEMENTBASICDATA",
"R_SRVCDOCITEMDOCUMENTFLOW"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CUSTMGMTBUSOBJTYPE",
"I_CUSTMGMTEXTREFID",
"I_PAYMENTTERMS",
"I_PRODUCT",
"I_SERVICEDOCUMENTENHCD",
"I_SRVCSEPAMANDATERELEVANCE",
"I_UNITOFMEASURE",
"R_SERVICECONTRACTTP",
"R_SRVCCONTRITEMAPPOINTMENTTP",
"R_SRVCCONTRITEMDURATIONTP",
"R_SRVCCONTRITEMLONGTEXTTP",
"R_SRVCCONTRITEMPARTNERTP",
"R_SRVCCONTRITEMPRICEELEMENTTP",
"R_SRVCCONTRITEMPRODUCTTP",
"R_SRVCCONTRITEMREFOBJECTTP",
"R_SRVCCONTRITEMUSERSTATUSTP",
"R_SRVCCONTRITMBILLGREQITEMTP",
"R_SRVCCONTRITMFUPBILLGDOCTP",
"R_SRVCCONTRITMFUPSRVCORDTP"
],
"BASE":
[
"I_SERVICEDOCUMENTITEMENHCD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/