R_BusinessSolutionQuotationTP

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata:
{
  ignorePropagatedAnnotations: true
}

@EndUserText.label: 'Business Solution Quotation - TP'
@ObjectModel.sapObjectNodeType.name: 'BusinessSolutionQuotation'
@ObjectModel: {
  semanticKey: ['BusinessSolutionQuotation'],
  representativeKey: 'BusinessSolutionQuotation',
  usageType: {dataClass:      #TRANSACTIONAL,
              serviceQuality: #C,
              sizeCategory:   #L}
}
define root view entity R_BusinessSolutionQuotationTP
  as select from I_ServiceDocumentEnhcd     as ServiceDocumentEnhcd
    inner join   I_BusSolutionQuotationType as BusSolutionQuotationType on BusSolutionQuotationType.BusSolutionQuotationType = ServiceDocumentEnhcd.ServiceDocumentType

  association [0..1] to I_SrvcLifeCycleSystemStatusT as _LifecycleUserStsText on  $projection.ServiceDocumentStatus      = _LifecycleUserStsText.SrvcLifeCycleSystemStatus
                                                                                        and _LifecycleUserStsText.Language = $session.system_language
  association [0..1] to I_SrvcMgmtBPQuickView_2        as _SrvcDocBPRespEmployee        on  $projection.RespEmployeeBusinessPartnerId = _SrvcDocBPRespEmployee.BusinessPartner

  association [1]    to I_SrvcDocRejectionStatus       as _ServiceDocCancelled          on  $projection.BusSolnQuotationIsRejected = _ServiceDocCancelled.ServiceDocumentIsRejected

  association [1]    to I_SrvcDocReleaseStatus         as _ServiceDocReleaseStatus      on  $projection.BusSolnQuotationIsReleased = _ServiceDocReleaseStatus.ServiceDocumentIsReleased

  association [0..1] to I_ServiceDocumentPriorityText  as _ServiceDocumentPriorityText  on  $projection.ServiceDocumentPriority   = _ServiceDocumentPriorityText.ServiceDocumentPriority
                                                                                        and _ServiceDocumentPriorityText.Language = $session.system_language

  association [1]    to I_BusinessPartner              as _ServiceDocCreatedBy          on  $projection.ServiceDocumentCreatedByUser = _ServiceDocCreatedBy.BusinessPartner

  association [1] to P_BusSolnQtanAcceptanceStatus  as _SolnQtanAccptcStatus         on  $projection.BusinessSolutionQuotation = _SolnQtanAccptcStatus.BusinessSolutionQuotation

  composition [0..*] of R_BusSolnQtanItemTP  as _BusinessSolutionQtanItemTP
{
  key ServiceDocumentEnhcd.ServiceDocument                       as BusinessSolutionQuotation,
      ServiceDocumentEnhcd.ServiceObjectType                     as CustMgmtObjectType,
      ServiceDocumentEnhcd.ServiceDocumentType                   as BusSolutionQuotationType,
      ServiceDocumentEnhcd.ServiceDocumentUUID                   as BusSolutionQuotationUUID,
      ServiceDocumentEnhcd.ServiceDocumentDescription            as BusSolnQtanDescription,

      // Organizational Data

      @ObjectModel.foreignKey.association: '_SalesOrganization'
      ServiceDocumentEnhcd.SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      ServiceDocumentEnhcd.DistributionChannel,
      @ObjectModel.foreignKey.association: '_Division'
      ServiceDocumentEnhcd.Division,
      @ObjectModel.foreignKey.association: '_SalesOffice'
      ServiceDocumentEnhcd.SalesOffice,
      @ObjectModel.foreignKey.association: '_SalesGroup'
      ServiceDocumentEnhcd.SalesGroup,

      //CRM Org units

      //these fields are only ON PREMISE

      @Feature: 'BF:API_FULLSCOPE'
      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit_2'
      ServiceDocumentEnhcd.SalesOrganizationOrgUnitID,
      @Feature: 'BF:API_FULLSCOPE'
      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit_2'
      ServiceDocumentEnhcd.SalesOfficeOrgUnitID,
      @Feature: 'BF:API_FULLSCOPE'
      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit_2'
      ServiceDocumentEnhcd.SalesGroupOrgUnitID,
      @Feature: 'BF:API_FULLSCOPE'
      @ObjectModel.foreignKey.association: '_ServiceOrganizationOrgUnit_2'
      ServiceDocumentEnhcd.ServiceOrganization,

      //Partners

      @ObjectModel.foreignKey.association: '_RespEmployee'
      ServiceDocumentEnhcd.ResponsibleEmployee                   as RespEmployeeBusinessPartnerId,


      //Fields added for ListReport- Solution Quotation Manage Page

      @ObjectModel.foreignKey.association: '_SoldToParty'
      ServiceDocumentEnhcd.SoldToParty,

      ServiceDocumentEnhcd.ServiceDocumentStatus,
      _LifecycleUserStsText.SrvcLifeCycleSystemStatusName as ServiceDocumentStatusName,


      ServiceDocumentEnhcd.ServiceDocumentCreationDate           as CreationDate,

      ServiceDocumentEnhcd.ServiceDocumentCreatedByUser,

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      ServiceDocumentEnhcd.TransactionCurrency,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      ServiceDocumentEnhcd.ServiceDocNetAmount,

      @Semantics.booleanIndicator
      ServiceDocumentEnhcd.ServiceDocumentHasError,

      cast(ServiceDocumentEnhcd.PurchaseOrderByCustomer as crmt_ext_ref_num )               as BusSolnQtanExtReference,

      ServiceDocumentEnhcd.PostingDate,

      ServiceDocumentEnhcd.SoldToPartyCountry,

      ServiceDocumentEnhcd.ServiceDocumentPriority,

      ServiceDocumentEnhcd.BillToParty,

      ServiceDocumentEnhcd.PayerParty,

      @Semantics.booleanIndicator
      ServiceDocumentEnhcd.ServiceDocumentIsRejected             as BusSolnQuotationIsRejected,

      @Semantics.booleanIndicator
      ServiceDocumentEnhcd.ServiceDocumentIsReleased             as BusSolnQuotationIsReleased,

      ServiceDocumentEnhcd.SrvcQuotationValidityStartDate,
      ServiceDocumentEnhcd.SrvcQuotationValidityEndDate,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      ServiceDocumentEnhcd.ServiceDocGrossAmount,
      ServiceDocumentEnhcd.ContactPerson                         as ContactPersonBusinessPartnerId,
      ServiceDocumentEnhcd._ContactPerson.BusinessPartnerName    as ContactPersonName,

      @Semantics.booleanIndicator
      _SolnQtanAccptcStatus.QuotationIsAccepted,
      _SolnQtanAccptcStatus._SolnQtanAcceptanceStatusText.SrvcDocAcceptanceStatusText,
//      _SolnQtanAccptcStatusText.ddtext,

      //'Y'       as BusSolutionQuotationIsAccepted,

      ServiceDocumentEnhcd._SoldToParty,
      ServiceDocumentEnhcd._TransactionCurrency,
      ServiceDocumentEnhcd._ServiceDocHasError,
      ServiceDocumentEnhcd._ServiceObjType,
      ServiceDocumentEnhcd._ContactPerson,

      //End of Fields added for ListReport


      ServiceDocumentEnhcd._SalesOrganization,
      ServiceDocumentEnhcd._DistributionChannel,
      ServiceDocumentEnhcd._Division,
      ServiceDocumentEnhcd._SalesOffice,
      ServiceDocumentEnhcd._SalesGroup,
      ServiceDocumentEnhcd._SalesOrganizationOrgUnit_2,
      ServiceDocumentEnhcd._SalesOfficeOrgUnit_2,
      ServiceDocumentEnhcd._SalesGroupOrgUnit_2,
      ServiceDocumentEnhcd._ServiceOrganizationOrgUnit_2,
      ServiceDocumentEnhcd._RespEmployee,

      //Associations

      _BusinessSolutionQtanItemTP,
      _LifecycleUserStsText,
      _SrvcDocBPRespEmployee,
      _ServiceDocCancelled,
      _ServiceDocReleaseStatus,
      _ServiceDocCreatedBy,
      _ServiceDocumentPriorityText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_BUSSOLUTIONQUOTATIONTYPE",
"I_SERVICEDOCUMENTENHCD",
"I_SRVCLIFECYCLESYSTEMSTATUST",
"I_SRVCQTANACCEPTANCESTATUSTEXT",
"P_BUSSOLNQTANACCEPTANCESTATUS"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CURRENCY",
"I_CUSTMGMTBUSOBJTYPE",
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_SALESGROUP",
"I_SALESOFFICE",
"I_SALESORGANIZATION",
"I_SERVICEDOCERRORSTATUS",
"I_SERVICEDOCUMENTPRIORITYTEXT",
"I_SRVCDOCREJECTIONSTATUS",
"I_SRVCDOCRELEASESTATUS",
"I_SRVCLIFECYCLESYSTEMSTATUST",
"I_SRVCMGMTBPQUICKVIEW_2",
"I_SRVCMGMTORGANIZATIONUNIT",
"R_BUSSOLNQTANITEMTP"
],
"BASE":
[
"I_SERVICEDOCUMENTENHCD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/