@VDM: {
lifecycle.contract.type: #SAP_INTERNAL_API,
viewType: #TRANSACTIONAL
}
@ObjectModel: {
usageType: {
dataClass: #TRANSACTIONAL,
serviceQuality: #C,
sizeCategory: #L
},
semanticKey: ['SalesOrder', 'SalesOrderItem']
}
@AbapCatalog.extensibility: {
extensible: true,
dataSources: ['_Extension'],
elementSuffix: 'SDI',
quota: {
maximumFields: 204, //This is calculated with formula - 2* <Customer Percentage from SCFD_REGISTRY> * <max number of fields in SCFD_REGISTRY>
maximumBytes: 100000 //Set to maximum allowed bytes
}
}
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Sales Order Item - TP'
define view entity R_SalesOrderItemTP
as select from I_SalesOrderItem as SalesOrderItem
composition [0..*] of R_SalesOrderItemPartnerTP as _ItemPartner
composition [0..*] of R_SalesOrderItemTextTP as _ItemText
composition [0..*] of R_SalesOrderItemPrcgElmntTP as _ItemPricingElement
composition [0..1] of R_SalesOrderItemBillingPlanTP as _ItemBillingPlan
composition [0..*] of R_SalesOrderScheduleLineTP as _ScheduleLine
association [0..1] to R_VariantConfigurationTP as _VariantConfiguration on $projection.ProductConfiguration = _VariantConfiguration.VarConfigurationRootInstance
and _VariantConfiguration.VarConfigurationBusObjectType = 'VBPS'
and $projection.VarConfigurationBusObjectKey = _VariantConfiguration.VarConfigurationBusObjectKey
association to parent R_SalesOrderTP as _SalesOrder on $projection.SalesOrder = _SalesOrder.SalesOrder
association [0..1] to I_SlsDocItemEnhancedFields as _ItemEnhancedFields on $projection.SalesOrder = _ItemEnhancedFields.SalesDocument
and $projection.SalesOrderItem = _ItemEnhancedFields.SalesDocumentItem
association [0..1] to I_Batch as _Batch on $projection.Plant = _Batch.Plant
and $projection.Product = _Batch.Material
and $projection.Batch = _Batch.Batch
association [0..1] to I_ProductPricingGroup as _ProductPricingGroup on $projection.MaterialPricingGroup = _ProductPricingGroup.ProductPricingGroup
association [0..1] to I_ControllingArea as _ControllingArea on $projection.ControllingArea = _ControllingArea.ControllingArea
association [0..1] to I_SalesDocumentItemCategory as _HigherLevelItemCategory on $projection.HigherLevelItemCategory = _HigherLevelItemCategory.SalesDocumentItemCategory
association [0..1] to I_WBSElementByExternalID as _WBSElementExternalID on $projection.WBSElementExternalID = _WBSElementExternalID.WBSElementExternalID
//Extension Association
association [1] to E_SalesDocumentItemBasic as _Extension on $projection.SalesOrder = _Extension.SalesDocument
and $projection.SalesOrderItem = _Extension.SalesDocumentItem
{
key SalesOrderItem.SalesOrder,
key SalesOrderItem.SalesOrderItem,
SalesOrderItem.HigherLevelItem,
@ObjectModel.foreignKey.association: '_ItemCategory'
SalesOrderItem.SalesOrderItemCategory,
@Semantics.text: true
SalesOrderItem.SalesOrderItemText,
@ObjectModel.foreignKey.association: '_Product'
SalesOrderItem.Product,
@ObjectModel.foreignKey.association: '_ProductGroup'
SalesOrderItem.ProductGroup,
SalesOrderItem.MaterialByCustomer,
SalesOrderItem.InternationalArticleNumber,
SalesOrderItem.PurchaseOrderByCustomer,
_ItemEnhancedFields._RequestedDeliveryDate.RequestedDeliveryDate,
_ItemEnhancedFields._ConfirmedDeliveryDate.ConfirmedDeliveryDate,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
SalesOrderItem.ConfdDelivQtyInOrderQtyUnit,
@ObjectModel.foreignKey.association: '_OrderQuantityUnit'
SalesOrderItem.OrderQuantityUnit,
@Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
@Semantics.valueRange.minimum: '0'
SalesOrderItem.RequestedQuantity,
@ObjectModel.foreignKey.association: '_RequestedQuantityUnit'
SalesOrderItem.RequestedQuantityUnit,
@Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
SalesOrderItem.ItemGrossWeight,
@Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
SalesOrderItem.ItemNetWeight,
@ObjectModel.foreignKey.association: '_ItemWeightUnit'
SalesOrderItem.ItemWeightUnit,
@Semantics.quantity.unitOfMeasure: 'ItemVolumeUnit'
SalesOrderItem.ItemVolume,
@ObjectModel.foreignKey.association: '_ItemVolumeUnit'
SalesOrderItem.ItemVolumeUnit,
SalesOrderItem.PricingDate,
SalesOrderItem.ServicesRenderedDate,
SalesOrderItem.BillingDocumentDate,
SalesOrderItem.FixedValueDate,
@ObjectModel.foreignKey.association: '_CustomerGroup'
SalesOrderItem.CustomerGroup,
@ObjectModel.foreignKey.association: '_Batch'
SalesOrderItem.Batch,
@ObjectModel.foreignKey.association: '_Plant'
SalesOrderItem.Plant,
@ObjectModel.foreignKey.association: '_StorageLocation'
SalesOrderItem.StorageLocation,
@ObjectModel.foreignKey.association: '_ShippingPoint'
SalesOrderItem.ShippingPoint,
@ObjectModel.foreignKey.association: '_ShippingType'
SalesOrderItem.ShippingType,
@ObjectModel.foreignKey.association: '_Route'
SalesOrderItem.Route,
@ObjectModel.foreignKey.association: '_DeliveryPriority'
SalesOrderItem.DeliveryPriority,
@ObjectModel.foreignKey.association: '_PartialDeliveryItem'
SalesOrderItem.PartialDeliveryIsAllowed,
@Semantics.valueRange.minimum: '0'
SalesOrderItem.MaxNmbrOfPartialDelivery,
SalesOrderItem.DeliveryDateQuantityIsFixed,
@ObjectModel.foreignKey.association: '_DeliveryDateTypeRule'
SalesOrderItem.DeliveryDateTypeRule,
SalesOrderItem.ReceivingPoint,
@Semantics.valueRange.minimum: '0'
SalesOrderItem.DeliveryGroup,
SalesOrderItem.ProductConfiguration,
case when SalesOrderItem.ProductConfiguration is not initial
then
cast ( concat(SalesOrderItem.SalesOrder, SalesOrderItem.SalesOrderItem) as ibobjkey )
end as VarConfigurationBusObjectKey,
@ObjectModel.foreignKey.association: '_IncotermsClassification'
SalesOrderItem.IncotermsClassification,
SalesOrderItem.IncotermsLocation1,
SalesOrderItem.IncotermsLocation2,
SalesOrderItem.OrderCombinationIsAllowed,
@ObjectModel.foreignKey.association: '_IncotermsVersion'
SalesOrderItem.IncotermsVersion,
@ObjectModel.foreignKey.association: '_CustomerPaymentTerms'
SalesOrderItem.CustomerPaymentTerms,
@ObjectModel.foreignKey.association: '_CustomerPriceGroup'
SalesOrderItem.CustomerPriceGroup,
@ObjectModel.foreignKey.association: '_ProductPricingGroup'
cast (MaterialPricingGroup as productpricinggroup preserving type ) as MaterialPricingGroup,
@ObjectModel.foreignKey.association: '_ItemBillingBlockReason'
SalesOrderItem.ItemBillingBlockReason,
@ObjectModel.foreignKey.association: '_SalesDocumentRjcnReason'
SalesOrderItem.SalesDocumentRjcnReason,
@ObjectModel.foreignKey.association: '_TransactionCurrency'
SalesOrderItem.TransactionCurrency,
@Semantics.amount.currencyCode: 'TransactionCurrency'
SalesOrderItem.NetAmount,
@Semantics.amount.currencyCode: 'TransactionCurrency'
SalesOrderItem.TaxAmount,
@ObjectModel.foreignKey.association: '_SDProcessStatus'
SalesOrderItem.SDProcessStatus,
@ObjectModel.foreignKey.association: '_SDDocumentRejectionStatus'
SalesOrderItem.SDDocumentRejectionStatus,
@ObjectModel.foreignKey.association: '_DeliveryStatus'
SalesOrderItem.DeliveryStatus,
@ObjectModel.foreignKey.association: '_BillingBlockStatus'
SalesOrderItem.BillingBlockStatus,
@ObjectModel.foreignKey.association: '_ItemGeneralIncompletionStatus'
SalesOrderItem.ItemGeneralIncompletionStatus,
@ObjectModel.foreignKey.association: '_DeliveryBlockStatus'
SalesOrderItem.DeliveryBlockStatus,
@ObjectModel.foreignKey.association: '_ItemDownPaymentStatus'
SalesOrderItem.SlsOrderItemDownPaymentStatus,
@ObjectModel.foreignKey.association: '_OrderRelatedBillingStatus'
SalesOrderItem.OrderRelatedBillingStatus,
@ObjectModel.foreignKey.association: '_ChmlCmplncStatus'
SalesOrderItem.ChmlCmplncStatus,
@ObjectModel.foreignKey.association: '_DangerousGoodsStatus'
SalesOrderItem.DangerousGoodsStatus,
@ObjectModel.foreignKey.association: '_SafetyDataSheetStatus'
SalesOrderItem.SafetyDataSheetStatus,
@ObjectModel.foreignKey.association: '_TrdCmplncEmbargoSts'
SalesOrderItem.TrdCmplncEmbargoSts,
@ObjectModel.foreignKey.association: '_TrdCmplncSnctndListChkSts'
SalesOrderItem.TrdCmplncSnctndListChkSts,
@ObjectModel.foreignKey.association: '_OvrlTrdCmplncLegalCtrlChkSts'
SalesOrderItem.OvrlTrdCmplncLegalCtrlChkSts,
@ObjectModel.foreignKey.association: '_BusinessArea'
SalesOrderItem.BusinessArea,
@ObjectModel.foreignKey.association: '_ProfitCenter'
SalesOrderItem.ProfitCenter,
@ObjectModel.foreignKey.association: '_ControllingArea'
SalesOrderItem.ControllingArea,
@ObjectModel.foreignKey.association: '_MatlAccountAssignmentGroup'
SalesOrderItem.MatlAccountAssignmentGroup,
SalesOrderItem.WBSElementInternalID,
@ObjectModel.foreignKey.association: '_WBSElementExternalID'
SalesOrderItem._WBSElementBasicData_2.WBSElementExternalID as WBSElementExternalID,
@ObjectModel.foreignKey.association: '_SDPricingProcedure'
SalesOrderItem._SalesOrder.SDPricingProcedure,
@ObjectModel.foreignKey.association: '_ItemCategoryGroup'
_ItemEnhancedFields.ItemCategoryGroup,
@ObjectModel.foreignKey.association: '_SDDocumentItemUsage'
_ItemEnhancedFields.SDDocumentItemUsage,
@ObjectModel.foreignKey.association: '_HigherLevelItemCategory'
SalesOrderItem._HigherLevelItem.SalesOrderItemCategory as HigherLevelItemCategory,
//Parent
_SalesOrder,
//Compositions
_ItemPartner,
_ItemText,
_ItemPricingElement,
_ItemBillingPlan,
_ScheduleLine,
_VariantConfiguration,
// For Access control
@Consumption.hidden: true
_SalesOrder.SalesOrderType,
@Consumption.hidden: true
_SalesOrder.OrganizationDivision,
@Consumption.hidden: true
_SalesOrder.SalesOrganization,
@Consumption.hidden: true
_SalesOrder.DistributionChannel,
//Associations
SalesOrderItem._HigherLevelItem,
SalesOrderItem._Product,
SalesOrderItem._ProductGroup,
SalesOrderItem._RequestedQuantityUnit,
SalesOrderItem._TransactionCurrency,
SalesOrderItem._ItemCategory,
SalesOrderItem._ShippingPoint,
SalesOrderItem._CustomerGroup,
SalesOrderItem._DeliveryPriority,
SalesOrderItem._ShippingType,
SalesOrderItem._Route,
SalesOrderItem._DeliveryDateTypeRule,
SalesOrderItem._ItemBillingBlockReason,
SalesOrderItem._SalesDocumentRjcnReason,
SalesOrderItem._IncotermsClassification,
SalesOrderItem._IncotermsVersion,
SalesOrderItem._BusinessArea,
SalesOrderItem._WBSElementBasicData_2,
@Consumption.filter.businessDate.at: true
SalesOrderItem._ProfitCenter,
SalesOrderItem._MatlAccountAssignmentGroup,
SalesOrderItem._CustomerPaymentTerms,
SalesOrderItem._CustomerPriceGroup,
SalesOrderItem._StorageLocation,
SalesOrderItem._Plant,
SalesOrderItem._PartialDeliveryItem,
SalesOrderItem._OrderQuantityUnit,
SalesOrderItem._ItemWeightUnit,
SalesOrderItem._ItemVolumeUnit,
SalesOrderItem._SDProcessStatus,
SalesOrderItem._SDDocumentRejectionStatus,
SalesOrderItem._DeliveryStatus,
SalesOrderItem._BillingBlockStatus,
SalesOrderItem._ItemGeneralIncompletionStatus,
SalesOrderItem._DeliveryBlockStatus,
SalesOrderItem._ChmlCmplncStatus,
SalesOrderItem._DangerousGoodsStatus,
SalesOrderItem._SafetyDataSheetStatus,
SalesOrderItem._OvrlTrdCmplncLegalCtrlChkSts,
SalesOrderItem._TrdCmplncSnctndListChkSts,
SalesOrderItem._TrdCmplncEmbargoSts,
SalesOrderItem._ItemDownPaymentStatus,
SalesOrderItem._OrderRelatedBillingStatus,
SalesOrderItem._SalesOrder._SDPricingProcedure,
_ItemEnhancedFields._ItemCategoryGroup,
_ItemEnhancedFields._SDDocumentItemUsage,
_ControllingArea,
_Batch,
_ProductPricingGroup,
_HigherLevelItemCategory,
_WBSElementExternalID
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESORDER",
"I_SALESORDERITEM",
"I_SLSDOCITEMCONFDELIVERYDATE",
"I_SLSDOCITEMENHANCEDFIELDS",
"I_SLSDOCITEMREQDDELIVERYDATE",
"I_WBSELEMENTBASICDATA",
"R_SALESORDERTP"
],
"ASSOCIATED":
[
"I_BATCH",
"I_BILLINGBLOCKREASON",
"I_BILLINGBLOCKSTATUS",
"I_BUSINESSAREA",
"I_CHMLCMPLNCSTATUS",
"I_CONTRACTDOWNPAYMENTSTATUS",
"I_CONTROLLINGAREA",
"I_CURRENCY",
"I_CUSTOMERGROUP",
"I_CUSTOMERMATERIALITEMUSAGE",
"I_CUSTOMERPAYMENTTERMS",
"I_CUSTOMERPRICEGROUP",
"I_DANGEROUSGOODSSTATUS",
"I_DELIVERYBLOCKSTATUS",
"I_DELIVERYDATETYPERULE",
"I_DELIVERYPRIORITY",
"I_DELIVERYSTATUS",
"I_INCOTERMSCLASSIFICATION",
"I_INCOTERMSVERSION",
"I_ITEMCATEGORYGROUP",
"I_ITEMGENINCOMPLETIONSTATUS",
"I_MATLACCOUNTASSIGNMENTGROUP",
"I_ORDERRELATEDBILLINGSTATUS",
"I_OVRLTRDCMPLNCLEGALCTRLCHKSTS",
"I_PARTIALDELIVERYITEM",
"I_PLANT",
"I_PRODUCT",
"I_PRODUCTGROUP_2",
"I_PRODUCTPRICINGGROUP",
"I_PROFITCENTER",
"I_ROUTE",
"I_SAFETYDATASHEETSTATUS",
"I_SALESDOCUMENTITEMCATEGORY",
"I_SALESDOCUMENTRJCNREASON",
"I_SALESORDERITEM",
"I_SDDOCUMENTREJECTIONSTATUS",
"I_SDPROCESSSTATUS",
"I_SHIPPINGPOINT",
"I_SHIPPINGTYPE",
"I_SLSPRICINGPROCEDURE",
"I_STORAGELOCATION",
"I_TRDCMPLNCCHECKSTATUS",
"I_UNITOFMEASURE",
"I_WBSELEMENTBASICDATA",
"I_WBSELEMENTBYEXTERNALID",
"R_SALESORDERITEMBILLINGPLANTP",
"R_SALESORDERITEMPARTNERTP",
"R_SALESORDERITEMPRCGELMNTTP",
"R_SALESORDERITEMTEXTTP",
"R_SALESORDERSCHEDULELINETP",
"R_SALESORDERTP",
"R_VARIANTCONFIGURATIONTP"
],
"BASE":
[
"I_SALESORDER",
"I_SALESORDERITEM",
"I_SLSDOCITEMENHANCEDFIELDS"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/