R_InboundDeliveryTP

@EndUserText.label: 'Inbound Delivery - TP'
@AccessControl.authorizationCheck: #MANDATORY
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@ObjectModel: {
    usageType: {
        dataClass:      #TRANSACTIONAL,
        serviceQuality: #B,
        sizeCategory:   #L
    },
    sapObjectNodeType.name: 'InboundDelivery',
    semanticKey: ['InboundDelivery'],
    representativeKey: 'InboundDelivery'
}
@Metadata.ignorePropagatedAnnotations: true
define root view entity R_InboundDeliveryTP
  as select from I_DeliveryDocument as InboundDelivery
  composition [1..*] of R_InboundDeliveryItemTP as _Item
  composition [1..*] of R_InbDeliveryPartnerTP  as _Partner
  composition [0..*] of R_InboundDeliveryTextTP as _Text

  //Extensibility

  association [0..1] to E_DeliveryDocument      as _Extension on $projection.InboundDelivery = _Extension.DeliveryDocument

{

      // Key

      @Consumption.semanticObject: 'InboundDelivery'
  key DeliveryDocument                                              as InboundDelivery,

      // Category

      SDDocumentCategory,
      DeliveryDocumentType,
      // Admin

      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDate.createdAt: true
      CreationDate,
      @Semantics.systemTime.createdAt: true
      CreationTime,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      @Semantics.systemDate.lastChangedAt: true
      LastChangeDate,

      // Organization

      ShippingPoint                                                 as GoodsReceivingPoint,

      // Delivery

      @Semantics.booleanIndicator: true
      CompleteDeliveryIsDefined,
      DeliveryPriority,
      DeliveryBlockReason,
      DeliveryDocumentBySupplier,
      @Semantics.booleanIndicator: true
      DeliveryIsInPlant,
      DeliveryVersion,
      DocumentDate,
      ExternalIdentificationType,
      GoodsIssueOrReceiptSlipNumber                                 as GoodsMovementSlipNumber,
      @Semantics.quantity.unitOfMeasure: 'HeaderWeightUnit'
      HeaderGrossWeight,
      @Semantics.quantity.unitOfMeasure: 'HeaderWeightUnit'
      HeaderNetWeight,
      @Semantics.quantity.unitOfMeasure: 'HeaderVolumeUnit'
      HeaderVolume,
      HeaderVolumeUnit,
      HeaderWeightUnit,
      @Semantics.booleanIndicator: true
      IsExportDelivery,
      MeansOfTransportRefMaterial,
      @Semantics.booleanIndicator: true
      OrderCombinationIsAllowed,
      ReceivingPlant,
      SpecialProcessingCode,
      Supplier,
      Warehouse,
      WarehouseGate,
      WarehouseStagingArea,


      // Pick Pack Load

      TotalNumberOfPackage,
      LoadingDate,
      LoadingTime,
      BillOfLading,
      HandlingUnitInStock,

      // Shipping

      DeliveryDate,
      DeliveryTime,
      ShippingCondition,
      ShippingType,
      ShipmentBlockReason,
      TransportationPlanningDate,
      TransportationPlanningTime,
      RouteSchedule,
      PlannedGoodsIssueDate                                         as PlannedGoodsMovementDate,
      cast(GoodsIssueTime as le_wauhr preserving type)              as PlannedGoodsMovementTime,
      ActualGoodsMovementDate,
      cast(ActualGoodsMovementTime as le_wauhr_ist preserving type) as ActualGoodsMovementTime,
      IncotermsClassification,
      IncotermsTransferLocation,
      ExternalTransportSystem,
      TransportationGroup,
      MeansOfTransport,
      MeansOfTransportType,
      ProofOfDeliveryDate,
      ConfirmationTime                                              as ProofOfDeliveryTime,
      FactoryCalendarByCustomer,
      ShippingLocationTimeZone,
      ReceivingLocationTimeZone,

      // Billing

      IntercompanyBillingDate,
      BillingDocumentDate,
      HeaderBillingBlockReason,
      InternalFinancialDocument,
      PaymentGuaranteeProcedure,
      DepreciationPercentage                                        as DepreciationInPercent,

      // Sales

      CustomerGroup,
      TransactionCurrency,
      StatisticsCurrency,

      // Status

      OverallIntcoBillingStatus,
      OverallSDProcessStatus                                        as OverallDeliveryProcessStatus,
      TotalBlockStatus,
      OverallDelivConfStatus,
      TransportationPlanningStatus,
      OverallPickingConfStatus                                      as OverallPutawayConfStatus,
      OverallPickingStatus                                          as OverallPutawayStatus,
      OverallPackingStatus,
      OverallWarehouseActivityStatus,
      DistrStatusByDecentralizedWrhs,
      OverallGoodsMovementStatus,
      OverallDelivReltdBillgStatus,
      OverallProofOfDeliveryStatus,
      HdrGeneralIncompletionStatus,
      HeaderDelivIncompletionStatus,
      HeaderPickgIncompletionStatus                                 as HeaderPutawayIncompltnStatus,
      HeaderPackingIncompletionSts,
      HdrGoodsMvtIncompletionStatus,
      HeaderBillgIncompletionStatus,
      OvrlItmDelivIncompletionSts,
      OvrlItmGdsMvtIncompletionSts,
      OvrlItmGeneralIncompletionSts,
      OvrlItmPackingIncompletionSts,
      OvrlItmPickingIncompletionSts                                 as OvrlItmPutawayIncompletionSts,
      TotalCreditCheckStatus,

      /*Compositions*/
      _Item,
      _Partner,
      _Text

}
where
  SDDocumentCategory = '7';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DELIVERYDOCUMENT"
],
"ASSOCIATED":
[
"R_INBDELIVERYPARTNERTP",
"R_INBOUNDDELIVERYITEMTP",
"R_INBOUNDDELIVERYTEXTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/