P_SFOTraceableAssldComp

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XL,
  dataClass: #MIXED
}
@VDM.viewType: #CONSUMPTION
@VDM.private: true
define view entity P_SFOTraceableAssldComp
  as select from           P_SFOAssldTrcblCompByLdngResvn as SFOAssldTrcblCompByLdngResvn
    inner join             P_SFOAssldCompByLdngResvnNoIn  as SFOAssldCompByLdngResvnNoIn on  SFOAssldCompByLdngResvnNoIn.Reservation        = SFOAssldTrcblCompByLdngResvn.Reservation
                                                                                         and SFOAssldCompByLdngResvnNoIn.ReservationItem    = SFOAssldTrcblCompByLdngResvn.ReservationItem
                                                                                         and SFOAssldCompByLdngResvnNoIn.RecordType         = SFOAssldTrcblCompByLdngResvn.RecordType
                                                                                         and SFOAssldCompByLdngResvnNoIn.OpActyNtwkInstance = SFOAssldTrcblCompByLdngResvn.OpActyNtwkInstance
                                                                                         and SFOAssldCompByLdngResvnNoIn.OpActyNtwkElement  = SFOAssldTrcblCompByLdngResvn.OpActyNtwkElement
                                                                                         and SFOAssldCompByLdngResvnNoIn.Material           = SFOAssldTrcblCompByLdngResvn.Material
                                                                                         and SFOAssldCompByLdngResvnNoIn.Plant              = SFOAssldTrcblCompByLdngResvn.Plant
    inner join             I_MatlPlntCompAssembleControl  as MatlPlntCompAssembleControl on  MatlPlntCompAssembleControl.Product = SFOAssldTrcblCompByLdngResvn.Material
                                                                                         and MatlPlntCompAssembleControl.Plant   = SFOAssldTrcblCompByLdngResvn.Plant
    left outer to one join I_OpActyInstceComponentDetail  as OpActyInstceComponentDetail on  OpActyInstceComponentDetail.OpActyNtwkInstance = SFOAssldTrcblCompByLdngResvn.OpActyNtwkInstance
                                                                                         and OpActyInstceComponentDetail.OpActyNtwkElement  = SFOAssldTrcblCompByLdngResvn.OpActyNtwkElement
                                                                                         and OpActyInstceComponentDetail.Reservation        = SFOAssldTrcblCompByLdngResvn.Reservation
                                                                                         and OpActyInstceComponentDetail.ReservationItem    = SFOAssldTrcblCompByLdngResvn.ReservationItem
                                                                                         and OpActyInstceComponentDetail.RecordType         = SFOAssldTrcblCompByLdngResvn.RecordType
    left outer to one join I_OpActyNtwkInstanceBasic      as OpActyNtwkInstanceBasic     on OpActyNtwkInstanceBasic.OpActyNtwkInstance = SFOAssldTrcblCompByLdngResvn.OpActyNtwkInstance
    left outer to one join I_OrderOperationBasic          as OrderOperationBasic         on  OpActyNtwkInstanceBasic.OrderInternalID          = OrderOperationBasic.OrderInternalID
                                                                                         and OpActyNtwkInstanceBasic.OrderOperationInternalID = OrderOperationBasic.OrderOperationInternalID
    left outer to one join I_InstanceReferenceDesignator  as InstanceReferenceDesignator on InstanceReferenceDesignator.DgtlMockUpCharcsUUID = SFOAssldTrcblCompByLdngResvn.DgtlMockUpCharcsUUID

  association [0..1] to I_ReservationDocumentHeader  as _Reservation                on  $projection.Reservation = _Reservation.Reservation
  association [1..1] to I_OpActyNtwkInstance         as _OpActyNtwkInstance         on  $projection.OpActyNtwkInstance = _OpActyNtwkInstance.OpActyNtwkInstance
  association [1..1] to I_OperationActivityInstance  as _OperationActivityInstance  on  $projection.OpActyNtwkInstance = _OperationActivityInstance.OpActyNtwkInstance
                                                                                    and $projection.OpActyNtwkElement  = _OperationActivityInstance.OpActyNtwkElement
  association [1..1] to I_ShopFloorItem              as _ShopFloorItem              on  $projection.ShopFloorItem = _ShopFloorItem.ShopFloorItem

  association [0..1] to I_BillOfMaterialItemBasic    as _BillOfMaterialItemBasic    on  $projection.BillOfMaterialCategory     = _BillOfMaterialItemBasic.BillOfMaterialCategory
                                                                                    and $projection.BillOfMaterialInternalID   = _BillOfMaterialItemBasic.BillOfMaterial
                                                                                    and $projection.BOMItem                    = _BillOfMaterialItemBasic.BillOfMaterialItemNodeNumber
                                                                                    and $projection.BOMItemInternalChangeCount = _BillOfMaterialItemBasic.BOMItemInternalChangeCount
  association [0..1] to I_MfgBOMItemWithPhantomHier  as _MfgBOMItemWithPhantomHier  on  $projection.BillOfMaterialCategory   = _MfgBOMItemWithPhantomHier.MfgBillOfMaterialCategory
                                                                                    and $projection.BillOfMaterialInternalID = _MfgBOMItemWithPhantomHier.MfgBillOfMaterial
                                                                                    and $projection.BillOfMaterialVariant    = _MfgBOMItemWithPhantomHier.MfgBillOfMaterialVariant
                                                                                    and $projection.BillOfMaterialVersion    = _MfgBOMItemWithPhantomHier.MfgBillOfMaterialVersion
                                                                                    and $projection.InheritedBOMItemNode     = _MfgBOMItemWithPhantomHier.MfgBOMItmInhtdNodeNmbr
  association [0..1] to I_MfgRefStrucItemWithDetails as _MfgRefStrucItemWithDetails on  $projection.MfgRefStructureItemDetailUUID = _MfgRefStrucItemWithDetails.MfgRefStructureItemUUID
                                                                                    and $projection.MfgRefStrucItmDetIsContextual = ''
  association [0..1] to I_MfgRefHierItemWithDetails  as _MfgRefHierItemWithDetails  on  $projection.MfgRefStructureItemDetailUUID = _MfgRefHierItemWithDetails.MfgRefHierarchyItemUUID
                                                                                    and $projection.MfgRefStrucItmDetIsContextual = 'X'
{
  key SFOAssldTrcblCompByLdngResvn.Reservation,
  key SFOAssldTrcblCompByLdngResvn.ReservationItem,
  key SFOAssldTrcblCompByLdngResvn.RecordType,
      @ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
  key SFOAssldTrcblCompByLdngResvn.OpActyNtwkInstance,
      @ObjectModel.foreignKey.association: '_OperationActivityInstance'
  key SFOAssldTrcblCompByLdngResvn.OpActyNtwkElement,
  key SFOAssldTrcblCompByLdngResvn.ShopFloorItem,
  key SFOAssldTrcblCompByLdngResvn.Batch,
  key cast(SFOAssldTrcblCompByLdngResvn.Material as mpe_component_matnr preserving type )                           as Material,
      @ObjectModel.foreignKey.association: '_Plant'
  key SFOAssldTrcblCompByLdngResvn.Plant,
  key SFOAssldTrcblCompByLdngResvn.DgtlMockUpCharcsUUID,
  key SFOAssldTrcblCompByLdngResvn.MfgRefStrucBOMLeafAssgmtUUID,
  key SFOAssldTrcblCompByLdngResvn.MfgRefStructureItemDetailUUID,
  key SFOAssldTrcblCompByLdngResvn.MfgRefStrucItmDetIsContextual,
      OpActyInstceComponentDetail.BillOfMaterialItemNumber                                                          as BillOfMaterialItemNumber,
      OpActyInstceComponentDetail.BillOfMaterialCategory                                                            as BillOfMaterialCategory,
      OpActyInstceComponentDetail.BillOfMaterialInternalID                                                          as BillOfMaterialInternalID,
      OpActyInstceComponentDetail.BOMItem                                                                           as BOMItem,
      OpActyInstceComponentDetail.BOMItemInternalChangeCount                                                        as BOMItemInternalChangeCount,
      OpActyInstceComponentDetail.BillOfMaterialVariant                                                             as BillOfMaterialVariant,
      OpActyInstceComponentDetail.BillOfMaterialVersion                                                             as BillOfMaterialVersion,
      OpActyInstceComponentDetail.BOMItemCategory                                                                   as BOMItemCategory,
      OpActyInstceComponentDetail.InheritedBOMItemNode                                                              as InheritedBOMItemNode,
      OpActyInstceComponentDetail.EffectivityParameterVariant                                                       as EffectivityParameterVariant,
      _BillOfMaterialItemBasic.InheritedNodeNumberForBOMItem                                                        as InheritedNodeNumberForBOMItem,
      _BillOfMaterialItemBasic.InheritedNodeNumberVersionBOM                                                        as InheritedNodeNumberVersionBOM,
      OpActyInstceComponentDetail.Assembly                                                                          as Assembly,

      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      cast(OpActyInstceComponentDetail.RequiredQuantity as mpe_planned_qty preserving type )                        as RequiredQuantity,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      OpActyInstceComponentDetail.RequiredQuantityInBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      cast(case OpActyInstceComponentDetail.MaterialCompIsVariableSized
        when 'X' then SFOAssldTrcblCompByLdngResvn.QuantityInEntryUnit
        else SFOAssldTrcblCompByLdngResvn.MaterialComponentQuantity
      end as mpe_consumed_qty preserving type)                                                                      as MaterialComponentQuantity,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      cast(SFOAssldTrcblCompByLdngResvn.MaterialComponentQuantity as mpe_consumed_qty_in_base_unit preserving type) as ResvnItmWithdrawnQtyInBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      cast(SFOAssldCompByLdngResvnNoIn.MaterialComponentQuantity as enmng preserving type)                          as ResvnItmTotalWithdrawnQty,
      SFOAssldTrcblCompByLdngResvn.MaterialBaseUnit,
      SFOAssldTrcblCompByLdngResvn.EntryUnit,

      -- Variable-Size Item Fields
      OpActyInstceComponentDetail.MaterialCompIsVariableSized,
      OpActyInstceComponentDetail.FormulaKey,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      OpActyInstceComponentDetail.VariableSizeDimension1,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      OpActyInstceComponentDetail.VariableSizeDimension2,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      OpActyInstceComponentDetail.VariableSizeDimension3,
      OpActyInstceComponentDetail.VariableSizeDimensionUnit,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeComponentUnit'
      OpActyInstceComponentDetail.VariableSizeComponentQuantity,
      OpActyInstceComponentDetail.VariableSizeComponentUnit,

      SFOAssldTrcblCompByLdngResvn.ManufacturingOrder,
      cast(OrderOperationBasic.Operation_2 as mpe_vornr_char preserving type)                                       as Operation,
      OrderOperationBasic.OperationText,
      OpActyNtwkInstanceBasic.OrderInternalID,
      OpActyNtwkInstanceBasic.OrderOperationInternalID,
      OpActyNtwkInstanceBasic.OperationActivityNetwork,
      OpActyNtwkInstanceBasic.OpActyNtwkVersionCounter,
      _ShopFloorItem.SerialNumber,
      cast(_ShopFloorItem._Equipment.ManufacturerSerialNumber as mpe_mfr_sernr preserving type)                     as ManufacturerSerialNumber,
      InstanceReferenceDesignator.ReferenceDesignatorValue,
      @ObjectModel.foreignKey.association: '_MatlCompAssembleControl'
      MatlPlntCompAssembleControl.MatlCompAssembleControl,
      OpActyInstceComponentDetail.DebitCreditCode,

      _Reservation,
      _OpActyNtwkInstance,
      _OperationActivityInstance,
      SFOAssldTrcblCompByLdngResvn._ManufacturingOrder,
      _ShopFloorItem,
      SFOAssldTrcblCompByLdngResvn._Material,
      SFOAssldTrcblCompByLdngResvn._Plant,
      SFOAssldTrcblCompByLdngResvn._ProductPlantBasic,
      MatlPlntCompAssembleControl._MatlCompAssembleControl,
      OpActyInstceComponentDetail._BOMItemCategory,
      _MfgBOMItemWithPhantomHier,
      _MfgRefStrucItemWithDetails,
      _MfgRefHierItemWithDetails
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFMATERIALITEMBASIC",
"I_EQUIPMENT",
"I_INSTANCEREFERENCEDESIGNATOR",
"I_MATLPLNTCOMPASSEMBLECONTROL",
"I_OPACTYINSTCECOMPONENTDETAIL",
"I_OPACTYNTWKINSTANCEBASIC",
"I_ORDEROPERATIONBASIC",
"I_SHOPFLOORITEM",
"P_SFOASSLDCOMPBYLDNGRESVNNOIN",
"P_SFOASSLDTRCBLCOMPBYLDNGRESVN"
],
"ASSOCIATED":
[
"I_BILLOFMATERIALITEMCATEGORY",
"I_MANUFACTURINGORDER",
"I_MATERIAL",
"I_MATLCOMPASSEMBLECONTROL",
"I_MFGBOMITEMWITHPHANTOMHIER",
"I_MFGREFHIERITEMWITHDETAILS",
"I_MFGREFSTRUCITEMWITHDETAILS",
"I_OPACTYNTWKINSTANCE",
"I_OPERATIONACTIVITYINSTANCE",
"I_PLANT",
"I_PRODUCTPLANTBASIC",
"I_RESERVATIONDOCUMENTHEADER",
"I_SHOPFLOORITEM"
],
"BASE":
[
"I_MATLPLNTCOMPASSEMBLECONTROL",
"I_OPACTYINSTCECOMPONENTDETAIL",
"P_SFOASSLDTRCBLCOMPBYLDNGRESVN"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/