R_MaintTaskListSubOpTP

@AbapCatalog : {  dataMaintenance:#RESTRICTED }
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Tasklist Suboperations'
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@VDM: { viewType: #TRANSACTIONAL, lifecycle.contract.type: #SAP_INTERNAL_API }
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}

define view entity R_MaintTaskListSubOpTP
  as select distinct from I_BOOSubOperationChangeState
  association        to parent R_MaintTaskListOperationTP as _NonHistOp on  $projection.TaskListType                = _NonHistOp.TaskListType
                                                                        and $projection.TaskListGroup               = _NonHistOp.TaskListGroup
                                                                        and $projection.TaskListGroupCounter        = _NonHistOp.TaskListGroupCounter
                                                                        and $projection.TaskListSequence            = _NonHistOp.TaskListSequence
                                                                        and $projection.SuperiorOperationInternalID = _NonHistOp.TaskListOperationInternalId
  association [1..*] to R_MaintTaskListOpBasicTP          as _Operation on  $projection.TaskListType                = _Operation.TaskListType
                                                                        and $projection.TaskListGroup               = _Operation.TaskListGroup
                                                                        and $projection.TaskListGroupCounter        = _Operation.TaskListGroupCounter
                                                                        and $projection.TaskListSequence            = _Operation.TaskListSequence
                                                                        and $projection.SuperiorOperationInternalID = _Operation.TaskListOperationInternalId
  association        to R_MaintenanceTaskListTP           as _Header    on  $projection.TaskListType         = _Header.TaskListType
                                                                        and $projection.TaskListGroup        = _Header.TaskListGroup
                                                                        and $projection.TaskListGroupCounter = _Header.TaskListGroupCounter
  association [1..1] to R_MaintTaskListOpBasicTP          as _SubOperation on $projection.TaskListType              = _SubOperation.TaskListType
                                                                        and $projection.TaskListGroup               = _SubOperation.TaskListGroup
                                                                        and $projection.TaskListGroupCounter        = _SubOperation.TaskListGroupCounter
                                                                        and $projection.TaskListSequence            = _SubOperation.TaskListSequence 
                                                                        and $projection.TaskListOperationInternalId = _SubOperation.TaskListOperationInternalId
                                                                        and $projection.TaskListOpBOMItmIntVersCounter = _SubOperation.TaskListOpBOMItmIntVersCounter                                                                        
{
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key BillOfOperationsType                                     as TaskListType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key BillOfOperationsGroup                                    as TaskListGroup,
      @ObjectModel.foreignKey.association: '_BillOfOperations'
  key BillOfOperationsVariant                                  as TaskListGroupCounter,
      @ObjectModel.foreignKey.association: '_BillOfOperationsSequence'
  key BillOfOperationsSequence                                 as TaskListSequence,
      @ObjectModel.foreignKey.association: '_BOOOperationInternalID'
  key BOOOperationInternalID                                   as TaskListOperationInternalId,

  key BOOOpInternalVersionCounter                              as TaskListOpBOMItmIntVersCounter,
      @ObjectModel.foreignKey.association: '_BOOSqncOperationAssgmtChgSt'
      BOOSqncOpAssgmtIntVersionCntr,
      _Operation.MaintOperationExecStageCode                   as MaintOperationExecStageCode,
      _Operation.MaintenanceTaskListOperation                  as MaintenanceTaskListOperation,
      BillOfOperationsVersion, // NOT a key field in THIS view !


      // ***************** Work Center *****************

      _Operation.WorkCenter                                    as WorkCenter,
      WorkCenterInternalID,
      WorkCenterTypeCode,

      // ***************** Indicators *****************


      case IsDeleted
        when ' ' then IsDeleted
        else          IsDeleted
      end                                                      as IsDeleted,
      case IsImplicitlyDeleted
        when ' ' then IsImplicitlyDeleted
      else            IsImplicitlyDeleted
      end                                                      as IsImplicitlyDeleted,

      // ************************** Operation Header ***************************


      SubOperation,

      SuperiorOperationInternalID,

      // ************************** Operation General **************************

      //      @ObjectModel.text.element: 'SubOperationText'

      -- Operation
      SubOperationText,

      LongTextLanguageCode,

      Plant,

      case _WorkCenter.OpControlProfileIsReferenced
        when 'X' then _WorkCenter.OperationControlProfile
        else OperationControlProfile
      end                                                      as OperationControlProfile,

      case _WorkCenter.StandardTextIDIsReferenced
      when 'X' then _WorkCenter.StandardTextInternalID
      else OperationStandardTextCode
      end                                                      as OperationStandardTextCode,

      FactoryCalendar,

      -- Origin
      BillOfOperationsRefType,
      BillOfOperationsRefGroup,
      BillOfOperationsRefVariant,

      cast(CapacityCategoryCode as pph_kapart preserving type) as CapacityCategoryCode,

      -- Transfer to Orders     (-> Suboperations)
      OperationStdWorkQtyGrpgCat,

      // *************************** Administration ****************************


      -- Administrative Data
      CreationDate,
      CreatedByUser,

      LastChangeDate,
      LastChangedByUser,

      -- Validity
      ChangeNumber,

      cast(case when ValidityStartDate > ValidityStartDate
        then ValidityStartDate
        else ValidityStartDate
      end as pph_begda preserving type)                        as ValidityStartDate,
      cast(case when ValidityEndDate < ValidityEndDate
        then ValidityEndDate
        else ValidityEndDate
      end as pph_endda preserving type)                        as ValidityEndDate,

      // ************************** Processing Times ***************************


      -- Standard Values
      @Semantics.quantity.unitOfMeasure : 'OperationUnit'
      OperationReferenceQuantity,
      OperationUnit,

      OpQtyToBaseQtyNmrtr,
      OpQtyToBaseQtyDnmntr,
      @Semantics.quantity.unitOfMeasure : 'BillOfOperationsBreakDurnUnit'
      BillOfOperationsBreakDuration,
      BillOfOperationsBreakDurnUnit,

      _WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam1,
      @Semantics.quantity.unitOfMeasure : 'StandardWorkQuantityUnit1'
      StandardWorkQuantity1,
      StandardWorkQuantityUnit1,
      CostCtrActivityType1,
      PerfEfficiencyRatioCode1,

      _WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam2,
      @Semantics.quantity.unitOfMeasure : 'StandardWorkQuantityUnit2'
      StandardWorkQuantity2,
      StandardWorkQuantityUnit2,
      CostCtrActivityType2,
      PerfEfficiencyRatioCode2,

      _WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam3,
      @Semantics.quantity.unitOfMeasure : 'StandardWorkQuantityUnit3'
      StandardWorkQuantity3,
      StandardWorkQuantityUnit3,
      CostCtrActivityType3,
      PerfEfficiencyRatioCode3,

      _WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam4,
      @Semantics.quantity.unitOfMeasure : 'StandardWorkQuantityUnit4'
      StandardWorkQuantity4,
      StandardWorkQuantityUnit4,
      CostCtrActivityType4,
      PerfEfficiencyRatioCode4,

      _WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam5,
      @Semantics.quantity.unitOfMeasure : 'StandardWorkQuantityUnit5'
      StandardWorkQuantity5,
      StandardWorkQuantityUnit5,
      CostCtrActivityType5,
      PerfEfficiencyRatioCode5,

      _WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam6,
      @Semantics.quantity.unitOfMeasure : 'StandardWorkQuantityUnit6'
      StandardWorkQuantity6,
      StandardWorkQuantityUnit6,
      CostCtrActivityType6,
      PerfEfficiencyRatioCode6,

      BusinessProcess,

      // ************************ Interoperation Times *************************


      -- Lead Time Reduction
      LeadTimeReductionStrategy,

      --- Offset (for sub-operations)
      @Semantics.quantity.unitOfMeasure : 'StartDateOffsetDurationUnit'
      StartDateOffsetDuration,
      StartDateOffsetDurationUnit,


      @Semantics.quantity.unitOfMeasure : 'EndDateOffsetDurationUnit'
      EndDateOffsetDuration,
      EndDateOffsetDurationUnit,
      // ********************* Additional Operation Data ***********************


      --- General Data
      OperationScrapPercent,

      NumberOfTimeTickets,
      case _WorkCenter.NumberOfConfSlipsIsReferenced
      when 'X' then _WorkCenter.NumberOfConfirmationSlips
      else NumberOfConfirmationSlips
      end                                                      as NumberOfConfirmationSlips,

      cast(case _WorkCenter.EmployeeWageGroupIsReferenced
        when 'X' then _WorkCenter.EmployeeWageGroup
        else EmployeeWageGroup
      end as pph_logrp preserving type)                        as EmployeeWageGroup,
      cast(case _WorkCenter.EmployeeWageTypeIsReferenced
        when 'X' then _WorkCenter.EmployeeWageType
        else EmployeeWageType
      end as pph_loart preserving type)                        as EmployeeWageType,
      case _WorkCenter.EmplSuitabilityIsReferenced
        when 'X' then _WorkCenter.EmployeeSuitability
        else EmployeeSuitability
      end                                                      as EmployeeSuitability,
      NumberOfEmployees,

      -- Setup
      case _WorkCenter.WorkCenterSetpTypeIsReferenced
        when 'X' then _WorkCenter.WorkCenterSetupType
        else OperationSetupType
      end                                                      as OperationSetupType,
      OperationSetupGroupCategory,
      OperationSetupGroup,

      // ************************* Process Control Data ************************


      ControlRecipeDestination,

      // ************************ External Processing **************************


      -- External Processing
      @Semantics.booleanIndicator : true
      OpIsExtlyProcdWithSubcontrg,

      PurchasingInfoRecord,

      PurchasingOrganization,

      PurchaseContract,
      PurchaseContractItem,

      PurchasingInfoRecdAddlGrpgName,

      MaterialGroup,

      PurchasingGroup,

      Supplier,

      PlannedDeliveryDuration,

      NumberOfOperationPriceUnits,
      @Semantics.amount.currencyCode : 'OpExternalProcessingCurrency'
      OpExternalProcessingPrice,

      InspectionLotType,

      CostElement,

      OpExternalProcessingCurrency,

      OperationCostingRelevancyType,
      @ Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      _SubOperation.PurchaseOrderQty as PurchaseOrderQty,
      _SubOperation.PurchaseOrderQuantityUnit as PurchaseOrderQuantityUnit,
      
      // **************************** Associations *****************************


      _BOOOperationInternalID,
      _BOOSqncOperationAssgmtChgSt,
      _BillOfOperations,
      _BillOfOperationsGroup,
      _BillOfOperationsOperation,
      _BillOfOperationsSequence,
      _BillOfOperationsType,
      _BillOfOperationsBreakDurnUnit,
      _CapacityCategory,
      _ChangeMaster,
      _ControlRecipeDestination,
      _EndDateOffsetDurnUnit,
      _FactoryCalendar,
      _InspectionLotType,
      _LeadTimeReductionStrategy,
      _LongTextLanguage,
      _MaterialGroup,
      _OperationSetupGroup,
      _OperationSetupGroupCategory,
      _OperationStdWorkQtyGrpgCat,
      _OperationUnit,
      _OpExternalProcessingCurrency,
      _PerformanceEfficiencyRatio1,
      _PerformanceEfficiencyRatio2,
      _PerformanceEfficiencyRatio3,
      _PerformanceEfficiencyRatio4,
      _PerformanceEfficiencyRatio5,
      _PerformanceEfficiencyRatio6,
      _Plant,
      _PurchaseContract,
      _PurchaseContractItem,
      _PurchasingGroup,
      _PurchasingInfoRecord,
      _PurchasingOrganization,
      _Supplier,
      _WorkCenter,
      _WorkCenterType,
      _Operation,
      _NonHistOp,
      _Header
}
where
  (
       BillOfOperationsType = 'A' // General Maintenance Tasklist

    or BillOfOperationsType = 'T' // Functional Location Tasklist

    or BillOfOperationsType = 'E'
  ); // Equipment Tasklist

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BOOSUBOPERATIONCHANGESTATE",
"I_STANDARDWORKFMLAPARAMGROUP",
"I_WORKCENTER",
"R_MAINTTASKLISTOPBASICTP"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSOPERATION",
"I_BILLOFOPERATIONSSEQUENCE",
"I_BILLOFOPERATIONSTYPE",
"I_BOOOPERATIONINTERNALID",
"I_BOOSQNCOPERATIONASSGMTCHGST",
"I_CAPACITYCATEGORY",
"I_CHANGEMASTER",
"I_CONTROLRECIPEDESTINATION",
"I_CURRENCY",
"I_FACTORYCALENDAR",
"I_INSPECTIONLOTTYPE",
"I_LANGUAGE",
"I_LEADTIMEREDUCTIONSTRATEGY",
"I_MATERIALGROUP",
"I_OPERATIONSETUPGROUP",
"I_OPERATIONSETUPGROUPCATEGORY",
"I_OPERATIONSTDWORKQTYGRPGCAT",
"I_PERFORMANCEEFFICIENCYRATIO",
"I_PLANT",
"I_PURCHASECONTRACT",
"I_PURCHASECONTRACTITEM",
"I_PURCHASINGGROUP",
"I_PURCHASINGINFORECORDAPI01",
"I_PURCHASINGORGANIZATION",
"I_SUPPLIER",
"I_UNITOFMEASURE",
"I_WORKCENTER",
"I_WORKCENTERTYPE",
"R_MAINTENANCETASKLISTTP",
"R_MAINTTASKLISTOPBASICTP",
"R_MAINTTASKLISTOPERATIONTP"
],
"BASE":
[
"I_BOOSUBOPERATIONCHANGESTATE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/