R_CreditMemoRequestItemTextTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}

@ObjectModel.semanticKey: ['CreditMemoRequest', 'CreditMemoRequestItem', 'Language', 'LongTextID']

@Metadata.ignorePropagatedAnnotations: true

@AccessControl.authorizationCheck: #CHECK

@EndUserText.label: 'Credit Memo Request Item - Text TP'
define view entity R_CreditMemoRequestItemTextTP
  as select from P_SalesDocumentItemText( P_SAPClient : $session.client ) as CreditMemoRequestItemText 

  inner join   I_SalesDocumentItemBasic               as SalesDocumentItemBasic       on  SalesDocumentItemBasic.SalesDocument      = CreditMemoRequestItemText.SalesDocument
                                                                                      and SalesDocumentItemBasic.SalesDocumentItem  = CreditMemoRequestItemText.SalesDocumentItem
                                                                                      and SalesDocumentItemBasic.SDDocumentCategory = 'K'

  inner join   I_SalesDocumentItemCategory            as SalesDocumentItemCategory    on SalesDocumentItemCategory.SalesDocumentItemCategory = SalesDocumentItemBasic.SalesDocumentItemCategory

  association to parent R_CreditMemoRequestItemTP     as _Item                        on  $projection.CreditMemoRequest     = _Item.CreditMemoRequest
                                                                                      and $projection.CreditMemoRequestItem = _Item.CreditMemoRequestItem

  association [0..*] to I_TextDeterminationProcedItem as _TextDeterminationProcedItem on  $projection.TextDeterminationProcedure          = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                      and $projection.LongTextID                          = _TextDeterminationProcedItem.LongTextID
                                                                                      and _TextDeterminationProcedItem.TextObjectCategory = 'VBBP'

  association [1..1] to R_CreditMemoRequestTP         as _CreditMemoRequest           on  $projection.CreditMemoRequest = _CreditMemoRequest.CreditMemoRequest

  association [0..1] to I_Language                    as _Language                    on  $projection.LanguageForEdit = _Language.Language

  association [0..1] to I_SDDocumentItemLongTextID    as _LongTextID                  on  $projection.LongTextIDForEdit = _LongTextID.LongTextID

{
  key cast(CreditMemoRequestItemText.SalesDocument as credit_memo_request preserving type)  as CreditMemoRequest,

  key cast(CreditMemoRequestItemText.SalesDocumentItem as credit_memo_request_item preserving type) as CreditMemoRequestItem,

  key CreditMemoRequestItemText.Language,

  key CreditMemoRequestItemText.LongTextID,

      @ObjectModel.foreignKey.association: '_LongTextID'
      CreditMemoRequestItemText.LongTextID                                                  as LongTextIDForEdit,

      @ObjectModel.foreignKey.association: '_Language'
      CreditMemoRequestItemText.Language                                                    as LanguageForEdit,

      CreditMemoRequestItemText.LongText,

      @Consumption.hidden: true
      SalesDocumentItemCategory.TextDeterminationProcedure,

      _TextDeterminationProcedItem.TextDeterminationProcedureItem                           as TextDeterminationProcedureItem,

      //    For Access control

      @Consumption.hidden: true
      SalesDocumentItemBasic.SalesDocumentType                                              as CreditMemoRequestType,
      @Consumption.hidden: true
      SalesDocumentItemBasic.OrganizationDivision,
      @Consumption.hidden: true
      SalesDocumentItemBasic.SalesOrganization,
      @Consumption.hidden: true
      SalesDocumentItemBasic.DistributionChannel,

      //     Exposed associations

      _Item,
      _CreditMemoRequest,
      _Language,
      _LongTextID
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESDOCUMENTITEMBASIC",
"I_SALESDOCUMENTITEMCATEGORY",
"I_TEXTDETERMINATIONPROCEDITEM"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_SDDOCUMENTITEMLONGTEXTID",
"R_CREDITMEMOREQUESTITEMTP",
"R_CREDITMEMOREQUESTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/