R_PURCHASEORDER

@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Purchase Order Internal View'
@AccessControl: { authorizationCheck:#CHECK, personalData.blocking: #BLOCKED_DATA_EXCLUDED, privilegedAssociations: [ '_SupplierAddress' ] } 
@VDM.viewType : #BASIC
@AbapCatalog.sqlViewName: 'RMMPURCHASEORDER'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel: {
  modelCategory: #BUSINESS_OBJECT,
  compositionRoot:true,
  semanticKey: 'PurchaseOrder',
  representativeKey: 'PurchaseOrder'
}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
 
define view R_PurchaseOrder
  as select from R_PurchasingDocument

  association [0..1] to I_PurchaseOrderType            as _PurchaseOrderType         on _PurchaseOrderType.PurchaseOrderType = $projection.PurchaseOrderType

  association [0..*] to R_PurchaseOrderItem            as _PurchaseOrderItem         on  $projection.PurchaseOrder = _PurchaseOrderItem.PurchaseOrder

  association [0..*] to R_PurchaseOrderSupplierAddress as _SupplierAddress           on  $projection.PurchaseOrder = _SupplierAddress.PurchaseOrder

  association [1..1] to I_PurchaseOrderCalcFields      as _PurchaseOrderCalcFields   on  $projection.PurchaseOrder = _PurchaseOrderCalcFields.PurchaseOrder

  association [1..1] to I_PurchaseOrderDeletionCode    as _PurchaseOrderDeletionCode on  $projection.PurchaseOrderDeletionCode = _PurchaseOrderDeletionCode.PurchaseOrderDeletionCode


{
      //Key

  key cast (PurchasingDocument as vdm_purchaseorder preserving type)             as PurchaseOrder,

      //Category

      @ObjectModel.foreignKey.association: '_PurchaseOrderType'
      PurchasingDocumentType                                                     as PurchaseOrderType,
      PurchasingDocumentSubtype                                                  as PurchaseOrderSubtype,
      PurchasingDocumentProcessCode,
      PurchasingDocumentOrigin,
      PurchasingDocumentIsAged,

      //Admin

      CreatedByUser,
      //   @Semantics.businessDate.createdAt

      CreationDate,
      cast (PurchasingDocumentOrderDate as bedat preserving type)                as PurchaseOrderDate,
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
      Language,

      //Status

      @ObjectModel.foreignKey.association: '_PurchaseOrderDeletionCode'
      cast (PurchasingDocumentDeletionCode as mmpur_po_del_code preserving type) as PurchaseOrderDeletionCode,
      ReleaseIsNotCompleted,
      PurchasingCompletenessStatus,
      PurchasingProcessingStatus,
      PurgReleaseSequenceStatus,
      ReleaseCode,
      PurchasingReleaseStrategy,

      //Organization

      @ObjectModel.foreignKey.association: '_CompanyCode'
      CompanyCode,
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      PurchasingOrganization,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      PurchasingGroup,

      //Supplier

      @ObjectModel.foreignKey.association: '_Supplier'
      Supplier,
      ManualSupplierAddressID,
      SupplierAddressID,
      SupplierRespSalesPersonName,
      SupplierPhoneNumber,
      @ObjectModel.foreignKey.association: '_SupplyingSupplier'
      SupplyingSupplier,
      @ObjectModel.foreignKey.association: '_SupplyingPlant'
      SupplyingPlant,
      @ObjectModel.foreignKey.association: '_InvoicingParty'
      InvoicingParty,
      Customer,

      // Contract

      PurchaseContract,

      // Request For Quotation

      RequestForQuotation,
      QuotationSubmissionDate,
      // Collective Number

      PurchasingCollectiveNumber,
      ItemNumberIntervalForSubItems,

      //Quotation

      SupplierQuotationExternalID,

      //PaymentTerms

      @ObjectModel.foreignKey.association: '_PaymentTerms'
      PaymentTerms,
      CashDiscount1Days,
      CashDiscount2Days,
      NetPaymentDays,
      CashDiscount1Percent,
      CashDiscount2Percent,

      //DownPayment

      DownPaymentType,
      DownPaymentPercentageOfTotAmt,
      DownPaymentAmount,
      DownPaymentDueDate,

      //Incoterms

      @ObjectModel.foreignKey.association: '_IncotermsClassification'
      IncotermsClassification,
      IncotermsTransferLocation,
      @ObjectModel.foreignKey.association: '_IncotermsVersion'
      IncotermsVersion,
      IncotermsLocation1,
      IncotermsLocation2,
      IncotermsSupChnLoc1AddlUUID,      
      IncotermsSupChnLoc2AddlUUID,
      IncotermsSupChnDvtgLocAddlUUID,            

      //Intratat

      IsIntrastatReportingRelevant,
      IsIntrastatReportingExcluded,

      //References

      CorrespncExternalReference, //Your reference

      CorrespncInternalReference, //Our reference


      //Pricing

      PricingDocument,
      PricingProcedure,

      @Semantics.currencyCode
      @ObjectModel.foreignKey.association: '_DocumentCurrency'
      DocumentCurrency,

      ValidityStartDate,
      ValidityEndDate,

      @Consumption.hidden: true
      ExchangeRate,
      ExchangeRateIsFixed,

      LastChangeDateTime,
      IsEndOfPurposeBlocked,

      TaxReturnCountry,
      VATRegistrationCountry,
      PurgReasonForDocCancellation,
      PurgReleaseTimeTotalAmount,

      // fields from product compliance

      PurgAggrgdProdCmplncSuplrSts,
      PurgAggrgdProdMarketabilitySts,
      PurgAggrgdSftyDataSheetStatus,
      PurgProdCmplncTotDngrsGoodsSts,
      
      PurgDocDefaultShippingType,


      //_CompanyCode.FiscalYearVariant as FiscalYearVariant,


      // Associations


      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _PurchaseOrderItem,
      _PurchaseOrderType,
      _CompanyCode,
      _CreatedByUser,
      _Supplier,
      _SupplyingSupplier,
      _InvoicingParty,
      _PurchasingOrganization,
      _PurchasingGroup,
      _DocumentCurrency,
      _IncotermsClassification,
      _IncotermsVersion,
      _SupplyingPlant,
      _PaymentTerms,
      _SupplierAddress,
      _Language,
      _PurchaseOrderDeletionCode,
      _PurchaseOrderCalcFields,
      _PurchasingProcessingStatus

      //Missing Associations


      //_AllContacts

      // Partner

      //Conditions

      //PricingProcedure

}
where
      R_PurchasingDocument.PurchasingDocumentCategory = 'F'
  and R_PurchasingDocument.PurchasingDocumentIsAged   = ''
  and IsEndOfPurposeBlocked                           = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_PURCHASINGDOCUMENT"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCY",
"I_INCOTERMSCLASSIFICATION",
"I_INCOTERMSVERSION",
"I_LANGUAGE",
"I_PAYMENTTERMS",
"I_PLANT",
"I_PURCHASEORDERCALCFIELDS",
"I_PURCHASEORDERDELETIONCODE",
"I_PURCHASEORDERTYPE",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_PURCHASINGPROCESSINGSTATUS",
"I_SUPPLIER",
"I_USER",
"R_PURCHASEORDERITEM",
"R_PURCHASEORDERSUPPLIERADDRESS"
],
"BASE":
[
"R_PURCHASINGDOCUMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/