R_ProcessOrderRelationshipTP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#TRANSACTIONAL_PROVIDER]
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@EndUserText.label: 'Process Order Relationship - TP'

//      ************************  DO NOT USE  ************************

//      *            This RAP BO is for testing purpose only         *

//      **************************************************************


define view entity R_ProcessOrderRelationshipTP
  as select from I_MfgOrderOpRelationship as Relationship

  // BO relation

  // parent relation: superior operation

  association        to parent R_ProcessOrderPhaseTP as _SuccessorPhase   on  _SuccessorPhase.OrderInternalID      = $projection.SuccessorOrderInternalID
                                                                          and _SuccessorPhase.OrderPhaseInternalID = $projection.SuccessorPhaseInternalID

  association [1..1] to R_ProcessOrderTP             as _SuccessorOrder   on  _SuccessorOrder.ProcessOrder = $projection.SuccessorOrder

  association [1..1] to R_ProcessOrderPhaseTP        as _PredecessorPhase on  _PredecessorPhase.OrderInternalID      = $projection.PredecessorOrderInternalID
                                                                          and _PredecessorPhase.OrderPhaseInternalID = $projection.PredecessorPhaseInternalID

  association [1..1] to R_ProcessOrderTP             as _PredecessorOrder on  _PredecessorOrder.ProcessOrder = $projection.PredecessorOrder

{
      // Key

  key PredecessorOrderInternalID,
  key PredecessorOperationInternalID                             as PredecessorPhaseInternalID,
  key SuccessorOrderInternalID,
  key SuccessorOperationInternalID                               as SuccessorPhaseInternalID,
  key OrderOpRelationshipIntType                                 as OrderPhaseRelationshipIntType,
      @Semantics.booleanIndicator: true
  key MaxTimeIntvlIsUsedForSchedg,

      // External ID of predecessor

      PredecessorOrder,
      PredecessorOrderOperation                                  as PredecessorOrderPhase,

      // External ID of successor

      SuccessorOrder,
      SuccessorOrderOperation                                    as SuccessorOrderPhase,

      @Consumption.hidden: true // for DCLS

      ManufacturingOrderCategory,

      // Time interval Duration

      OpRelationshipTimeIntervalUnit                             as PhaseRelshpTimeIntervalUnit,
      @Semantics.quantity.unitOfMeasure: 'PhaseRelshpTimeIntervalUnit'
      OpRelationshipTimeIntervalDurn                             as PhaseRelshpTimeIntervalDurn,
      @Semantics.quantity.unitOfMeasure: 'PhaseRelshpTimeIntervalUnit'
      MaxTimeIntvlBtwnRelshp                                     as PhaseRelshpTimeIntervalDurnMax,
      TimeIntvlBtwnRelshpInPct,
      TimeInterval,

      // Others

      ObjectInternalID,
      ObjectIsDeleted,
      FactoryCalendar,
      Plant,
      WorkCenterInternalID                                       as ProductionResourceInternalID,
      cast(_WorkCenter.WorkCenter as cr_resourc preserving type) as ProductionResource,
      // Associations

      _SuccessorPhase,
      _SuccessorOrder,
      _PredecessorPhase,
      _PredecessorOrder
}
where
  ManufacturingOrderCategory = '40'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MFGORDEROPRELATIONSHIP",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"R_PROCESSORDERPHASETP",
"R_PROCESSORDERTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/