R_POSubcontractingComponentTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl: { authorizationCheck: #CHECK}
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@EndUserText.label: 'PO Subcontracting Components TP view'
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MASTER}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

define view entity R_POSubcontractingComponentTP
  as select from R_POSubcontractingComponent

  association [1..1] to R_PurchaseOrderTP                    as _PurchaseOrder     on  $projection.PurchaseOrder = _PurchaseOrder.PurchaseOrder

  association [1..1] to R_PurchaseOrderItemTP                as _PurchaseOrderItem on  $projection.PurchaseOrder     = _PurchaseOrderItem.PurchaseOrder
                                                                                   and $projection.PurchaseOrderItem = _PurchaseOrderItem.PurchaseOrderItem

  association        to parent R_PurchaseOrderScheduleLineTP as _ScheduleLine      on  $projection.PurchaseOrder     = _ScheduleLine.PurchaseOrder
                                                                                   and $projection.PurchaseOrderItem = _ScheduleLine.PurchaseOrderItem
                                                                                   and $projection.ScheduleLine      = _ScheduleLine.ScheduleLine
{
      // Keys

  key PurchaseOrder,
  key PurchaseOrderItem,
  key PurchaseOrderScheduleLine                                     as ScheduleLine,
  key ReservationItem,
  key RecordType,

      // Material data

      Material,
      @Semantics.booleanIndicator: true
      IsMaterialProvision,
      MaterialProvisionType,
      MaterialQtyToBaseQtyNmrtr,
      MaterialQtyToBaseQtyDnmntr,
      cast( MaterialRevisionLevel as vdm_qm_revlv preserving type ) as MaterialRevisionLevel,
      MaterialCompIsVariableSized,
      MaterialComponentIsPhantomItem,

      // Reservation and Requirements

      Reservation,
      RequiredQuantity,
      RequirementDate,
      RequirementTime,
      ReservationIsFinallyIssued,

      // Amount and Units

      BaseUnit,
      QuantityInEntryUnit,

      EntryUnit,


      VariableSizeItemQuantity,
      VariableSizeItemUnit,
      VariableSizeComponentUnit,
      VariableSizeComponentQuantity,
      UnitOfMeasureForSize1To3,
      Size1,
      Size2,
      Size3,

      // The other fields

      Plant,
      LatestRequirementDate,
      OrderLevelValue,
      OrderPathValue,
      cast( BillOfMaterialItemNumber as vdm_sposn preserving type ) as BillOfMaterialItemNumber,
      SortField                                                     as MatlCompFreeDefinedAttribute,
      BOMItemCategory,
      IsBulkMaterialComponent,
      AccountAssignmentCategory,
      InventorySpecialStockType,
      ConsumptionPosting,
      InventorySpecialStockValnType,
      DebitCreditCode,
      WithdrawnQuantity,

      QuantityIsFixed,
      ComponentScrapInPercent,
      OperationScrapInPercent,
      IsNetScrap,
      LeadTimeOffset,
      QuantityDistributionKey,
      FormulaKey,
      StorageLocation,
      ProductionSupplyArea,
      Batch,
      BOMItemDescription,
      BOMItemText2,
      ChangeNumber,

      // TODO's

      // Fields exist in POPARTNER (BAPIEKKOP) and should be added to CDS view

      // ENTRY_UOM_ISO

      // CHANGE_ID

      // MATERIAL_EXTERNAL

      // MATERIAL_GUID

      // MATERIAL_VERSION

      // BASE_UOM

      // BASE_UOM_ISO

      // REQ_SEGMENT

      // MATERIAL_LONG

      // REQ_SEG_LONG


      /* Associations */
      _BaseUnit,
      _EntryUnit,
      _Material,
      _Product,
      _PurchaseOrder,
      _PurchaseOrderItem,
      _ScheduleLine,
      _VariableSize1To3Unit,
      _VariableSizeCompUnit
}
where
  _PurchaseOrderItem.PurchasingDocumentDeletionCode = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_POSUBCONTRACTINGCOMPONENT",
"R_PURCHASEORDERITEMTP"
],
"ASSOCIATED":
[
"I_MATERIAL",
"I_PRODUCT",
"I_UNITOFMEASURE",
"R_PURCHASEORDERITEMTP",
"R_PURCHASEORDERSCHEDULELINETP",
"R_PURCHASEORDERTP"
],
"BASE":
[
"R_POSUBCONTRACTINGCOMPONENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/