R_REContrPartAssgmtTP

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]

@ObjectModel.representativeKey: 'REPartnerRelationUUID'
//@Analytics.technicalName: 'RRECNPARTASSTP'

@ObjectModel.semanticKey: ['InternalRealEstateNumber', 'REPartnerRelationUUID' ]
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@EndUserText.label: 'Real Estate Partner Assignment TP'
define view entity R_REContrPartAssgmtTP
  as select from I_REPartnerAssgmt as _REPartnerAssgmt
  association        to parent R_REContractTP as _REContract          on  $projection.InternalRealEstateNumber = _REContract.InternalRealEstateNumber

  association [1..1] to I_REPartnerAssgmtAddl as _REPartnerAssgmtAddl on  $projection.InternalRealEstateNumber  = _REPartnerAssgmtAddl.InternalRealEstateNumber
                                                                      and $projection.BusinessPartner           = _REPartnerAssgmtAddl.BusinessPartner
                                                                      and $projection.BusinessPartnerRole       = _REPartnerAssgmtAddl.BusinessPartnerRole
                                                                      and $projection.ValidityStartEndDateValue = _REPartnerAssgmtAddl.ValidityStartEndDateValue
  association [1..1] to I_REEntryValidity     as _REEntryValidity     on  $projection.REEntryValidity = _REEntryValidity.REEntryValidity

{
  key REPartnerRelationUUID,
  key InternalRealEstateNumber,
      BusinessPartner,
//      @Consumption.valueHelpDefinition: [{entity: {name: 'I_BusinessPartnerRole', element: 'BusinessPartnerRole' }}]

      @Consumption.valueHelpDefinition: [{association: '_BusinessPartnerRole'}]      
      BusinessPartnerRole,
      //    key ValidityStartDate,

      cast(concat(ValidityStartDate, ValidityEndDate ) as recadateperiod) as ValidityStartEndDateValue,
      //    Workaround Smart Elements Fiori DATS Null value issue: cast to tstmp and back to dats in case of null

      @Semantics.businessDate.from: true
      cast( coalesce(ValidityStartDate, '00000000') as rebdvdmvalidfrom ) as ValidityStartDate,
      @Semantics.businessDate.to: true
      cast( coalesce(ValidityEndDate, '99991231') as rebdvdmvalidto )     as ValidityEndDate,

      @ObjectModel.foreignKey.association: '_REEntryValidity'
      case
      //           when ValidityStartDate is initial then cast ('0' as recavdmentryvalidity)

          when ValidityStartDate is initial and ValidityEndDate is initial then cast ('3' as recavdmentryvalidity)
          when ValidityStartDate > $session.system_date then cast ('2' as recavdmentryvalidity)
          when ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date then cast('3' as recavdmentryvalidity)
          else cast ('1' as recavdmentryvalidity)
      end                                                                 as REEntryValidity,

      case
      //           when ValidityStartDate is initial then 0

          when ValidityStartDate is initial and ValidityEndDate is initial then 3
          when ValidityStartDate > $session.system_date then 2
          when ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date then 3
      else 1
      end                                                                 as REEntryValidityCriticality,

      case when BusinessPartnerRole = _REContract.REBusinessPartnerRole1
              then cast ('X' as rebpvdmmainpartner)
              else cast ('' as rebpvdmmainpartner)
          end                                                             as REIsMainPartner,

      case when BusinessPartnerRole = _REContract.REBusinessPartnerRole1
      then 3
      else 0
      end                                                                 as REMainPartnerCriticality,

      REPartnerRoleType,
      REPartnerApplicationCategory,
      AddressType,
      REFractionalPrptyShrRatio,
      REOwnershipShrRatio,
      RECoOwnershipShrRatio,
      REFractionalShrCnvrsnRatio,
      ContractAccount,

      _REContract,
      _REPartnerAssgmtAddl,
      _BusinessPartner,
      _BusinessPartnerRole,
      _REPartnerRoleType,
      _REEntryValidity,
      _BusinessPartnerAddressType

}
where
      _REContract.RealEstateObjectType                             = 'IS'
// DPP Business Partner compliance

// based on decision 2023-03-01, blocking shifted to DCL, in order to consider uthorization to access blocked data

//  and _REPartnerAssgmt._BusinessPartner.IsBusinessPurposeCompleted = ''

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_REPARTNERASSGMT",
"R_RECONTRACTTP"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNERADDRESSTYPE",
"I_BUSINESSPARTNERROLE",
"I_REENTRYVALIDITY",
"I_REPARTNERASSGMTADDL",
"I_REPARTNERROLETYPE",
"R_RECONTRACTTP"
],
"BASE":
[
"I_REPARTNERASSGMT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/