R_InboundDeliveryItemTP

@EndUserText.label: 'Inbound Delivery Item - TP'
@AccessControl.authorizationCheck: #MANDATORY
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@ObjectModel: {
    usageType: {
        dataClass:      #TRANSACTIONAL,
        serviceQuality: #B,
        sizeCategory:   #XL
    },
    semanticKey: ['InboundDelivery', 'InboundDeliveryItem'],
    representativeKey: 'InboundDeliveryItem'
}
@Metadata.ignorePropagatedAnnotations: true
define view entity R_InboundDeliveryItemTP
  as select from I_DeliveryDocumentItem as InboundDeliveryItem
  composition [0..*] of R_InbDelivItemSerialNumberTP as _SerialNumber
  composition [0..*] of R_InbDelivItemTextTP         as _ItemText

  association        to parent R_InboundDeliveryTP   as _Delivery  on  $projection.InboundDelivery     = _Delivery.InboundDelivery

  //Extensibility

  association [0..1] to E_DeliveryDocumentItem       as _Extension on  $projection.InboundDelivery     = _Extension.DeliveryDocument
                                                                   and $projection.InboundDeliveryItem = _Extension.DeliveryDocumentItem
{
      // Key

      @ObjectModel.foreignKey.association: '_Delivery'
  key cast(DeliveryDocument as inbound_delivery preserving type) as InboundDelivery,
  key cast(DeliveryDocumentItem as inbound_delivery_item preserving type) as InboundDeliveryItem,

      // Admin

      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDate.createdAt: true
      CreationDate,
      @Semantics.systemTime.createdAt: true
      CreationTime,
      @Semantics.systemDate.lastChangedAt: true
      LastChangeDate,
  
      // Quantities

      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      cast(ActualDeliveredQtyInBaseUnit as le_lgmng2 preserving type)      as ActualDeliveredQtyInBaseUnit,
      DeliveryQuantityUnit          as OrderQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      cast(ActualDeliveryQuantity as le_lfimg2 preserving type)            as ActualDeliveredQtyInOrderUnit,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @ObjectModel.virtualElement:true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_LE_RAP_INBDLV_PUTAWAY_QTY'
      cast( 0.00 as pikmg_bu )      as PutawayQuantityInBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      @ObjectModel.virtualElement:true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_LE_RAP_INBDLV_PUTAWAY_QTY'
      cast( 0.00 as pikmg )         as PutawayQuantityInOrderUnit,
      QuantityIsFixed,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      OriginalDeliveryQuantity,
      BaseUnit,
      DeliveryToBaseQuantityDnmntr,
      DeliveryToBaseQuantityNmrtr,

      // Weight and Volume

      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      ItemGrossWeight,
      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      ItemNetWeight,
      ItemWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'ItemVolumeUnit'
      ItemVolume,
      ItemVolumeUnit,

      // Item Status

      PickingStatus                 as PutawayStatus,
      WarehouseActivityStatus,
      PickingConfirmationStatus     as PutawayConfirmationStatus,
      PackingStatus,
      GoodsMovementStatus,
      ProofOfDeliveryStatus,
      DeliveryRelatedBillingStatus,
      IntercompanyBillingStatus,
      SDProcessStatus               as DeliveryItemProcessStatus,
      ItemGeneralIncompletionStatus,
      ItemDeliveryIncompletionStatus,
      ItemPickingIncompletionStatus as ItemPutawayIncompletionStatus,
      ItemGdsMvtIncompletionSts,
      ItemPackingIncompletionStatus,
      ItemBillingIncompletionStatus,
      
      @Semantics.booleanIndicator: true
      IsCompletelyDelivered,

      // Quality Inspection

      InspectionLot,
      InspectionPartialLot,

      // Material

      Material,
      DeliveryDocumentItemText,
      MaterialByCustomer,
      AlternateProductNumber,
      CustEngineeringChgStatus,
      BOMExplosion,
      HigherLevelItem,
      InternationalArticleNumber,
      OriginallyRequestedMaterial,
      MaterialGroup,
      AdditionalMaterialGroup1,
      AdditionalMaterialGroup2,
      AdditionalMaterialGroup3,
      AdditionalMaterialGroup4,
      AdditionalMaterialGroup5,

      // Batch

      Batch,
      MaterialIsBatchManaged,
      ShelfLifeExpirationDate,
      ManufactureDate,
      BatchClassification,
      BatchBySupplier,
      HigherLvlItmOfBatSpltItm,
      NumberOfSerialNumbers,
      ProductConfiguration,
      ProductHierarchyNode,

      // Warehouse

      Plant,
      StorageLocation,
      StorageBin,
      StorageType,
      Warehouse,
      cast(WarehouseStorageBin as le_lgpbe preserving type)                as WarehouseStorageBin,
      WarehouseStagingArea,
      cast(WarehouseStockCategory as le_bestq preserving type)             as WarehouseStockCategory,
      
      ProductAvailabilityDate,
      ProductAvailabilityTime,

      // Loading and Shipment

      LoadingGroup,
      TransportationGroup,
      MaterialFreightGroup,
      FixedShipgProcgDurationInDays,
      VarblShipgProcgDurationInDays,
      ProofOfDeliveryRelevanceCode,

      // Financial Processing

      // Billing Document

      ItemIsBillingRelevant         as BillingRelevanceCode,
      ItemBillingBlockReason,
      PaymentGuaranteeForm,
      // Account Assignment

      BusinessArea,
      ControllingArea,
      CostCenter,
      ProfitCenter,
      OrderID                       as ManufacturingOrder,
      OrderItem                     as ManufacturingOrderItem,
      GLAccount,
      InventoryValuationType,
      IsSeparateValuation,
      DepartmentClassificationByCust,

      // Predecessor Data

      // Order

      ReferenceSDDocument,
      ReferenceSDDocumentItem,
      ReferenceSDDocumentCategory,
      ReferenceDocumentLogicalSystem,
      PartialDeliveryIsAllowed,
      UnlimitedOverdeliveryIsAllowed,
      OverdelivTolrtdLmtRatioInPct,
      UnderdelivTolrtdLmtRatioInPct,
      SalesDocumentItemType,

      // Organization

      DistributionChannel,
      Division,
      DeliveryGroup,
      DeliveryDocumentItemCategory,

      // Control

      GoodsMovementType,
      StockType,
      @Semantics.booleanIndicator: true
      IsNotGoodsMovementsRelevant,
      GoodsMovementReasonCode,
      InventorySpecialStockType,
      SubsequentMovementType,
      PrimaryPostingSwitch,
      ConsumptionPosting,
      StatisticsDate,

      AdditionalCustomerGroup1,
      AdditionalCustomerGroup2,
      AdditionalCustomerGroup3,
      AdditionalCustomerGroup4,
      AdditionalCustomerGroup5,

      // Stock Transfer Posting

      cast(IssgOrRcvgStockCategory as le_umbestq preserving type) as IssgOrRcvgStockCategory,
      IssgOrRcvgMaterial,
      IssuingOrReceivingPlant,
      IssuingOrReceivingStorageLoc,
      IssgOrRcvgBatch,
      IssgOrRcvgValuationType,
      IssgOrRcvgSpclStockInd                                      as IssgOrRcvgSpclStockCode,      

      /*Compositions*/
      _SerialNumber,
      _ItemText,

      /*Association*/
      _Delivery

}
where
  _Delivery.SDDocumentCategory = '7';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DELIVERYDOCUMENTITEM",
"R_INBOUNDDELIVERYTP"
],
"ASSOCIATED":
[
"R_INBDELIVITEMSERIALNUMBERTP",
"R_INBDELIVITEMTEXTTP",
"R_INBOUNDDELIVERYTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/