P_SFIAssembledComponent2

@AbapCatalog.sqlViewName: 'PMPESFIACMP2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}
@VDM.viewType: #CONSUMPTION
@VDM.private: true
define view P_SFIAssembledComponent2
  as select from P_SFIAssembledComponent       as SFIAssembledComponent
    inner join   I_MatlPlntCompAssembleControl as MfgOrderProductPlant on  SFIAssembledComponent.Material = MfgOrderProductPlant.Product
                                                                       and SFIAssembledComponent.Plant    = MfgOrderProductPlant.Plant
  association [1..1] to I_MatlCompAssembleControl    as _MatlCompAssembleControl    on  $projection.MatlCompAssembleControl = _MatlCompAssembleControl.MatlCompAssembleControl
  association [0..1] to I_ShopFloorItem              as _AssemblyShopFloorItem      on  $projection.AssemblyShopFloorItem = _AssemblyShopFloorItem.ShopFloorItem
  association [1..1] to I_ReservationDocumentHeader  as _Reservation                on  $projection.Reservation = _Reservation.Reservation
  association [0..1] to I_StorageLocation            as _StorageLocation            on  $projection.Plant           = _StorageLocation.Plant
                                                                                    and $projection.StorageLocation = _StorageLocation.StorageLocation
  association [0..1] to I_OrderComponent             as _OrderComponent             on  $projection.Reservation     = _OrderComponent.Reservation
                                                                                    and $projection.ReservationItem = _OrderComponent.ReservationItem
                                                                                    and $projection.RecordType      = _OrderComponent.RecordType
  association [0..1] to I_BOMItmMfgRefStrucItmAssgmt as _BOMItmMfgRefStrucItmAssgmt on  $projection.MfgRefStrucBOMLeafAssgmtUUID = _BOMItmMfgRefStrucItmAssgmt.MfgRefStrucBOMLeafAssgmtUUID
  association [0..1] to I_MfgRefStrucItemWithDetails as _MfgRefStrucItemWithDetails on  $projection.MfgRefStructureItemDetailUUID = _MfgRefStrucItemWithDetails.MfgRefStructureItemUUID
                                                                                    and $projection.MfgRefStrucItmDetIsContextual = ''
  association [0..1] to I_MfgRefHierItemWithDetails  as _MfgRefHierItemWithDetails  on  $projection.MfgRefStructureItemDetailUUID = _MfgRefHierItemWithDetails.MfgRefHierarchyItemUUID
                                                                                    and $projection.MfgRefStrucItmDetIsContextual = 'X'
{
      @ObjectModel.foreignKey.association: '_Reservation'
  key SFIAssembledComponent.Reservation,
  key SFIAssembledComponent.ReservationItem,
  key SFIAssembledComponent.RecordType,
  key SFIAssembledComponent.OpActyNtwkInstance,
  key SFIAssembledComponent.OpActyNtwkElement,
      @ObjectModel.foreignKey.association: '_AssemblyShopFloorItem'
  key SFIAssembledComponent.AssemblyShopFloorItem,
  key SFIAssembledComponent.Material,
  key SFIAssembledComponent.Plant,
      cast(case
        when SFIAssembledComponent.StorageLocation is null then '    '
        else SFIAssembledComponent.StorageLocation
      end as pph_lgort preserving type)                                                                      as StorageLocation, --Display Storage Location if defined in Component
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      SFIAssembledComponent.RequiredQuantity,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      cast(case _OrderComponent.MaterialCompIsVariableSized
        when 'X' then SFIAssembledComponent.RequiredQuantity * SFIAssembledComponent.VariableSizeComponentQuantity
        else SFIAssembledComponent.RequiredQuantity
      end as mpe_planned_qty_in_base_unit)                                                                   as RequiredQuantityInBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      cast(case SFIAssembledComponent.MaterialCompIsVariableSized
      -- Variable-size item: Assembly typically has to be done in PC, but base unit e.g. is square meter
          when 'X' then SFIAssembledComponent.QuantityInEntryUnit
          else SFIAssembledComponent.MaterialComponentQuantity
        end as mpe_consumed_qty preserving type)                                                             as MaterialComponentQuantity, --Consumed Quantity
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      cast(SFIAssembledComponent.MaterialComponentQuantity as mpe_consumed_qty_in_base_unit preserving type) as ResvnItmWithdrawnQtyInBaseUnit,
      @Semantics.unitOfMeasure: true
      SFIAssembledComponent.MaterialBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      SFIAssembledComponent.QuantityInEntryUnit,
      @Semantics.unitOfMeasure: true
      SFIAssembledComponent.EntryUnit,
      SFIAssembledComponent.OrderInternalID,
      SFIAssembledComponent.OrderOperationInternalID,
      SFIAssembledComponent.OperationActivityNetwork,
      SFIAssembledComponent.OpActyNtwkVersionCounter,

      SFIAssembledComponent.MatlCompIsMarkedForBackflush,
      MfgOrderProductPlant.SerialNumberProfile,
      MfgOrderProductPlant.SerialNumberIsRqdForAssembly,
      MfgOrderProductPlant.StockCheckMessageType,
      MfgOrderProductPlant.IsBatchManagementRequired,
      cast(case SFIAssembledComponent.MatlCompIsMarkedForBackflush
        when 'X' then 4
        else MfgOrderProductPlant.MatlCompAssembleControl
      end as mpe_comp_assemble_control preserving type )                                                     as MatlCompAssembleControl,
      SFIAssembledComponent.GoodsMovementIsAllowed,
      SFIAssembledComponent.MatlCompInstceAssyIsRequired,
      _OrderComponent.BillOfMaterialCategory                                                                 as BillOfMaterialCategory,
      _OrderComponent.BillOfMaterialVariant                                                                  as BillOfMaterialVariant,
      _OrderComponent.BillOfMaterialVersion                                                                  as BillOfMaterialVersion,
      _OrderComponent.InheritedBOMItemNode                                                                   as InheritedBOMItemNode,
      SFIAssembledComponent.BOMItemCategory                                                                  as BOMItemCategory,
      cast( SFIAssembledComponent.BillOfMaterialInternalID as mpe_exec_stnum preserving type )               as BillOfMaterialInternalID,
      SFIAssembledComponent.BOMItem                                                                          as BOMItem,
      SFIAssembledComponent.BOMItemInternalChangeCount                                                       as BOMItemInternalChangeCount,

      -- Variable-Size Item Fields
      SFIAssembledComponent.MaterialCompIsVariableSized,
      SFIAssembledComponent.FormulaKey,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      SFIAssembledComponent.VariableSizeDimension1,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      SFIAssembledComponent.VariableSizeDimension2,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      SFIAssembledComponent.VariableSizeDimension3,
      @Semantics.unitOfMeasure: true
      SFIAssembledComponent.VariableSizeDimensionUnit,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeComponentUnit'
      SFIAssembledComponent.VariableSizeComponentQuantity,
      @Semantics.unitOfMeasure: true
      SFIAssembledComponent.VariableSizeComponentUnit,

      SFIAssembledComponent.MfgRefStrucBOMLeafAssgmtUUID,
      SFIAssembledComponent.MfgRefStructureItemDetailUUID,
      SFIAssembledComponent.MfgRefStrucItmDetIsContextual,

      SFIAssembledComponent.BOOOpBOMItemInternalID,
      SFIAssembledComponent.LogicalComponent,
      SFIAssembledComponent.MfgOrderComponentUsageNetQty,

      _Reservation,
      _AssemblyShopFloorItem,
      SFIAssembledComponent._Material,
      SFIAssembledComponent._Plant,
      _StorageLocation,
      SFIAssembledComponent._ProductPlant,
      SFIAssembledComponent._OpActyNtwkInstance,
      SFIAssembledComponent._OperationActivityInstance,
      _MatlCompAssembleControl,
      _OrderComponent,
      SFIAssembledComponent._BOMItemCategory,
      _BOMItmMfgRefStrucItmAssgmt,
      _MfgRefStrucItemWithDetails,
      _MfgRefHierItemWithDetails
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATLPLNTCOMPASSEMBLECONTROL",
"I_ORDERCOMPONENT",
"P_SFIASSEMBLEDCOMPONENT"
],
"ASSOCIATED":
[
"I_BILLOFMATERIALITEMCATEGORY",
"I_BOMITMMFGREFSTRUCITMASSGMT",
"I_MATERIAL",
"I_MATLCOMPASSEMBLECONTROL",
"I_MFGREFHIERITEMWITHDETAILS",
"I_MFGREFSTRUCITEMWITHDETAILS",
"I_OPACTYNTWKINSTANCE",
"I_OPERATIONACTIVITYINSTANCE",
"I_ORDERCOMPONENT",
"I_PLANT",
"I_PRODUCTPLANT",
"I_RESERVATIONDOCUMENTHEADER",
"I_SHOPFLOORITEM",
"I_STORAGELOCATION"
],
"BASE":
[
"P_SFIASSEMBLEDCOMPONENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/