C_CustomerContactAttributeTP

@Metadata: { allowExtensions: true }
@VDM: { usage: { type:     [ #TRANSACTIONAL_PROCESSING_SERVICE ] },
	             viewType: #CONSUMPTION }
@AccessControl: { personalData:           { blocking: #BLOCKED_DATA_EXCLUDED },
	              privilegedAssociations: [ '_ChangedByCard',
		                                      '_CreatedByCard',
		                                      '_CollectionSpecialistCard' ],
	              authorizationCheck: #CHECK }
@ObjectModel: { usageType: { serviceQuality: #X,
    		                     sizeCategory:   #L,
    		                     dataClass:      #TRANSACTIONAL },
	            representativeKey: 'CustomerContactUUID',
	            semanticKey: [ 'BusinessPartner',
		                         'CustomerContactUUID',
		                         'CollectionSegment' ] }
@EndUserText: { label: 'Customer Contact' }

define root view entity C_CustomerContactAttributeTP
  provider contract transactional_query
  as projection on R_CustomerContactAttributeTP
{

          // VDM Fields

  key     CustomerContactUUID,

          @ObjectModel: { text: { element: [ 'BusinessPartnerName' ] } }
          BusinessPartner,

          @ObjectModel: { text: { element: [ 'CollectionSegmentName' ] } }
          CollectionSegment,

          CollectionCustomerContact,

          @ObjectModel: { text: { element: [ 'CollectionSpecialistUserName' ] } }
          CollectionSpecialist,

          ContactPerson,
          ContactPersonName,
          ContactPersonEmailAddress,
          ContactPersonPhoneNumber,
          ContactPersonFaxNumber,

          @ObjectModel: { text: { element: [ 'CountryName' ] } }
          ContactPersonFaxCountry,

          @ObjectModel: { text: { element: [ 'CustomerContactDirectionName' ] } }
          CustomerContactDirection,

          @ObjectModel: { text: { element: [ 'CustomerContactTypeName' ] } }
          CustomerContactType,

          @ObjectModel: { text: { element: [ 'CustomerContactResultText' ] } }
          CustomerContactResult,

          CustomerIsReached,
          CustomerContactDateTime,
          CustContactDurationInMinutes,

          @ObjectModel: { text: { element: [ 'CreatedByUserName' ] } }
          CreatedByUser,

          CreationDateTime,

          @ObjectModel: { text: { element: [ 'ChangedByUserName' ] } }
          ChangedBy,

          ChangedOnDateTime,
          CollectionWorklistItemUUID,

          // Elements for Free Search

          _BusinessPartner.OrganizationBPName1,
          _BusinessPartner.OrganizationBPName2,
          _CollectionSpecialistCard.FirstName                          as UICT_SpecialistFirstName,
          _CollectionSpecialistCard.LastName                           as UICT_SpecialistLastName,
          _CreatedByCard.FirstName                                     as UICT_CreatedByFirstName,
          _CreatedByCard.LastName                                      as UICT_CreatedByLastName,
          _ChangedByCard.FirstName                                     as UICT_ChangedByFirstName,
          _ChangedByCard.LastName                                      as UICT_ChangedByLastName,

          // Text Elements

          _BusinessPartner.BusinessPartnerName                         as BusinessPartnerName,
          _CollectionSegment._Text.CollectionSegmentName               as CollectionSegmentName        : localized,
          _CreatedByCard.UserDescription                               as CreatedByUserName,
          _ChangedByCard.UserDescription                               as ChangedByUserName,
          _CollectionSpecialistCard.UserDescription                    as CollectionSpecialistUserName,
          _CustomerContactDirection._Text.CustomerContactDirectionName as CustomerContactDirectionName : localized,
          _CustomerContactType._Text.CustomerContactTypeName           as CustomerContactTypeName      : localized,
          _CustomerContactResult._Text.CustomerContactResultText       as CustomerContactResultText    : localized,
          _Country._Text.CountryName                                   as CountryName                  : localized,

          // Virtual Elements

          @ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COLL_CCT_VE' }
  virtual Customer : kunnr,

          // Exposed Associations

          _BusinessPartner,
          _ChangedByCard            : redirected to C_RblsMgmtUserContactCard,
          _CollectionSegment,
          _CollectionSpecialistCard : redirected to C_RblsMgmtUserContactCard,
          _CollectionWorklistItem,
          _Country,
          _CreatedByCard            : redirected to C_RblsMgmtUserContactCard,
          _CustomerContactDirection,
          _CollectionsBPQuickView   : redirected to C_BPCollectionsSgmtQuickView,
          _CustomerContactResult,
          _CustomerContactType,
          _CustomerContact,
          _CollectionContact,

          // BO Composition

          _CustomerContactRelation  : redirected to composition child C_CustomerContactRelationTP

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_COLLECTIONSEGMENT",
"I_COLLECTIONSEGMENTTEXT",
"I_COUNTRY",
"I_COUNTRYTEXT",
"I_CUSTOMERCONTACTDIRECTION",
"I_CUSTOMERCONTACTDIRECTIONTEXT",
"I_CUSTOMERCONTACTRESULT",
"I_CUSTOMERCONTACTRESULTTEXT",
"I_CUSTOMERCONTACTTYPE",
"I_CUSTOMERCONTACTTYPETEXT",
"R_CUSTOMERCONTACTATTRIBUTETP",
"R_RBLSMGMTUSERCONTACTCARD"
],
"ASSOCIATED":
[
"C_BPCOLLECTIONSSGMTQUICKVIEW",
"C_CUSTOMERCONTACTRELATIONTP",
"C_RBLSMGMTUSERCONTACTCARD",
"I_BUSINESSPARTNER",
"I_COLLECTIONCONTACT",
"I_COLLECTIONSEGMENT",
"I_COLLECTIONWORKLISTITEM",
"I_COUNTRY",
"I_CUSTOMERCONTACT",
"I_CUSTOMERCONTACTDIRECTION",
"I_CUSTOMERCONTACTRESULT",
"I_CUSTOMERCONTACTTYPE",
"R_BPCOLLECTIONSSGMTQUICKVIEW",
"R_CUSTOMERCONTACTRELATIONTP",
"R_RBLSMGMTUSERCONTACTCARD"
],
"BASE":
[
"R_CUSTOMERCONTACTATTRIBUTETP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/