R_SrvcContrItemLongTextTP

@EndUserText.label: 'Service Contract Item Long Text - TP'
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@Metadata: {
  ignorePropagatedAnnotations: true
}

@ObjectModel: {
   dataCategory: #TEXT,
   usageType: {dataClass:      #TRANSACTIONAL,
                serviceQuality: #C,
                sizeCategory:   #L}
}

define view entity R_SrvcContrItemLongTextTP
  as select from I_ServiceDocumentLongText as ServiceItemText
    inner join   I_ServiceDocumentItem     as ServiceContractItem on  ServiceItemText.ServiceDocument                 = ServiceContractItem.ServiceDocument
                                                               and ServiceItemText.ServiceDocumentItem                = ServiceContractItem.ServiceDocumentItem
                                                               and ServiceItemText.TextObjectCategory                 = 'CRM_ORDERI'
                                                               and ServiceContractItem.ServiceObjectType              = 'BUS2000112'
                                                               and ServiceContractItem.ServiceDocumentItemIsQuotation is initial
                                                               and ServiceContractItem.ServiceDocumentTemplateType    is initial
  association to parent R_ServiceContractItemTP as _ServiceContractItemTP on  $projection.ServiceContract     = _ServiceContractItemTP.ServiceContract
                                                                          and $projection.ServiceContractItem = _ServiceContractItemTP.ServiceContractItem
  association [1..1] to R_ServiceContractTP     as _ServiceContractTP     on  $projection.ServiceContract = _ServiceContractTP.ServiceContract

{
  key ServiceContractItem.ServiceDocument        as ServiceContract,
  key ServiceContractItem.ServiceDocumentItem    as ServiceContractItem,
  key ServiceItemText.TextObjectType,
      @Semantics.language:true
  key ServiceItemText.Language,
  key ServiceItemText.SrvcDocLogTextIdentifier,
      ServiceItemText.ServiceDocumentLongTextUUID,


      // ServiceOrderItem.ServiceObjectType,


      ServiceItemText.TextObjectCategory,


      ServiceItemText.SrvcDocLongTextMimeType,
      @Semantics.text:true
      ServiceItemText.ServiceDocumentLongText as SrvcContrItemLongText,

      ServiceItemText.ReferenceTextObjectCategory,
      ServiceItemText.ReferenceTextObjectType,
      ServiceItemText.ReferenceLongTextKey,
      ServiceItemText.ReferenceServiceObjectType,
      ServiceItemText.ReferenceServiceDocument,
      ServiceItemText.ReferenceServiceDocumentItem,

      ServiceItemText.SrvcDocLongTxtCreationDateTime,
      ServiceItemText.SrvcDocLongTextCreatedByUser,
      ServiceItemText.SrvcDocLongTextChangedDateTime,
      ServiceItemText.SrvcDocLongTextChangedByUser,

      /* Associations */
      ServiceItemText._Language,
      ServiceItemText._ReferenceTextObjectCategory,
      ServiceItemText._ReferenceTextObjectType,
      ServiceItemText._TextObjectCategory,
      ServiceItemText._TextObjectType,
      
      _ServiceContractItemTP,
      _ServiceContractTP
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENTITEM",
"I_SERVICEDOCUMENTLONGTEXT"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_TEXTOBJECTCATEGORY",
"I_TEXTOBJECTTYPE",
"R_SERVICECONTRACTITEMTP",
"R_SERVICECONTRACTTP"
],
"BASE":
[
"I_SERVICEDOCUMENTLONGTEXT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/