R_BusinessSolutionOrderItemTP

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@ObjectModel: {
  semanticKey: ['BusinessSolutionOrderItem'],
  representativeKey: 'BusinessSolutionOrderItem',
  usageType:{
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory:   #L
  }
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@EndUserText.label: 'Business Solution Order Item -TP'

define view entity R_BusinessSolutionOrderItemTP
  as select from I_ServiceDocumentItemEnhcd

  association        to parent R_BusinessSolutionOrderTP as _BusinessSolutionOrder   on  $projection.BusinessSolutionOrder = _BusinessSolutionOrder.BusinessSolutionOrder

  association [1..1] to I_ServiceDocumentItemEnhcd       as _ServiceDocItemEnhcd     on  $projection.BusinessSolutionOrder      = _ServiceDocItemEnhcd.ServiceDocument
                                                                                     and $projection.BusinessSolutionOrderItem  = _ServiceDocItemEnhcd.ServiceDocumentItem
                                                                                     and _ServiceDocItemEnhcd.ServiceObjectType = 'BUS2000172'

  association [0..1] to I_CustMgmtExtRefID               as _ItemExternalReference   on  $projection.BusinessSolutionOrder           = _ItemExternalReference.CustMgmtDocument
                                                                                     and $projection.BusinessSolutionOrderItem       = _ItemExternalReference.CustMgmtDocumentItem
                                                                                     and _ItemExternalReference.CustMgmtObjectType   = 'BUS2000172'
                                                                                     and _ItemExternalReference.CustMgmtExtRefIDType = '0013'

  association [0..1] to I_CustMgmtExtRefID               as _HeaderExternalReference on  $projection.BusinessSolutionOrder             = _HeaderExternalReference.CustMgmtDocument
                                                                                     and _HeaderExternalReference.CustMgmtObjectType   = 'BUS2000172'
                                                                                     and _HeaderExternalReference.CustMgmtExtRefIDType = '0012'

  association [0..1] to I_BusinessPartner                as _RespEmployee            on  $projection.RespEmployeeBusinessPartnerId = _RespEmployee.BusinessPartner

  association [0..1] to I_ServiceDocumentItemPrdcssr_3   as _ReferenceSrvcContract   on  $projection.ServiceDocumentItemCharUUID               = _ReferenceSrvcContract.ServiceDocumentItemCharUUID
                                                                                     and _ReferenceSrvcContract.ServiceDocItmPrdcssrBusObjType = 'BUS2000137'
 
  association [0..1] to I_SrvcMgmtObjectStatus         as _BusSolnOrdItemStatus    on  $projection.BusinessSolutionOrderItemUUID = _BusSolnOrdItemStatus.SrvcMgmtObjectUUID
                                                                                     and (
                                                                                        _BusSolnOrdItemStatus.SrvcMgmtObjectStatus          = 'I1002'
                                                                                        or _BusSolnOrdItemStatus.SrvcMgmtObjectStatus       = 'I1003'
                                                                                        or _BusSolnOrdItemStatus.SrvcMgmtObjectStatus       = 'I1004'
                                                                                        or _BusSolnOrdItemStatus.SrvcMgmtObjectStatus       = 'I1005'
                                                                                      )
                                                                                     and _BusSolnOrdItemStatus.SrvcMgmtObjectStatusIsInactive     = ''                                                                                  
  
  association [0..1] to I_SalesDocumentRjcnReasonText    as _RejectionReasonText     on  $projection.BusSolnOrdItmRjcnReason = _RejectionReasonText.SalesDocumentRjcnReason
                                                                                     and $projection.Language                = _RejectionReasonText.Language


  association [0..1] to I_CustMgmtPartner                as _ProjectManager          on  $projection.BusinessSolutionOrder            = _ProjectManager.CustMgmtDocument
                                                                                     and $projection.BusinessSolutionOrderItem        = _ProjectManager.CustMgmtDocumentItem
                                                                                     and _ProjectManager.CustMgmtPartnerFunction      = 'PROJM001'
                                                                                     and _ProjectManager.CustMgmtPartFunctionCategory = '0093'
                                                                                     and _ProjectManager.CustMgmtObjectType           = 'BUS2000172'

  association [0..1] to I_CustMgmtPartner                as _ServicePerformer        on  _ServicePerformer.CustMgmtPartnerFunction      = '00000028'
                                                                                     and _ServicePerformer.CustMgmtPartFunctionCategory = '0091'
                                                                                     and $projection.BusinessSolutionOrder              = _ServicePerformer.CustMgmtDocument
                                                                                     and $projection.BusinessSolutionOrderItem          = _ServicePerformer.CustMgmtDocumentItem
  
  association [0..1] to E_ServiceDocumentItem            as _Extension               on  _Extension.ServiceCategory            = 'BUS2000172'
                                                                                     and $projection.BusinessSolutionOrder     = _Extension.ServiceOrderItem
                                                                                     and $projection.BusinessSolutionOrderItem = _Extension.ServiceLineExternalID

  association [0..1] to I_SrvcMgmtObjectStatus              as _ServiceContractDetn  on  $projection.BusinessSolutionOrderItemUUID = _ServiceContractDetn.SrvcMgmtObjectUUID
                                                                                     and _ServiceContractDetn.SrvcMgmtObjectStatus          = 'I0994'
                                                                                     and _ServiceContractDetn.SrvcMgmtObjectStatusIsInactive     = ''
  association [0..1] to I_CustMgmtDateRule            as _SettlementPeriodRule       on  $projection.SettlementPeriodRuleUUID = _SettlementPeriodRule.CustMgmtDateRuleUUID  

  composition [0..*] of R_BusSolnOrdItmPartnerTP         as _BusSolnOrdItmPartnerTP
  composition [0..*] of R_BusSolnOrdItmRefObjectTP       as _BusSolnOrdItmRefObjectTP
  composition [0..*] of R_BusSolnOrdItmPriceElementTP    as _BusSolnOrdItmPriceElementTP
  composition [0..*] of R_BusSolnOrdItmProductTP         as _BusSolnOrdItmProductTP
  composition [0..*] of R_BusSolnOrdItmUserStatusTP      as _BusSolnOrdItmUserStatusTP
  composition [0..*] of R_BSOrdItmRateElementTP          as _BSOrdItmRateElementTP
  composition [0..*] of R_BSOrdItmSubscrpnParameterTP    as _BSOrdItmSubscrpnParameterTP
  composition [0..*] of R_BSOrdItmSubscrpnPriceParamTP   as _BSOrdItmSubscrpnPriceParamTP
  composition [0..*] of R_BusSolnOrdItmAppointmentTP     as _BusSolnOrdItmAppointmentTP
  composition [0..*] of R_BusSolnOrdItmDurationTP        as _BusSolnOrdItmDurationTP
  composition [0..*] of R_BusSolnOrdItmFUPSalesOrderTP   as _BusSolnOrdItmFUPSalesOrderTP
  composition [0..*] of R_BusSolnOrdItmFUPSrvcOrdTP      as _BusSolnOrdItmFUPSrvcOrdTP
  composition [0..*] of R_BusSolnOrdItmFUPSrvcContrTP    as _BusSolnOrdItmFUPSrvcContrTP
  composition [0..*] of R_BusSolnOrdItmFUPSubscrpnTP     as _BusSolnOrdItmFUPSubscrpnTP
  composition [0..*] of R_BusSolnOrdItmFUPEntProjectTP   as _BusSolnOrdItmFUPEntProjectTP
  composition [0..*] of R_BSOrdItmPrdcssrSrvcContrTP     as _BSOrdItmPrdcssrSrvcContrTP
  composition [0..*] of R_BusSolnOrdItmScheduleLineTP    as _BusSolnOrdItmScheduleLineTP
  composition [0..*] of R_BSOrdItmSubscrpnPriceAgrmtTP   as _BSOrdItmSubscrpnPriceAgrmtTP
  composition [0..*] of R_BusSolnOrdItmConfigurationTP   as _BusSolnOrdItmConfigurationTP
  composition [0..*] of R_BusSolnOrdItemLongTextTP       as _BusSolnOrdItemLongTextTP
{
      // Administrative

      @ObjectModel.foreignKey.association: '_ServiceDocument'
  key ServiceDocument                                           as BusinessSolutionOrder,
  key ServiceDocumentItem                                       as BusinessSolutionOrderItem,

      _ParentServiceDocItem_2.ServiceDocumentItem               as ParentBusSolnOrdItem,
      ServiceDocumentItemObjectType,
      ServiceDocItemCategory                                    as BusSolnOrdItmCategory,

      @Semantics.uuid: true
      ServiceDocumentItemUUID                                   as BusinessSolutionOrderItemUUID,

      @Semantics.uuid: true
      ServiceDocumentItemCharUUID,
      ServiceDocumentItemDescription                            as BusSolnOrdItmDescription,
      Language,
      PostingDate,

      PlannedServiceStartDateTime,
      PlannedServiceEndDateTime,
      RequestedServiceStartDateTime,
      RequestedServiceEndDateTime,
      RequestedDeliveryUTCDateTime,
      ServiceDocItemCreationDateTime,
      ServiceDocItemChangedDateTime,
      ServiceDocItemCreatedByUser,
      ServiceDocItemChangedByUser,
      _HeaderExternalReference.CustMgmtExtRefID                 as BusSolnOrdExtReference,
      _ItemExternalReference.CustMgmtExtRefID                   as BusSolnOrdItmExtReference,


      // Item

      @ObjectModel.foreignKey.association: '_Product'
      Product,

      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      ServiceDocumentItemQuantity                               as Quantity,
      ServiceDocItemQuantityUnit                                as QuantityUnit,


      // Partners

      @ObjectModel.foreignKey.association: '_SoldToParty'
      SoldToParty,

      @ObjectModel.foreignKey.association: '_ShipToParty'
      ShipToParty,

      @ObjectModel.foreignKey.association: '_BillToParty'
      BillToParty,

      @ObjectModel.foreignKey.association: '_PayerParty'
      PayerParty,

      @ObjectModel.foreignKey.association: '_ContactPerson'
      ContactPerson                                             as ContactPersonBusinessPartnerId,

      @ObjectModel.foreignKey.association: '_RespEmployee'
      ResponsibleEmployee                                       as RespEmployeeBusinessPartnerId,

      _ProjectManager.CustMgmtBusinessPartner                   as ProjectManager,
      _ServicePerformer.CustMgmtBusinessPartner                 as ServicePerformer,

      // Status

      cast(case _BusSolnOrdItemStatus.SrvcMgmtObjectStatus
      when 'I1002' then 'X'
      else ' '
      end                  as   xfeld preserving type)          as BusSolnOrdItmIsNew,

      cast(case _BusSolnOrdItemStatus.SrvcMgmtObjectStatus
      when 'I1003' then 'X'
      else ' '
      end                  as   xfeld preserving type)          as BusSolnOrdItmIsInProcess,

      cast(case _BusSolnOrdItemStatus.SrvcMgmtObjectStatus
      when 'I1004' then 'X'
      else ' '
      end                  as   xfeld preserving type)          as BusSolnOrdItmIsReleased,

      cast(case _BusSolnOrdItemStatus.SrvcMgmtObjectStatus
      when 'I1005' then 'X'
      else ' '
      end                  as   xfeld preserving type)          as BusSolnOrdItmIsCompleted,

      ServiceDocumentItemStatus                                 as BusSolnOrdItmStatus,

      @Semantics.booleanIndicator: true
      ServiceDocumentItemIsRejected                             as BusSolnOrdItmIsRejected,
      ServiceDocItemBillingStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'SrvcDocDeliveryStatus'
      SrvcDocItmDeliveryStatus,

      @ObjectModel.foreignKey.association: '_SrvcDocItemTransferStatus'
      SrvcDocItemTransferStatus, //Distribution Status



      // Pricing

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      TransactionCurrency,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      ServiceDocumentItemNetAmount,


      // Shipping

      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      ItemGrossWeight,

      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      ItemNetWeight,

      @Semantics.quantity.unitOfMeasure: 'ItemVolumeUnit'
      ItemVolume,
      ItemVolumeUnit,
      ItemWeightUnit,
      DeliveryBlockReason,
      ItemOrderProbabilityInPercent,

      cast( case when ServiceDocumentItemObjectType = 'BUS2000131'
      then IncotermsPart1
      else ''
      end as crmt_incoterms1 preserving type )                  as IncotermsPart1,

      cast( case when ServiceDocumentItemObjectType = 'BUS2000131'
      then IncotermsPart2
      else ''
      end as crmt_incoterms2 preserving type )                  as IncotermsPart2,

      cast( case when ServiceDocumentItemObjectType = 'BUS2000131'  
      then OrderCombinationIsAllowed
      else ''
      end as crmt_ordercombind preserving type )                as OrderCombinationIsAllowed,
      
      DeliveryGroup,
      
      cast (case when ServiceDocumentItemObjectType = 'BUS2000131' 
      then DeliveryPriority 
      else '00' 
      end as crmt_dlv_prio preserving type )                   as DeliveryPriority,

      Plant,

      // SLA

      ResponseProfile,
      ServiceProfile,


      // Reference Documents

      _ReferenceSrvcContract._ServiceDocItm.ServiceDocument     as ReferenceServiceContract,
      _ReferenceSrvcContract._ServiceDocItm.ServiceDocumentItem as ReferenceServiceContractItem,
      
      cast (case when _ServiceContractDetn.SrvcMgmtObjectStatus = 'I0994'
      then 'X' 
      else '' 
      end as xfeld  preserving type )                           as SrvcContrDetnIsSpprsd,

      // Organization

      SalesOrganization,
      DistributionChannel,
      Division,
      SalesOffice,
      SalesGroup,
      ResponsibleCostCenter,
      EnterpriseProjectServiceOrg,

      // Other

      BillingBlockReason,
      @ObjectModel.foreignKey.association: '_ServiceDocItemRejectionReason'
      ServiceDocItemRejectionReason                             as BusSolnOrdItmRjcnReason,
      MaterialPricingGroup,
      PartialDeliveryIsAllowed,
      PaymentTerms,
      ProfitCenter,
      PurchaseOrderByCustomer,
      BillableControl,
      
      @ObjectModel.foreignKey.association: '_ServiceDocOvertimeCat'
      TimeSheetOvertimeCategory,

      // Service Contract Related

      @Semantics.quantity.unitOfMeasure: 'SrvcContrItemRnwlDurationUnit'
      SrvcContrItemRnwlDuration,
      SrvcContrItemRnwlDurationUnit,

      @Semantics.quantity.unitOfMeasure: 'SrvcContrItemRnwlDurationUnit'
      SrvcContrItemExtensionDuration,
      SrvcContrItemExtnDurationUnit,

      _BillPlanDateRule.CustMgmtDateRuleName                    as SrvcMgmtBillgPlanBillgDateRule,
      SettlementPeriodRuleUUID,
      _SettlementPeriodRule.CustMgmtDateRuleName                  as SettlementPeriodRule,


      // Subscription Related

      cast(case SubscrpnContrTrmsAreSpecified
      when 'Y' then 'X'
      when ' ' then 'X'
      else '' end  as crms4_ovrwrt_default_terms_db)            as SubscrpnContrTrmsAreSpecified,

      MidBillgCycExprtnIsAllowed,
      SubscrpnContrAutoRnwlIsActv,
      _ServiceDocItemEnhcd.SubscriptionBillingCycle,


      // For Authorization

      SalesOrganizationOrgUnitID,
      SalesOfficeOrgUnitID,
      SalesGroupOrgUnitID,
      ServiceOrganization,
      @ObjectModel.sapObjectNodeTypeReference: 'ServiceDocumentType'
      ServiceDocumentType,

      //Inheritance of Complex set RAP

      SrvcDocItmPartReferenceItem, //For Item Partner

      SrvcDocItmApptRefObjectUUID, //For Item Appointment UUID

      SrvcDocItmApptReferenceItem, // For Appointment and Duration



      @ObjectModel.foreignKey.association: '_ServiceObjType'
      ServiceObjectType,

      //Below fields are added in order to consume in C_BusSolnOrdItmListRptAndObjPg


      _SalesOrganizationOrgUnit_2,
      _SalesOfficeOrgUnit_2,
      _SalesGroupOrgUnit_2,
      _ServiceOrganizationOrgUnit_2,
      _ServiceDocItemCategory,
      _ServiceDocItemStatus,
      _ServiceDocItemEnhcd,
      _SrvcDocItemTransferStatus,

      // Compositions

      _BusSolnOrdItmPartnerTP,
      _BusSolnOrdItmRefObjectTP,
      _BusSolnOrdItmPriceElementTP,
      _BusSolnOrdItmProductTP,
      _BusSolnOrdItmUserStatusTP,
      _BSOrdItmRateElementTP,
      _BSOrdItmSubscrpnParameterTP,
      _BSOrdItmSubscrpnPriceParamTP,
      _BusSolnOrdItmAppointmentTP,
      _BusSolnOrdItmDurationTP,
      _BusSolnOrdItmFUPSalesOrderTP,
      _BusSolnOrdItmFUPSrvcOrdTP,
      _BusSolnOrdItmFUPSrvcContrTP,
      _BusSolnOrdItmFUPSubscrpnTP,
      _BusSolnOrdItmFUPEntProjectTP,
      _BSOrdItmPrdcssrSrvcContrTP,
      _BusSolnOrdItmScheduleLineTP,
      _BusSolnOrdItmConfigurationTP,
      _BSOrdItmSubscrpnPriceAgrmtTP,
      _BusSolnOrdItemLongTextTP,


      // Associations

      _BusinessSolutionOrder,
      _SoldToParty,
      _ShipToParty,
      _BillToParty,
      _PayerParty,
      _ContactPerson,
      _RespEmployee,
      _BusSolnOrdItemStatus,
      _RejectionReasonText,
      _ServiceDocument,
      _Product,
      _TransactionCurrency,
      _ServiceDocItemRejectionReason,
      _ServiceObjType,
      _ServiceDocOvertimeCat

}
where
  ServiceObjectType = 'BUS2000172'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTMGMTDATERULE",
"I_CUSTMGMTEXTREFID",
"I_CUSTMGMTPARTNER",
"I_SERVICEDOCUMENTITEMENHCD",
"I_SERVICEDOCUMENTITEMPRDCSSR_3",
"I_SRVCMGMTOBJECTSTATUS"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CURRENCY",
"I_CUSTMGMTBUSOBJTYPE",
"I_PRODUCT",
"I_SALESDOCUMENTRJCNREASON",
"I_SALESDOCUMENTRJCNREASONTEXT",
"I_SERVICEDOCITEMCATEGORY",
"I_SERVICEDOCUMENTENHCD",
"I_SERVICEDOCUMENTITEMENHCD",
"I_SERVICEDOCUMENTSTATUS",
"I_SRVCDOCTRANSFERSTATUS",
"I_SRVCMGMTOBJECTSTATUS",
"I_SRVCMGMTORGANIZATIONUNIT",
"I_TIMESHEETOVERTIMECAT",
"R_BSORDITMPRDCSSRSRVCCONTRTP",
"R_BSORDITMRATEELEMENTTP",
"R_BSORDITMSUBSCRPNPARAMETERTP",
"R_BSORDITMSUBSCRPNPRICEAGRMTTP",
"R_BSORDITMSUBSCRPNPRICEPARAMTP",
"R_BUSINESSSOLUTIONORDERTP",
"R_BUSSOLNORDITEMLONGTEXTTP",
"R_BUSSOLNORDITMAPPOINTMENTTP",
"R_BUSSOLNORDITMCONFIGURATIONTP",
"R_BUSSOLNORDITMDURATIONTP",
"R_BUSSOLNORDITMFUPENTPROJECTTP",
"R_BUSSOLNORDITMFUPSALESORDERTP",
"R_BUSSOLNORDITMFUPSRVCCONTRTP",
"R_BUSSOLNORDITMFUPSRVCORDTP",
"R_BUSSOLNORDITMFUPSUBSCRPNTP",
"R_BUSSOLNORDITMPARTNERTP",
"R_BUSSOLNORDITMPRICEELEMENTTP",
"R_BUSSOLNORDITMPRODUCTTP",
"R_BUSSOLNORDITMREFOBJECTTP",
"R_BUSSOLNORDITMSCHEDULELINETP",
"R_BUSSOLNORDITMUSERSTATUSTP"
],
"BASE":
[
"I_SERVICEDOCUMENTITEMENHCD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/