I_MFGORDEROPRELATIONSHIP

CDS View

Relationships of Manufacturing Orders

I_MFGORDEROPRELATIONSHIP is a CDS View in S/4HANA. Relationships of Manufacturing Orders. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
R_ProcessOrderRelationshipTP view_entity from TRANSACTIONAL Process Order Relationship - TP 
@AccessControl.authorizationCheck: #MANDATORY
@Analytics.dataCategory: #FACT
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Relationships of Manufacturing Orders'

/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view entity I_MfgOrderOpRelationship
  as select from I_ProjectNetworkRelationship as rel

  association [1..1] to I_MfgOrderBasic       as _PredecessorOrder     on  $projection.PredecessorOrderInternalID = _PredecessorOrder.OrderInternalID
  association [1..1] to I_MfgOrderBasic       as _SuccessorOrder       on  $projection.SuccessorOrderInternalID = _SuccessorOrder.OrderInternalID
  association [1..1] to I_OrderOperationBasic as _PredecessorOperation on  $projection.PredecessorOrderInternalID     = _PredecessorOperation.OrderInternalID
                                                                       and $projection.PredecessorOperationInternalID = _PredecessorOperation.OrderOperationInternalID
  association [1..1] to I_OrderOperationBasic as _SuccessorOperation   on  $projection.SuccessorOrderInternalID     = _SuccessorOperation.OrderInternalID
                                                                       and $projection.SuccessorOperationInternalID = _SuccessorOperation.OrderOperationInternalID
  association [0..1] to I_FactoryCalendar     as _FactoryCalendar      on  $projection.FactoryCalendar = _FactoryCalendar.FactoryCalendar
  association [0..1] to I_Plant               as _Plant                on  $projection.Plant = _Plant.Plant
  association [0..1] to I_WorkCenter          as _WorkCenter           on  $projection.WorkCenterInternalID = _WorkCenter.WorkCenterInternalID
                                                                       and _WorkCenter.WorkCenterTypeCode   = 'A '
{
      // Key

  key cast(rel.PredecessorProjNtwkIntID            as vdm_aufpl_pre preserving type) as PredecessorOrderInternalID,
  key cast(rel.PredecessorNtwkActyIntID            as vdm_aplzl_pre preserving type) as PredecessorOperationInternalID,
  key cast(rel.SuccessorProjNtwkIntID              as vdm_aufpl_suc preserving type) as SuccessorOrderInternalID,
  key cast(rel.SuccessorNtwkActyIntID              as vdm_aplzl_suc preserving type) as SuccessorOperationInternalID,
  key cast(rel.NetworkActivityRelationType         as vdm_aobar     preserving type) as OrderOpRelationshipIntType,
      @Semantics.booleanIndicator: true
  key cast(rel.MaxTimeIntvlIsUsedForSchedg as BT_MaxTimeIntvlIsUsed preserving type) as MaxTimeIntvlIsUsedForSchedg,

      // External ID of predecessor

      cast(_PredecessorOrder.ManufacturingOrder    as vdm_aufnr_pre preserving type) as PredecessorOrder,
      cast(_PredecessorOperation.Operation_2       as vdm_vornr_pre preserving type) as PredecessorOrderOperation,

      // External ID of successor

      cast(_SuccessorOrder.ManufacturingOrder      as vdm_aufnr_suc preserving type) as SuccessorOrder,
      cast(_SuccessorOperation.Operation_2         as vdm_vornr_suc preserving type) as SuccessorOrderOperation,

      @Consumption.hidden: true // for DCLS

      _PredecessorOrder.ManufacturingOrderCategory                                   as ManufacturingOrderCategory,

      // Time interval Duration

      rel.NetworkActivityIntmsnDurnUnit                                              as OpRelationshipTimeIntervalUnit,
      @Semantics.quantity.unitOfMeasure: 'OpRelationshipTimeIntervalUnit'
      rel.NetworkActivityIntmsnDuration                                              as OpRelationshipTimeIntervalDurn,
      @Semantics.quantity.unitOfMeasure: 'OpRelationshipTimeIntervalUnit'
      rel.MaxTimeIntvlBtwnRelshp,
      rel.TimeIntvlBtwnRelshpInPct,
      rel.TimeInterval,

      // Others

      rel.ProjectNetworkObject                                                       as ObjectInternalID,
      rel.ObjectIsDeleted,
      rel.FactoryCalendar,
      rel.Plant,
      rel.WorkCenterInternalID,

      // Associations

      _PredecessorOrder,
      _PredecessorOperation,
      _SuccessorOrder,
      _SuccessorOperation,
      _FactoryCalendar,
      _Plant,
      _WorkCenter
}
where
  _PredecessorOrder.ManufacturingOrderCategory = '40';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MFGORDERBASIC",
"I_ORDEROPERATIONBASIC",
"I_PROJECTNETWORKRELATIONSHIP"
],
"ASSOCIATED":
[
"I_FACTORYCALENDAR",
"I_MFGORDERBASIC",
"I_ORDEROPERATIONBASIC",
"I_PLANT",
"I_WORKCENTER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More