I_REPartnerAssgmt

@AbapCatalog.sqlViewName: 'IREPARTNERASS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Real Estate Partner Assignments'
@ObjectModel: {
    usageType.dataClass: #MASTER,
    usageType.serviceQuality: #C,
    usageType.sizeCategory: #L
    }
    
// ATTENTION PERSONAL DATA BLOCKING

// Views consuming I_REPartnerAssgmt must make sure to restrict access for personal data access / DPP. Blocking only implemented on RAP consumption and above

@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel.representativeKey: 'REPartnerRelationUUID'
@ObjectModel.semanticKey: ['InternalRealEstateNumber', 'BusinessPartner', 'BusinessPartnerRole', 'ValidityStartDate' ]

//@ClientDependent: true

@VDM.viewType: #BASIC
//@Search.searchable: true

@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_REPartnerAssgmt
  as select from vibpobjrel as _REPartnerAssgmt
  association [0..1] to I_BusinessPartner            as _BusinessPartner            on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [0..1] to I_BusinessPartnerRole        as _BusinessPartnerRole        on  $projection.BusinessPartnerRole = _BusinessPartnerRole.BusinessPartnerRole
  association [0..1] to I_REPartnerRoleType          as _REPartnerRoleType          on  $projection.BusinessPartnerRole = _REPartnerRoleType.BusinessPartnerRole
                                                                                    and $projection.REPartnerRoleType   = _REPartnerRoleType.REPartnerRoleType
  association [0..1] to I_BusinessPartnerAddressType as _BusinessPartnerAddressType on  $projection.AddressType = _BusinessPartnerAddressType.AddressType
  association [0..1] to I_ContractAccountHeader      as _CAHeader                   on  $projection.ContractAccount = _CAHeader.ContractAccount

{
  key objrelguid                                             as REPartnerRelationUUID,
      intreno                                                as InternalRealEstateNumber,
      @ObjectModel.foreignKey.association: '_BusinessPartner'
      partner                                                as BusinessPartner,
      @ObjectModel.foreignKey.association: '_BusinessPartnerRole'
//      @Consumption.valueHelpDefinition: [{entity: {name: 'I_BusinessPartnerRole', element: 'BusinessPartnerRole' }}]

      @Consumption.valueHelpDefinition: [{association: '_BusinessPartnerRole'}]
      role                                                   as BusinessPartnerRole,
      @ObjectModel.foreignKey.association: '_REPartnerRoleType'
      subrole                                                as REPartnerRoleType,
      @ObjectModel.foreignKey.association: '_BusinessPartnerAddressType'
      addrtype                                               as AddressType,
      @Semantics.businessDate.from: true
      cast ( validfrom as rebdvdmvalidfrom preserving type ) as ValidityStartDate,
      @Semantics.businessDate.to: true
      cast ( validto as rebdvdmvalidto preserving type )     as ValidityEndDate,
      appl                                                   as REPartnerApplicationCategory,
      bruteil                                                as REFractionalPrptyShrRatio,
      bmiteig                                                as REOwnershipShrRatio,
      panteil                                                as RECoOwnershipShrRatio,
      rfakt                                                  as REFractionalShrCnvrsnRatio,
      vkont                                                  as ContractAccount,

      _BusinessPartner,
      _BusinessPartnerRole,
      _REPartnerRoleType,
      _BusinessPartnerAddressType,
      _CAHeader

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"VIBPOBJREL"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNERADDRESSTYPE",
"I_BUSINESSPARTNERROLE",
"I_CONTRACTACCOUNTHEADER",
"I_REPARTNERROLETYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/