I_REIntegObjToContractAssgmt

@AbapCatalog.sqlViewName: 'IREINTCONT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Integration Object Contract Assignment'

@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

//@ObjectModel.representativeKey: ['REStatusObjectSource']


@ObjectModel.supportedCapabilities:  [  #CDS_MODELING_ASSOCIATION_TARGET,
                                        #SQL_DATA_SOURCE,
                                        #EXTRACTION_DATA_SOURCE,
                                        #CDS_MODELING_DATA_SOURCE]
                                        
@Metadata.ignorePropagatedAnnotations: true                                        

@Analytics:{
    dataExtraction: {
        enabled: true
    }
}

@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_REIntegObjToContractAssgmt 
  as select from I_REObjectAssgmt 
//  I_REObjectAssgmtHier 

  as _REObjectAssgmt
  
//  association [1..1] to I_REIntegrationObject as _REIntegrationObject on $projection.internalrealestatenumber = _REIntegrationObject.InternalRealEstateNumber

  association [1..1] to I_REContract          as _REContract          on  $projection.REStatusObjectTarget      = _REContract.REStatusObject
  
  {
  key REStatusObjectTarget                                                as REStatusObjectSource,
  key REObjectAssignmentType,
  key _REContract.CompanyCode,
  key _REContract.RealEstateContract,
  key cast(concat(ValidityStartDate, ValidityEndDate ) as recadateperiod) as ValidityStartEndDateValue,
  key _REObjectTypeDetails.InternalRealEstateNumber,
      @Semantics.businessDate.from: true
      case when _REObjectAssgmt.ValidityStartDate > _REContract.ContractStartDate then cast( coalesce(ValidityStartDate, '00000000') as rebdvdmvalidfrom )
           when _REObjectTypeDetails._REIntegrationObject.ValidityStartDate > _REContract.ContractStartDate then _REObjectTypeDetails._REIntegrationObject.ValidityStartDate
           else _REContract.ContractStartDate
      end                                                                 as ValidityStartDate,
      REStatusObjectSource                                                as REStatusObjectTarget,

      @Semantics.businessDate.to: true                                        
      case when _REObjectAssgmt.ValidityEndDate < _REContract.ContractEndDate then cast( coalesce(ValidityEndDate, '99991231') as rebdvdmvalidto )
           when _REObjectTypeDetails._REIntegrationObject.ValidityEndDate < _REContract.ContractEndDate then _REObjectTypeDetails._REIntegrationObject.ValidityEndDate
           else _REContract.ContractEndDate
      end                                                                 as ValidityEndDate,
      REOnlyInfoAssgmt,
      REStatusObjectSourceIsArchived,
      REGenerationType,
      REIsMainAsset,
      REAssignmentHasMultiple,
      REObjectPossessionStartDate,
      REObjectPossessionEndDate,
//      REGroupNumber,

//      REObjectGroupName,      

      
      _REObjectTypeDetails,
      _REObjectAssignmentType,
      _REGenerationType,
      _REContract._CompanyCode,
      _REContract
//      _REIntegrationObject

}
where
      REStatusObjectTarget like 'J5%'
  and REStatusObjectSource like 'IS%'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RECONTRACT",
"I_REINTEGRATIONOBJECT",
"I_REOBJECTASSGMT",
"I_REOBJECTTYPEDETAILS"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_RECONTRACT",
"I_REGENERATIONTYPE",
"I_REOBJECTASSIGNMENTTYPE",
"I_REOBJECTTYPEDETAILS"
],
"BASE":
[
"I_RECONTRACT",
"I_REOBJECTASSGMT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/