P_SFITraceableAssldComp

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XL,
  dataClass: #MIXED
}
@VDM.viewType: #CONSUMPTION
@VDM.private: true
define view entity P_SFITraceableAssldComp
  as select from           P_SFIAssldTrcblCompByLdngResvn as SFIAssldTrcblCompByLdngResvn
    inner join             P_SFIAssldCompByLdngResvnNoIn  as SFIAssldCompByLdngResvnNoIn on  SFIAssldCompByLdngResvnNoIn.Reservation           = SFIAssldTrcblCompByLdngResvn.Reservation
                                                                                         and SFIAssldCompByLdngResvnNoIn.ReservationItem       = SFIAssldTrcblCompByLdngResvn.ReservationItem
                                                                                         and SFIAssldCompByLdngResvnNoIn.RecordType            = SFIAssldTrcblCompByLdngResvn.RecordType
                                                                                         and SFIAssldCompByLdngResvnNoIn.OpActyNtwkInstance    = SFIAssldTrcblCompByLdngResvn.OpActyNtwkInstance
                                                                                         and SFIAssldCompByLdngResvnNoIn.OpActyNtwkElement     = SFIAssldTrcblCompByLdngResvn.OpActyNtwkElement
                                                                                         and SFIAssldCompByLdngResvnNoIn.AssemblyShopFloorItem = SFIAssldTrcblCompByLdngResvn.AssemblyShopFloorItem
                                                                                         and SFIAssldCompByLdngResvnNoIn.Material              = SFIAssldTrcblCompByLdngResvn.Material
                                                                                         and SFIAssldCompByLdngResvnNoIn.Plant                 = SFIAssldTrcblCompByLdngResvn.Plant
    inner join             I_MatlPlntCompAssembleControl  as MatlPlntCompAssembleControl on  SFIAssldTrcblCompByLdngResvn.Material = MatlPlntCompAssembleControl.Product
                                                                                         and SFIAssldTrcblCompByLdngResvn.Plant    = MatlPlntCompAssembleControl.Plant
    left outer to one join I_OpActyInstceComponentDetail  as OpActyInstceComponentDetail on  OpActyInstceComponentDetail.OpActyNtwkInstance = SFIAssldTrcblCompByLdngResvn.OpActyNtwkInstance
                                                                                         and OpActyInstceComponentDetail.OpActyNtwkElement  = SFIAssldTrcblCompByLdngResvn.OpActyNtwkElement
                                                                                         and OpActyInstceComponentDetail.Reservation        = SFIAssldTrcblCompByLdngResvn.Reservation
                                                                                         and OpActyInstceComponentDetail.ReservationItem    = SFIAssldTrcblCompByLdngResvn.ReservationItem
                                                                                         and OpActyInstceComponentDetail.RecordType         = SFIAssldTrcblCompByLdngResvn.RecordType
    left outer to one join I_OpActyNtwkInstanceBasic      as OpActyNtwkInstanceBasic     on OpActyNtwkInstanceBasic.OpActyNtwkInstance = SFIAssldTrcblCompByLdngResvn.OpActyNtwkInstance
    left outer to one join I_InstanceReferenceDesignator  as InstanceReferenceDesignator on InstanceReferenceDesignator.DgtlMockUpCharcsUUID = SFIAssldTrcblCompByLdngResvn.DgtlMockUpCharcsUUID

  association [0..1] to I_ReservationDocumentHeader as _Reservation               on  $projection.Reservation = _Reservation.Reservation
  association [1..1] to I_OpActyNtwkInstance        as _OpActyNtwkInstance        on  $projection.OpActyNtwkInstance = _OpActyNtwkInstance.OpActyNtwkInstance
  association [1..1] to I_OperationActivityInstance as _OperationActivityInstance on  $projection.OpActyNtwkInstance = _OperationActivityInstance.OpActyNtwkInstance
                                                                                  and $projection.OpActyNtwkElement  = _OperationActivityInstance.OpActyNtwkElement
  association [1..1] to I_ShopFloorItem             as _ParentShopFloorItem       on  $projection.AssemblyShopFloorItem = _ParentShopFloorItem.ShopFloorItem
  association [1..1] to I_ShopFloorItem             as _ShopFloorItem             on  $projection.ShopFloorItem = _ShopFloorItem.ShopFloorItem

  association [0..1] to I_BillOfMaterialItemBasic   as _BillOfMaterialItemBasic   on  $projection.BillOfMaterialCategory     = _BillOfMaterialItemBasic.BillOfMaterialCategory
                                                                                  and $projection.BillOfMaterialInternalID   = _BillOfMaterialItemBasic.BillOfMaterial
                                                                                  and $projection.BOMItem                    = _BillOfMaterialItemBasic.BillOfMaterialItemNodeNumber
                                                                                  and $projection.BOMItemInternalChangeCount = _BillOfMaterialItemBasic.BOMItemInternalChangeCount
  association [0..1] to I_MfgBOMItemWithPhantomHier as _MfgBOMItemWithPhantomHier on  $projection.BillOfMaterialCategory   = _MfgBOMItemWithPhantomHier.MfgBillOfMaterialCategory
                                                                                  and $projection.BillOfMaterialInternalID = _MfgBOMItemWithPhantomHier.MfgBillOfMaterial
                                                                                  and $projection.BillOfMaterialVariant    = _MfgBOMItemWithPhantomHier.MfgBillOfMaterialVariant
                                                                                  and $projection.BillOfMaterialVersion    = _MfgBOMItemWithPhantomHier.MfgBillOfMaterialVersion
                                                                                  and $projection.InheritedBOMItemNode     = _MfgBOMItemWithPhantomHier.MfgBOMItmInhtdNodeNmbr
{
  key SFIAssldTrcblCompByLdngResvn.Reservation,
  key SFIAssldTrcblCompByLdngResvn.ReservationItem,
  key SFIAssldTrcblCompByLdngResvn.RecordType,
      @ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
  key SFIAssldTrcblCompByLdngResvn.OpActyNtwkInstance,
      @ObjectModel.foreignKey.association: '_OperationActivityInstance'
  key SFIAssldTrcblCompByLdngResvn.OpActyNtwkElement,
  key SFIAssldTrcblCompByLdngResvn.AssemblyShopFloorItem,
  key SFIAssldTrcblCompByLdngResvn.ShopFloorItem,
  key SFIAssldTrcblCompByLdngResvn.Batch,
  key cast(SFIAssldTrcblCompByLdngResvn.Material as mpe_component_matnr preserving type )                           as Material,
      @ObjectModel.foreignKey.association: '_Plant'
  key SFIAssldTrcblCompByLdngResvn.Plant,
  key SFIAssldTrcblCompByLdngResvn.DgtlMockUpCharcsUUID,
  key SFIAssldTrcblCompByLdngResvn.MfgRefStrucBOMLeafAssgmtUUID,
  key SFIAssldTrcblCompByLdngResvn.MfgRefStructureItemDetailUUID,
  key SFIAssldTrcblCompByLdngResvn.MfgRefStrucItmDetIsContextual,
      OpActyInstceComponentDetail.BillOfMaterialItemNumber                                                          as BillOfMaterialItemNumber,
      OpActyInstceComponentDetail.BillOfMaterialCategory                                                            as BillOfMaterialCategory,
      OpActyInstceComponentDetail.BillOfMaterialInternalID                                                          as BillOfMaterialInternalID,
      OpActyInstceComponentDetail.BOMItem                                                                           as BOMItem,
      OpActyInstceComponentDetail.BOMItemInternalChangeCount                                                        as BOMItemInternalChangeCount,
      OpActyInstceComponentDetail.BillOfMaterialVariant                                                             as BillOfMaterialVariant,
      OpActyInstceComponentDetail.BillOfMaterialVersion                                                             as BillOfMaterialVersion,
      OpActyInstceComponentDetail.BOMItemCategory                                                                   as BOMItemCategory,
      OpActyInstceComponentDetail.InheritedBOMItemNode                                                              as InheritedBOMItemNode,
      OpActyInstceComponentDetail.EffectivityParameterVariant                                                       as EffectivityParameterVariant,
      OpActyInstceComponentDetail.Assembly                                                                          as Assembly,
      _BillOfMaterialItemBasic.InheritedNodeNumberForBOMItem                                                        as InheritedNodeNumberForBOMItem,
      _BillOfMaterialItemBasic.InheritedNodeNumberVersionBOM                                                        as InheritedNodeNumberVersionBOM,

      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      cast(OpActyInstceComponentDetail.MfgOrderComponentUsageNetQty as mpe_planned_qty preserving type )            as RequiredQuantity,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      cast(case OpActyInstceComponentDetail.MaterialCompIsVariableSized
        when 'X' then OpActyInstceComponentDetail.MfgOrderComponentUsageNetQty * OpActyInstceComponentDetail.VariableSizeComponentQuantity
        else OpActyInstceComponentDetail.MfgOrderComponentUsageNetQty
      end as mpe_planned_qty_in_base_unit)                                                                          as RequiredQuantityInBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      cast(case OpActyInstceComponentDetail.MaterialCompIsVariableSized
        when 'X' then SFIAssldTrcblCompByLdngResvn.QuantityInEntryUnit
        else SFIAssldTrcblCompByLdngResvn.MaterialComponentQuantity
      end as mpe_consumed_qty preserving type)                                                                      as MaterialComponentQuantity,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      cast(SFIAssldTrcblCompByLdngResvn.MaterialComponentQuantity as mpe_consumed_qty_in_base_unit preserving type) as ResvnItmWithdrawnQtyInBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      cast(SFIAssldCompByLdngResvnNoIn.MaterialComponentQuantity as enmng preserving type)                          as ResvnItmTotalWithdrawnQty,
      SFIAssldTrcblCompByLdngResvn.MaterialBaseUnit,
      SFIAssldTrcblCompByLdngResvn.EntryUnit,

      -- Variable-Size Item Fields
      OpActyInstceComponentDetail.MaterialCompIsVariableSized,
      OpActyInstceComponentDetail.FormulaKey,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      OpActyInstceComponentDetail.VariableSizeDimension1,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      OpActyInstceComponentDetail.VariableSizeDimension2,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      OpActyInstceComponentDetail.VariableSizeDimension3,
      OpActyInstceComponentDetail.VariableSizeDimensionUnit,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeComponentUnit'
      OpActyInstceComponentDetail.VariableSizeComponentQuantity,
      OpActyInstceComponentDetail.VariableSizeComponentUnit,

      cast(OpActyInstceComponentDetail.ManufacturingOrderOperation as mpe_vornr_char preserving type)               as ManufacturingOrderOperation,
      OpActyInstceComponentDetail.MfgOrderOperationText                                                             as MfgOrderOperationText,
      OpActyNtwkInstanceBasic.OrderInternalID,
      OpActyNtwkInstanceBasic.OrderOperationInternalID,
      OpActyNtwkInstanceBasic.OperationActivityNetwork,
      OpActyNtwkInstanceBasic.OpActyNtwkVersionCounter,
      _ShopFloorItem.SerialNumber,
      cast(_ShopFloorItem._Equipment.ManufacturerSerialNumber as mpe_mfr_sernr preserving type)                     as ManufacturerSerialNumber,
      InstanceReferenceDesignator.ReferenceDesignatorValue,
      @ObjectModel.foreignKey.association: '_MatlCompAssembleControl'
      MatlPlntCompAssembleControl.MatlCompAssembleControl,
      OpActyInstceComponentDetail.DebitCreditCode,

      _Reservation,
      _OpActyNtwkInstance,
      _OperationActivityInstance,
      _ParentShopFloorItem,
      _ShopFloorItem,
      SFIAssldTrcblCompByLdngResvn._Material,
      SFIAssldTrcblCompByLdngResvn._Plant,
      SFIAssldTrcblCompByLdngResvn._ProductPlantBasic,
      MatlPlntCompAssembleControl._MatlCompAssembleControl,
      OpActyInstceComponentDetail._BOMItemCategory,
      _MfgBOMItemWithPhantomHier
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFMATERIALITEMBASIC",
"I_EQUIPMENT",
"I_INSTANCEREFERENCEDESIGNATOR",
"I_MATLPLNTCOMPASSEMBLECONTROL",
"I_OPACTYINSTCECOMPONENTDETAIL",
"I_OPACTYNTWKINSTANCEBASIC",
"I_SHOPFLOORITEM",
"P_SFIASSLDCOMPBYLDNGRESVNNOIN",
"P_SFIASSLDTRCBLCOMPBYLDNGRESVN"
],
"ASSOCIATED":
[
"I_BILLOFMATERIALITEMCATEGORY",
"I_MATERIAL",
"I_MATLCOMPASSEMBLECONTROL",
"I_MFGBOMITEMWITHPHANTOMHIER",
"I_OPACTYNTWKINSTANCE",
"I_OPERATIONACTIVITYINSTANCE",
"I_PLANT",
"I_PRODUCTPLANTBASIC",
"I_RESERVATIONDOCUMENTHEADER",
"I_SHOPFLOORITEM"
],
"BASE":
[
"I_MATLPLNTCOMPASSEMBLECONTROL",
"I_OPACTYINSTCECOMPONENTDETAIL",
"P_SFIASSLDTRCBLCOMPBYLDNGRESVN"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/