I_ProductionRouting

DDL: I_PRODUCTIONROUTING SQL: IPRODRTG Type: view_entity BASIC

Production Routing main header details

I_ProductionRouting is a Basic CDS View that provides data about "Production Routing main header details" in SAP S/4HANA. It reads from 1 data source (plkz) and exposes 18 fields with key fields BillOfOperationsType, BillOfOperationsGroup, BillOfOperationsVariant. It has 3 associations to related views.

1 data source(s) 18 fields

Data Sources (1)

SourceAliasJoin Type
plkz plkz from

Associations (3)

CardinalityTargetAliasCondition
[1..1] I_BillOfOperationsType _BillOfOperationsType $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
[0..1] I_BillOfOperationsVersionType _BillOfOperationsVersionType $projection.BillOfOperationsVersionType = _BillOfOperationsVersionType.BillOfOperationsVersionType
[1..1] I_BillOfOperationsGroup _BillOfOperationsGroup $projection.BillOfOperationsType = _BillOfOperationsGroup.BillOfOperationsType and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup

Annotations (8)

NameValueLevelField
VDM.viewType #BASIC view
ObjectModel.representativeKey BillOfOperationsVariant view
AccessControl.authorizationCheck #CHECK view
EndUserText.label Production Routing main header details view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #MASTER view
Metadata.allowExtensions true view

Fields (18)

KeyFieldSource TableSource FieldDescription
KEY BillOfOperationsType plkz plnty
KEY BillOfOperationsGroup plkz plnnr
KEY BillOfOperationsVariant plkz plnal
BillOfOperationsVersionType plkz subtype
BillOfOperationsSubtype plkz subtype
LastUsageDate plkz abdat
NumberOfUsages plkz abanz
HasChangeNumber plkz flg_ecm
HasParameterEffectivity plkz flg_ecm_par
aedatasLastChangeDate
LastChangeTime plkz aeuzeit
LastChangedByUser
IsMarkedForDeletion plkz delkz
RoutingIsReworkRouting plkz rework
ProdnProcgIsFlexible plkz relaxed
_BillOfOperationsType _BillOfOperationsType
_BillOfOperationsGroup _BillOfOperationsGroup
_BillOfOperationsVersionType _BillOfOperationsVersionType 
//@AbapCatalog.sqlViewName: 'IPRODRTG'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@VDM.viewType: #BASIC
//@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.representativeKey: 'BillOfOperationsVariant'
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Production Routing main header details'
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@Metadata.allowExtensions: true
//define view I_ProductionRouting

define view entity I_ProductionRouting
  as select from plkz
  association [1..1] to I_BillOfOperationsType        as _BillOfOperationsType        on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [0..1] to I_BillOfOperationsVersionType as _BillOfOperationsVersionType on  $projection.BillOfOperationsVersionType = _BillOfOperationsVersionType.BillOfOperationsVersionType
  association [1..1] to I_BillOfOperationsGroup       as _BillOfOperationsGroup       on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup
{
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plkz.plnty                                                   as   BillOfOperationsType,

      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key plkz.plnnr                                                   as   BillOfOperationsGroup,
  key plkz.plnal                                                   as   BillOfOperationsVariant,

      @ObjectModel.foreignKey.association: '_BillOfOperationsVersionType'
      plkz.subtype                                                 as   BillOfOperationsVersionType,

      plkz.subtype                                                 as   BillOfOperationsSubtype, //kept for compatibility reasons


      plkz.abdat                                                   as   LastUsageDate,
      plkz.abanz                                                   as   NumberOfUsages,

      plkz.flg_ecm                                                 as   HasChangeNumber,
      plkz.flg_ecm_par                                             as   HasParameterEffectivity,

      -- Administrative Data
      @Semantics.systemDate.lastChangedAt: true
      plkz.aedat                                                   as   LastChangeDate,
      plkz.aeuzeit                                                 as   LastChangeTime,
      @Semantics.user.lastChangedBy: true
      cast(plkz.aenam as vdm_lastchangedbyuserid preserving type)  as   LastChangedByUser,

      plkz.delkz                                                   as   IsMarkedForDeletion,

      plkz.rework                                                  as   RoutingIsReworkRouting,
      plkz.relaxed                                                 as   ProdnProcgIsFlexible,

      // **************************** Associations *****************************

      _BillOfOperationsType,
      _BillOfOperationsGroup,
      _BillOfOperationsVersionType
}
where
  plnty = 'N'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"PLKZ"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_BILLOFOPERATIONSVERSIONTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More