R_SalesOrderScheduleLineTP

DDL: R_SALESORDERSCHEDULELINETP Type: view_entity TRANSACTIONAL

Schedule Line for Sales Order Item - TP

R_SalesOrderScheduleLineTP is a Transactional CDS View that provides data about "Schedule Line for Sales Order Item - TP" in SAP S/4HANA. It reads from 1 data source (I_SalesOrderScheduleLine) and exposes 29 fields with key fields SalesOrder, SalesOrderItem, ScheduleLine. It has 1 association to related views.

1 data source(s) 29 fields

Data Sources (1)

SourceAliasJoin Type
I_SalesOrderScheduleLine SalesOrderScheduleLine from

Associations (1)

CardinalityTargetAliasCondition
[1..1] R_SalesOrderTP _SalesOrder $projection.SalesOrder = _SalesOrder.SalesOrder

Annotations (8)

NameValueLevelField
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #TRANSACTIONAL view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
Metadata.ignorePropagatedAnnotations true view
AccessControl.authorizationCheck #CHECK view
EndUserText.label Schedule Line for Sales Order Item - TP view

Fields (29)

KeyFieldSource TableSource FieldDescription
KEY SalesOrder I_SalesOrderScheduleLine SalesOrder
KEY SalesOrderItem I_SalesOrderScheduleLine SalesOrderItem
KEY ScheduleLine I_SalesOrderScheduleLine ScheduleLine
ScheduleLineForEdit I_SalesOrderScheduleLine ScheduleLine
ScheduleLineCategory I_SalesOrderScheduleLine ScheduleLineCategory
OrderQuantityUnit OrderQuantityUnit
OrderQuantitySAPUnit
ScheduleLineOrderQuantity ScheduleLineOrderQuantity
ConfdOrderQtyByMatlAvailCheck ConfdOrderQtyByMatlAvailCheck
DeliveredQtyInOrderQtyUnit DeliveredQtyInOrderQtyUnit
OpenConfdDelivQtyInOrdQtyUnit OpenConfdDelivQtyInOrdQtyUnit
CorrectedQtyInOrderQtyUnit CorrectedQtyInOrderQtyUnit
DeliveryDate DeliveryDate
RequestedDeliveryDate RequestedDeliveryDate
ConfirmedDeliveryDate ConfirmedDeliveryDate
DelivBlockReasonForSchedLine DelivBlockReasonForSchedLine
PurchaseRequisition PurchaseRequisition
PurchaseRequisitionItem PurchaseRequisitionItem
GoodsMovementType I_SalesOrderScheduleLine GoodsMovementType
_Item _Item
_SalesOrder _SalesOrder
SalesOrderType _SalesOrder SalesOrderType
OrganizationDivision _SalesOrder OrganizationDivision
SalesOrganization _SalesOrder SalesOrganization
DistributionChannel _SalesOrder DistributionChannel
_OrderQuantityUnit I_SalesOrderScheduleLine _OrderQuantityUnit
_DelivBlockReasonForSchedLine I_SalesOrderScheduleLine _DelivBlockReasonForSchedLine
_ScheduleLineCategory I_SalesOrderScheduleLine _ScheduleLineCategory
_GoodsMovementType I_SalesOrderScheduleLine _GoodsMovementType 
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@ObjectModel: {
    usageType: {
        dataClass:      #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory:   #XL
    },
    semanticKey: ['SalesOrder', 'SalesOrderItem', 'ScheduleLine']
}

@Metadata.ignorePropagatedAnnotations: true

@AccessControl.authorizationCheck: #CHECK

@EndUserText.label: 'Schedule Line for Sales Order Item - TP'

define view entity R_SalesOrderScheduleLineTP
  as select from I_SalesOrderScheduleLine as SalesOrderScheduleLine
  association        to parent R_SalesOrderItemTP   as _Item       on  $projection.SalesOrder             = _Item.SalesOrder
                                                                   and $projection.SalesOrderItem         = _Item.SalesOrderItem
  association [1..1] to R_SalesOrderTP              as _SalesOrder on  $projection.SalesOrder             = _SalesOrder.SalesOrder
 
{
  key SalesOrderScheduleLine.SalesOrder,

  key SalesOrderScheduleLine.SalesOrderItem,

  key SalesOrderScheduleLine.ScheduleLine,

      @ObjectModel.editableFieldFor: 'ScheduleLine'
      SalesOrderScheduleLine.ScheduleLine                                                 as ScheduleLineForEdit,

      @ObjectModel.foreignKey.association: '_ScheduleLineCategory'
      SalesOrderScheduleLine.ScheduleLineCategory,

      @ObjectModel.foreignKey.association: '_OrderQuantityUnit'
      OrderQuantityUnit,
      cast(_OrderQuantityUnit.UnitOfMeasureSAPCode as sd_ord_qty_sapunit preserving type) as OrderQuantitySAPUnit,

      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      ScheduleLineOrderQuantity,

      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      ConfdOrderQtyByMatlAvailCheck,

      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      DeliveredQtyInOrderQtyUnit,

      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      OpenConfdDelivQtyInOrdQtyUnit,

      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      CorrectedQtyInOrderQtyUnit,

      DeliveryDate,

      RequestedDeliveryDate,

      ConfirmedDeliveryDate,

      @ObjectModel.foreignKey.association: '_DelivBlockReasonForSchedLine'
      DelivBlockReasonForSchedLine,

      PurchaseRequisition,
      PurchaseRequisitionItem,
      
      @ObjectModel.foreignKey.association: '_GoodsMovementType'
      SalesOrderScheduleLine.GoodsMovementType,
      
      //Parent

      _Item,
      _SalesOrder,

      // For Access control

      @Consumption.hidden: true
      _SalesOrder.SalesOrderType,
      @Consumption.hidden: true
      _SalesOrder.OrganizationDivision,
      @Consumption.hidden: true
      _SalesOrder.SalesOrganization,
      @Consumption.hidden: true
      _SalesOrder.DistributionChannel,

      //Associations

      SalesOrderScheduleLine._OrderQuantityUnit,
      SalesOrderScheduleLine._DelivBlockReasonForSchedLine,
      SalesOrderScheduleLine._ScheduleLineCategory,
      SalesOrderScheduleLine._GoodsMovementType
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESORDERSCHEDULELINE",
"I_UNITOFMEASURE",
"R_SALESORDERTP"
],
"ASSOCIATED":
[
"I_DELIVERYBLOCKREASON",
"I_GOODSMOVEMENTTYPE",
"I_SCHEDULELINECATEGORY",
"I_UNITOFMEASURE",
"R_SALESORDERITEMTP",
"R_SALESORDERTP"
],
"BASE":
[
"I_SALESORDERSCHEDULELINE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More