R_ProductionRoutingHeaderTP_2

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Production Routing Header'
@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #M, dataClass: #MASTER }
@ObjectModel.representativeKey: 'ProductionRoutingInternalVers'
@VDM: { viewType: #TRANSACTIONAL, lifecycle.contract.type: #SAP_INTERNAL_API }
define view entity R_ProductionRoutingHeaderTP_2
  as select from I_RoutingHeader     as plko
    inner join   I_ProductionRouting as plkz on  plko.BillOfOperationsType    = plkz.BillOfOperationsType
                                             and plko.BillOfOperationsGroup   = plkz.BillOfOperationsGroup
                                             and plko.BillOfOperationsVariant = plkz.BillOfOperationsVariant

  association [0..*] to R_ProdnRoutingMatlAssgmtTP_2   as _MatlAssgmt on  $projection.ProductionRoutingGroup =  _MatlAssgmt.ProductionRoutingGroup
                                                                      and $projection.ProductionRouting      =  _MatlAssgmt.ProductionRouting
                                                                      and $projection.ValidityEndDate        >= _MatlAssgmt.ValidityStartDate
                                                                      and $projection.ValidityStartDate      <= _MatlAssgmt.ValidityEndDate
  association [1..*] to R_ProdnRoutingSequenceTP_2     as _Sequence   on  $projection.ProductionRoutingGroup =  _Sequence.ProductionRoutingGroup
                                                                      and $projection.ProductionRouting      =  _Sequence.ProductionRouting
                                                                      and $projection.ValidityEndDate        >= _Sequence.ValidityStartDate
                                                                      and $projection.ValidityStartDate      <= _Sequence.ValidityEndDate
  association        to parent R_ProductionRoutingTP_2 as _ProdnRtgTP on  $projection.ProductionRoutingGroup = _ProdnRtgTP.ProductionRoutingGroup
                                                                      and $projection.ProductionRouting      = _ProdnRtgTP.ProductionRouting

  association        to I_BillOfOperationsStatusText   as _StatusText on  $projection.BillOfOperationsStatus = _StatusText.BillOfOperationsStatus
                                                                      and _StatusText.Language               = $session.system_language
  association        to I_BillOfOperationsUsageText    as _UsageText  on  $projection.BillOfOperationsUsage = _UsageText.BillOfOperationsUsage
                                                                      and _UsageText.Language               = $session.system_language

  //Association for Product Count

  association [0..1] to I_ProdnRtgMatlCount            as _MatlCount  on  $projection.ProductionRoutingGroup = _MatlCount.ProductionRoutingGroup
                                                                      and $projection.ProductionRouting      = _MatlCount.ProductionRouting

  association [1..1] to I_Plant                        as _Plant      on  $projection.Plant = _Plant.Plant

{
  key plko.BillOfOperationsGroup     as ProductionRoutingGroup,
  key plko.BillOfOperationsVariant   as ProductionRouting,
  key plko.BOOInternalVersionCounter as ProductionRoutingInternalVers,
      plkz.IsMarkedForDeletion       as IsMarkedForDeletion, // DELKZ

      @Semantics.text: true
      plko.BillOfOperationsDesc,
      plko.Plant,
      plko.BillOfOperationsUsage,
      plko.BillOfOperationsStatus,
      plko.ResponsiblePlannerGroup,
      @Semantics.quantity.unitOfMeasure: 'BillOfOperationsUnit'
      plko.MinimumLotSizeQuantity,
      @Semantics.quantity.unitOfMeasure: 'BillOfOperationsUnit'
      plko.MaximumLotSizeQuantity,
      plko.BillOfOperationsUnit,
      plko.CreationDate,
      plko.CreatedByUser,
      plko.LastChangeDate,
      plko.LastChangedByUser,
      @Semantics.businessDate.from: true
      plko.ValidityStartDate,
      @Semantics.businessDate.to: true
      plko.ValidityEndDate,
      plko.ChangeNumber,
      _ProdnRtgTP.ChangedDateTime,
      @Semantics.text: true
      plko.PlainLongText,
      _Plant.PlantName,

      /* Associations */
      _MatlAssgmt,
      _ProdnRtgTP,
      _Sequence,
      _UsageText,
      _StatusText,
      _MatlCount,
      _Plant
}
where
      plko.IsDeleted           <> 'X'
  and plko.IsImplicitlyDeleted <> 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PLANT",
"I_PRODUCTIONROUTING",
"I_ROUTINGHEADER",
"R_PRODUCTIONROUTINGTP_2"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONSSTATUSTEXT",
"I_BILLOFOPERATIONSUSAGETEXT",
"I_PLANT",
"I_PRODNRTGMATLCOUNT",
"R_PRODNROUTINGMATLASSGMTTP_2",
"R_PRODNROUTINGSEQUENCETP_2",
"R_PRODUCTIONROUTINGTP_2"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/