R_MngJrnlEntrChangeDocument

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Journal Entry - Changed Document'
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XL,
  dataClass: #MIXED
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
define view entity R_MngJrnlEntrChangeDocument

  as select from I_JournalEntryHistory as _Change

{
  key cast( _Change.CompanyCode as fis_bukrs preserving type )           as CompanyCode,
  key _Change.Ledger,
  key cast( _Change.AccountingDocument as farp_belnr_d preserving type ) as AccountingDocument,
  key _Change.ChangeDocument                                             as ChangeDocument,
  key _Change.DatabaseTable                                              as DatabaseTable,
  key _Change.ChangeDocTableKey                                          as ChangeDocTableKey,
  key _Change.DatabaseTableField                                         as ChangeDocDatabaseTableField,
  key _Change.AccountingDocumentItem                                     as JournalEntryItem,
  key cast( _Change.FiscalYear as fis_gjahr_no_conv preserving type )    as FiscalYear,
      cast( _Change.DocumentDate as fis_bldat preserving type )          as DocumentDate,
      cast( _Change.PostingDate as fis_budat preserving type)            as PostingDate,
      _Change.UserName                                                   as ChangedBy,
      _Change.LastChangeTime                                             as LastChangeTime,
      _Change.OldFieldContent                                            as ChangedFieldOldValue,
      _Change.NewFieldContent                                            as ChangedFieldNewValue,
      _Change.LastChangeDate                                             as LastChangedDate,
      _Change.AccountingDocumentCreationDate                             as CreationDate,
      _Change.CreationTime,
      _Change.AccountingDocumentType,
      _Change.AccountingDocumentCategory

}

union all select from I_ChangeDocumentItem          as _ChangeDocItem
  inner join          R_MngJrnlEntrPrkdChgDocTblKey as _AccountingDoc on  _ChangeDocItem.DatabaseTable     = _AccountingDoc.DatabaseTable
                                                                and _ChangeDocItem.ChangeDocTableKey = _AccountingDoc.ChangeDocumentTableKey

{
  key _AccountingDoc.CompanyCode,
  key _AccountingDoc.Ledger,
  key _AccountingDoc.AccountingDocument,
  key _ChangeDocItem.ChangeDocument,
  key _ChangeDocItem.DatabaseTable,
  key _ChangeDocItem.ChangeDocTableKey,
  key _ChangeDocItem.ChangeDocDatabaseTableField,
  key _AccountingDoc.AccountingDocumentItem         as JournalEntryItem,
  key _AccountingDoc.FiscalYear,
      _AccountingDoc.DocumentDate,
      _AccountingDoc.PostingDate,
      _ChangeDocItem._ChangeDocument.CreatedByUser  as ChangedBy,
      _ChangeDocItem._ChangeDocument.CreationTime   as LastChangeTime,
      _ChangeDocItem.ChangeDocPreviousFieldValue    as ChangedFieldOldValue,
      _ChangeDocItem.ChangeDocNewFieldValue         as ChangedFieldNewValue,
      _ChangeDocItem._ChangeDocument.CreationDate   as LastChangedDate,
      _AccountingDoc.AccountingDocumentCreationDate as CreationDate,
      _AccountingDoc.CreationTime,
      _AccountingDoc.AccountingDocumentType,
      _AccountingDoc.AccountingDocumentCategory

}
where
      _ChangeDocItem.ChangeDocObjectClass =  'BELEGV'
  and _ChangeDocItem.DatabaseTable        <> 'VBKPF'

union all select from R_MngJrnlEntrPrkdChgHeader as _ChangeDocItem

{
  key CompanyCode,
  key Ledger,
  key AccountingDocument,
  key ChangeDocument,
  key DatabaseTable,
  key ChangeDocTableKey,
  key ChangeDocDatabaseTableField,
  key cast ('' as docln6 ) as JournalEntryItem, 
  key FiscalYear,
      DocumentDate,
      PostingDate,
      ChangedBy,
      LastChangeTime,
      ChangedFieldOldValue,
      ChangedFieldNewValue,
      LastChangedDate,
      CreationDate,
      CreationTime,
      AccountingDocumentType,
      AccountingDocumentCategory
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEDOCUMENT",
"I_CHANGEDOCUMENTITEM",
"I_JOURNALENTRYHISTORY",
"R_MNGJRNLENTRPRKDCHGDOCTBLKEY",
"R_MNGJRNLENTRPRKDCHGHEADER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/