R_PurchaseOrderTP

@AccessControl: { authorizationCheck: #CHECK, personalData.blocking: #BLOCKED_DATA_EXCLUDED, privilegedAssociations: ['_SupplierAddress','_PurchaseOrderPartner'] }
@EndUserText.label: 'Purchase Order Transactional View'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MASTER}

@ObjectModel.sapObjectNodeType.name: 'PurchaseOrder'
 
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

define root view entity R_PurchaseOrderTP
  as select from R_PurchaseOrder as PurchaseOrder
  //      inner join P_PurchaseOrderItemExists as PurchaseOrderItemExists on

  //                 PurchaseOrder.PurchaseOrder = PurchaseOrderItemExists.PurchaseOrder

  composition [1..*] of R_PurchaseOrderItemTP          as _PurchaseOrderItem
  composition [1..1] of R_PurchaseOrdSupplierAddressTP as _SupplierAddress
  composition [1..*] of R_PurchaseOrderNoteTP          as _PurchaseOrderNote
  composition [1..*] of R_PurchaseOrderPartnerTP       as _PurchaseOrderPartner
  --Extension Association
  association [1..1] to E_PurchasingDocument           as _PurchaseOrderExtension on $projection.PurchaseOrder = _PurchaseOrderExtension.PurchasingDocument
  association [1..1] to I_PurchasingDocumentType       as _PurchaseOrderType on $projection.PurchaseOrderType                 = _PurchaseOrderType.PurchasingDocumentType 
                                                                            and _PurchaseOrderType.PurchasingDocumentCategory = 'F'
{
      //Key

  key PurchaseOrder.PurchaseOrder,

      //Category

      PurchaseOrder.PurchaseOrderType,
      PurchaseOrder.PurchaseOrderSubtype,
      PurchaseOrder.PurchasingDocumentOrigin,
      //PurchasingDocumentIsAged,

      PurchasingDocumentProcessCode,

      //Admin

      PurchaseOrder.CreatedByUser,
      PurchaseOrder.CreationDate,
      PurchaseOrder.PurchaseOrderDate,
      PurchaseOrder.LastChangeDateTime,
      PurchaseOrder.ValidityStartDate,
      PurchaseOrder.ValidityEndDate,
      PurchaseOrder.Language,

      //Status

      PurchaseOrder.PurchaseOrderDeletionCode,
      PurchaseOrder.ReleaseIsNotCompleted,
      PurchaseOrder.PurchasingCompletenessStatus,
      PurchaseOrder.PurchasingProcessingStatus,
      PurchaseOrder.PurgReleaseSequenceStatus,
      PurchaseOrder.ReleaseCode,
      PurchaseOrder.PurchasingReleaseStrategy,
      PurchaseOrder.PurgReasonForDocCancellation,

      //Organization

      PurchaseOrder.CompanyCode,
      PurchaseOrder.PurchasingOrganization,
      PurchaseOrder.PurchasingGroup,

      //Supplier

      PurchaseOrder.Supplier,
      PurchaseOrder.ManualSupplierAddressID,
      PurchaseOrder.SupplierAddressID,
      PurchaseOrder.SupplierRespSalesPersonName,
      PurchaseOrder.SupplierPhoneNumber,
      PurchaseOrder.SupplyingSupplier,
      PurchaseOrder.SupplyingPlant,
      PurchaseOrder.InvoicingParty,
      PurchaseOrder.Customer,

      //Contract

      PurchaseOrder.PurchaseContract,

      //Quotation Request

      //      RequestForQuotation,

      PurchaseOrder.SupplierQuotationExternalID,
      PurchaseOrder.QuotationSubmissionDate,
      PurchaseOrder.ItemNumberIntervalForSubItems,

      //Payments

      PurchaseOrder.PaymentTerms,
      PurchaseOrder.CashDiscount1Days,
      PurchaseOrder.CashDiscount2Days,
      PurchaseOrder.NetPaymentDays,
      PurchaseOrder.CashDiscount1Percent,
      PurchaseOrder.CashDiscount2Percent,
      PurchaseOrder.DownPaymentType,
      PurchaseOrder.DownPaymentPercentageOfTotAmt,

      //Downpayment

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      PurchaseOrder.DownPaymentAmount,
      PurchaseOrder.DownPaymentDueDate,

      //Incoterms

      PurchaseOrder.IncotermsClassification,
      PurchaseOrder.IncotermsTransferLocation,
      PurchaseOrder.IncotermsVersion,
      PurchaseOrder.IncotermsLocation1,
      PurchaseOrder.IncotermsLocation2,

      //Reference and Intrastat

      PurchaseOrder.IsIntrastatReportingRelevant,
      PurchaseOrder.IsIntrastatReportingExcluded,
      PurchaseOrder.CorrespncExternalReference,
      PurchaseOrder.CorrespncInternalReference,

      //Pricing document

      PurchaseOrder.PricingDocument,
      PurchaseOrder.PricingProcedure,
      PurchaseOrder.DocumentCurrency,
      cast( PurchaseOrder.ExchangeRate as fis_exchange_rate preserving type ) as ExchangeRate,
      PurchaseOrder.ExchangeRateIsFixed,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      PurchaseOrder.PurgReleaseTimeTotalAmount,
      //

      //      @Semantics.booleanIndicator: true

      //      IsEndOfPurposeBlocked,

      PurchaseOrder.TaxReturnCountry,
      PurchaseOrder.VATRegistrationCountry,

      // fields from product compliance

      PurchaseOrder.PurgAggrgdProdCmplncSuplrSts,
      PurchaseOrder.PurgAggrgdProdMarketabilitySts,
      PurchaseOrder.PurgAggrgdSftyDataSheetStatus,
      PurchaseOrder.PurgProdCmplncTotDngrsGoodsSts,

      /* Compositions */
      _PurchaseOrderItem,
      _SupplierAddress,
      @ObjectModel.filter.enabled: false
      @ObjectModel.sort.enabled: false
      _PurchaseOrderNote,
      _PurchaseOrderPartner,

      /* Associations */
      PurchaseOrder._CompanyCode,
      PurchaseOrder._CreatedByUser,
      PurchaseOrder._DocumentCurrency,
      PurchaseOrder._IncotermsClassification,
      PurchaseOrder._IncotermsVersion,
      PurchaseOrder._InvoicingParty,
      PurchaseOrder._Language,
      PurchaseOrder._PaymentTerms,
      PurchaseOrder._PurchaseOrderCalcFields,
      PurchaseOrder._PurchaseOrderDeletionCode,
      _PurchaseOrderType,
      PurchaseOrder._PurchasingGroup,
      PurchaseOrder._PurchasingOrganization,
      PurchaseOrder._Supplier,
      PurchaseOrder._SupplyingPlant,
      PurchaseOrder._SupplyingSupplier

      //TODOs:


      //1.Category: fields exist in EKKO DB and need to be added to I_PurchasingDocument (GFN doesn't exist yet)

      //WarrantyDate - GWLDT

      //GoodsReceiptIndicator - WEAKT

      //CollectiveNumber - SUBMI

      //LogicalSystem - LOGSY

      //ShippingType - VSART

      //ShippingConditions - SHIPCOND

      //ExternalReferenceSysID - EXTERNALSYSTEM

      //ExternalReferenceID - EXTERNALREFERENCEID

      //ExternalCallRevisionTime - EXT_REV_TMSTMP


      //2.Category: GFN already created for the fields and need to be added to I_PurchasingDocument

      //GoodsReceiptReasonCode - REASON_CODE

      //RetentionIndicator - RETTP

      //RetentionPercentage - RETPC

      //GoodsHandoverLocation - HANDOVERLOC

      //IncompletenessCategory - MEMORYTYPE


      //3.Category: SAP and ISO unit fields - not yet clear in which view need to be added

      //LanguageISOUnit

      //LanguageSAPUnit

      //CurrencyISOUnit

      //CurrencySAPUnit

      //VATCountryISOUnit

      //VATCountrySAPUnit

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_PURCHASEORDER"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCY",
"I_INCOTERMSCLASSIFICATION",
"I_INCOTERMSVERSION",
"I_LANGUAGE",
"I_PAYMENTTERMS",
"I_PLANT",
"I_PURCHASEORDERCALCFIELDS",
"I_PURCHASEORDERDELETIONCODE",
"I_PURCHASINGDOCUMENTTYPE",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_SUPPLIER",
"I_USER",
"R_PURCHASEORDERITEMTP",
"R_PURCHASEORDERNOTETP",
"R_PURCHASEORDERPARTNERTP",
"R_PURCHASEORDSUPPLIERADDRESSTP"
],
"BASE":
[
"R_PURCHASEORDER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/