R_BusSolnQtanItemTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@EndUserText.label: 'Business Solution Quotation Item - TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@ObjectModel.usageType:{
  dataClass:      #MIXED,
    serviceQuality: #C,
    sizeCategory:   #XXL
}
define view entity R_BusSolnQtanItemTP
  as select from I_ServiceDocumentItemEnhcd as _ServiceDocumentItemEnhcd
  inner join I_BusSolutionQuotationType as _BusSolutionQuotationType on _ServiceDocumentItemEnhcd.ServiceDocumentType = _BusSolutionQuotationType.BusSolutionQuotationType
  association to parent R_BusinessSolutionQuotationTP as _BusinessSolutionQuotation on $projection.BusinessSolutionQuotation = _BusinessSolutionQuotation.BusinessSolutionQuotation
  association[1] to I_SrvcDocLifecycleStatusText as _SrvcDocLifecycleStatusText on $projection.ServiceDocumentItemStatus = _SrvcDocLifecycleStatusText.ServiceDocumentStatus
                                                 and _SrvcDocLifecycleStatusText.Language = $session.system_language
  association[0..1] to I_ServiceDocItemCategoryText as _ServiceDocItemCategoryText on $projection.BusSolnQtanItemCategory = _ServiceDocItemCategoryText.ServiceDocItemCategory
                                                    and _ServiceDocItemCategoryText.Language = $session.system_language
{
  key _ServiceDocumentItemEnhcd.ServiceDocument                as BusinessSolutionQuotation,
  key _ServiceDocumentItemEnhcd.ServiceObjectType              as CustMgmtObjectType,
  key _ServiceDocumentItemEnhcd.ServiceDocumentItem,

      @ObjectModel.foreignKey.association: '_Product'
      _ServiceDocumentItemEnhcd.Product,
      _ServiceDocumentItemEnhcd.ServiceDocumentItemDescription as BusSolnQtanItemDescription,

      _ServiceDocumentItemEnhcd.ServiceDocItemCategory         as BusSolnQtanItemCategory,
      _ServiceDocumentItemEnhcd.ServiceDocumentItemObjectType,
      _ServiceDocItemCategoryText.SrvcDocItmCategoryShortName,

      @Semantics.uuid: true
      _ServiceDocumentItemEnhcd.ServiceDocumentItemUUID,

      @Semantics.uuid: true
      _ServiceDocumentItemEnhcd.ParentServiceDocumentItemUUID,

      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      _ServiceDocumentItemEnhcd.ServiceDocumentItemQuantity    as Quantity,

      _ServiceDocumentItemEnhcd.ServiceDocItemQuantityUnit     as QuantityUnit,

      // Pricing

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      _ServiceDocumentItemEnhcd.TransactionCurrency,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      _ServiceDocumentItemEnhcd.ServiceDocumentItemNetAmount,

      _ServiceDocumentItemEnhcd.ServiceDocumentItemStatus,

      _SrvcDocLifecycleStatusText.ServiceDocumentStatusName,


      @ObjectModel.sapObjectNodeTypeReference: 'ServiceDocumentType'
      _ServiceDocumentItemEnhcd.ServiceDocumentType,

      _ServiceDocumentItemEnhcd.SalesGroup,
      _ServiceDocumentItemEnhcd.SalesOffice,
      _ServiceDocumentItemEnhcd.Division,
      _ServiceDocumentItemEnhcd.DistributionChannel,
      _ServiceDocumentItemEnhcd.SalesOrganization,
      _ServiceDocumentItemEnhcd.SalesOrganizationOrgUnitID,
      _ServiceDocumentItemEnhcd.ServiceOrganization,
      _ServiceDocumentItemEnhcd.SalesGroupOrgUnitID,
      _ServiceDocumentItemEnhcd.SalesOfficeOrgUnitID,

      @Semantics.text: true
      @ObjectModel.foreignKey.association: '_RespEmployee'
      _ServiceDocumentItemEnhcd.ResponsibleEmployee as RespEmployeeBusinessPartnerId,

      _ServiceDocumentItemEnhcd._ServiceDocItemCategory,

      //Associations

      _BusinessSolutionQuotation,
      _SrvcDocLifecycleStatusText,
      _ServiceDocItemCategoryText,
      _ServiceDocumentItemEnhcd._ServiceDocument,
      _ServiceDocumentItemEnhcd._ServiceObjType,
      _ServiceDocumentItemEnhcd._TransactionCurrency,
      _ServiceDocumentItemEnhcd._ServiceDocItemStatus,
      _ServiceDocumentItemEnhcd._ServiceDocumentType,
      _ServiceDocumentItemEnhcd._Product,
      _ServiceDocumentItemEnhcd._RespEmployee

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSSOLUTIONQUOTATIONTYPE",
"I_SERVICEDOCITEMCATEGORYTEXT",
"I_SERVICEDOCUMENTITEMENHCD",
"I_SRVCDOCLIFECYCLESTATUSTEXT"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CURRENCY",
"I_CUSTMGMTBUSOBJTYPE",
"I_PRODUCT",
"I_SERVICEDOCITEMCATEGORY",
"I_SERVICEDOCITEMCATEGORYTEXT",
"I_SERVICEDOCUMENTENHCD",
"I_SERVICEDOCUMENTSTATUS",
"I_SERVICEDOCUMENTTYPE",
"I_SRVCDOCLIFECYCLESTATUSTEXT",
"R_BUSINESSSOLUTIONQUOTATIONTP"
],
"BASE":
[
"I_SERVICEDOCUMENTITEMENHCD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/