R_CustomerContactAttributeTP

@AccessControl: { authorizationCheck: #CHECK,
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED },
                  privilegedAssociations: [ '_CollectionSpecialistCard',
                                            '_CreatedByCard',
                                            '_ChangedByCard' ] }
@EndUserText: { label: 'Customer Contact' }
@VDM: { viewType:  #TRANSACTIONAL,
        lifecycle: { contract: { type: #SAP_INTERNAL_API } } } 
@ObjectModel: { usageType:                      { serviceQuality: #A,
                                                  sizeCategory:   #L,
                                                  dataClass:      #TRANSACTIONAL },
                semanticKey:                    [ 'CustomerContactUUID',
                                                  'CollectionSegment' ],
                representativeKey:              'CustomerContactUUID',
                modelCategory:                  #BUSINESS_OBJECT,
                transactionalProcessingEnabled: true,
                sapObjectNodeType:              { name: 'CollectionsCustomerContact' } }

define root view entity R_CustomerContactAttributeTP
  as select from I_CustomerContactAttribute

  // BO Associations

  composition [0..*] of R_CustomerContactRelationTP  as _CustomerContactRelation
  
  //BO Colls Email hinzufügen, vorher root entity raus


  // VDM Associations

  // Collection Contact

  association [0..*] to I_CollectionContact          as _CollectionContact        on  $projection.BusinessPartner   = _CollectionContact.BusinessPartnerCompany
                                                                                  and $projection.CollectionSegment = _CollectionContact.CollectionSegment

  // Collection Specialist Contact Card

  association [0..1] to R_RblsMgmtUserContactCard    as _CollectionSpecialistCard on  $projection.CollectionSpecialist = _CollectionSpecialistCard.ContactCardID

  // Created By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard    as _CreatedByCard            on  $projection.CreatedByUser = _CreatedByCard.ContactCardID

  // Changed By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard    as _ChangedByCard            on  $projection.ChangedBy = _ChangedByCard.ContactCardID

  // Business Partner Quick View Facet

  association [0..1] to R_BPCollectionsSgmtQuickView as _CollectionsBPQuickView   on  $projection.BusinessPartner   = _CollectionsBPQuickView.BusinessPartner
                                                                                  and $projection.CollectionSegment = _CollectionsBPQuickView.CollectionSegment

{

      // VDM Fields

  key CustomerContactUUID,

      @ObjectModel: { foreignKey: { association: '_CollectionsBPQuickView' } }
      BusinessPartner,

      CollectionSegment,
      CollectionCustomerContact,

      @ObjectModel: { foreignKey: { association: '_CollectionSpecialistCard' } }
      CollectionSpecialist,

      ContactPerson,
      ContactPersonName,
      ContactPersonEmailAddress,
      ContactPersonPhoneNumber,
      ContactPersonFaxNumber,
      ContactPersonFaxCountry,
      CustomerContactDirection,
      CustomerContactType,
      CustomerContactResult,
      CustomerIsReached,
      CustomerContactDateTime,
      CustContactDurationInMinutes,

      @ObjectModel: { foreignKey: { association: '_CreatedByCard' } }
      CreatedByUser,

      CreationDateTime,

      @ObjectModel: { foreignKey: { association: '_ChangedByCard' } }
      ChangedBy,

      ChangedOnDateTime,
      CollectionWorklistItemUUID,

      // Exposed Associations

      _BusinessPartner,
      _ChangedByCard,
      _CollectionSegment,
      _CollectionSpecialistCard,
      _CollectionWorklistItem,
      _Country,
      _CreatedByCard,
      _CustomerContactDirection,
      _CustomerContactRelation,
      _CustomerContactResult,
      _CustomerContactType,
      _CustomerContact,
      _CollectionContact,
      _CollectionsBPQuickView

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMERCONTACTATTRIBUTE"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_COLLECTIONCONTACT",
"I_COLLECTIONSEGMENT",
"I_COLLECTIONWORKLISTITEM",
"I_COUNTRY",
"I_CUSTOMERCONTACT",
"I_CUSTOMERCONTACTDIRECTION",
"I_CUSTOMERCONTACTRESULT",
"I_CUSTOMERCONTACTTYPE",
"R_BPCOLLECTIONSSGMTQUICKVIEW",
"R_CUSTOMERCONTACTRELATIONTP",
"R_RBLSMGMTUSERCONTACTCARD"
],
"BASE":
[
"I_CUSTOMERCONTACTATTRIBUTE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/