R_CollsMgmtBusinessPartnerTP

@AccessControl: { authorizationCheck: #CHECK,
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED } }
@EndUserText: { label: 'Collections Management: Business Partner' }
@VDM: { viewType:  #TRANSACTIONAL,
        lifecycle: { contract: { type: #SAP_INTERNAL_API } } }
@ObjectModel: { usageType:         { serviceQuality: #X,
                                     sizeCategory:   #L,
                                     dataClass:      #TRANSACTIONAL },
                semanticKey:       [ 'BusinessPartner' ],
                representativeKey: 'BusinessPartner',
                sapObjectNodeType: { name: 'CollectionsManagementAccount' } }

define root view entity R_CollsMgmtBusinessPartnerTP
  as select distinct from  I_BusinessPartner
    inner join             I_BusinessPartnerToBPRole   on I_BusinessPartner.BusinessPartner = I_BusinessPartnerToBPRole.BusinessPartner
    inner join             I_BusinessPartnerCustomer   on I_BusinessPartner.BusinessPartner = I_BusinessPartnerCustomer.BusinessPartner
    left outer to one join I_BPCollectionProfileAssgmt on  I_BusinessPartner.BusinessPartner                       = I_BPCollectionProfileAssgmt.BusinessPartner
                                                       and I_BPCollectionProfileAssgmt.BPCollPrflAssignmentValidTo = '99991231'

  // VDM Associations

  // Business Partner

  association [0..1] to I_BusinessPartner             as _BusinessPartner on $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  // Customer

  association [0..1] to I_Customer                    as _Customer        on $projection.Customer = _Customer.Customer

  // BO Composition

  // Collections Profile

  composition [0..1] of R_BusPartCollsProfileAssgmtTP as _BusPartCollsProfileAssgmtTP

  // Collections Segment

  composition [0..*] of R_BPCollsSegmentAssignmentTP  as _BPCollsSegmentAssignmentTP

{
      // VDM Fields

  key I_BusinessPartner.BusinessPartner,
      I_BusinessPartnerCustomer.Customer,

      @Semantics: { systemDateTime : { lastChangedAt: true } }
      I_BPCollectionProfileAssgmt.LastChangeDateTime,

      // Exposed Associations

      _BusinessPartner,
      _Customer,

      // BO Compositions

      _BusPartCollsProfileAssgmtTP,
      _BPCollsSegmentAssignmentTP
}
where
  I_BusinessPartnerToBPRole._BusinessPartnerRole.RoleCategory = 'UDM000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPCOLLECTIONPROFILEASSGMT",
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNERCUSTOMER",
"I_BUSINESSPARTNERROLE",
"I_BUSINESSPARTNERTOBPROLE"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CUSTOMER",
"R_BPCOLLSSEGMENTASSIGNMENTTP",
"R_BUSPARTCOLLSPROFILEASSGMTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/