P_RealTimeRptdFinData_06

@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'PREALTIMERFD_06'
@AbapCatalog.compiler.compareFilter: true

@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE
//@AccessControl.authorizationCheck: #NOT_ALLOWED

@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true

define view P_RealTimeRptdFinData_06
  with parameters
    P_CreationDateTimeRgFr :timestamp,
    P_CreationDateTimeRgTo :timestamp

  as select from           P_RealTimeRptdFinData_05
                 (P_CreationDateTimeRgFr : :P_CreationDateTimeRgFr,
                            P_CreationDateTimeRgTo : :P_CreationDateTimeRgTo) as Source

  //  TF103A: Breakdown info for transaction currency (RTCUR) depending on breakdown category (ITGRP)

    left outer to one join I_BreakdownCategoryField tf103a_rtcur                         on  Source.ConsolidationChartOfAccounts = tf103a_rtcur.ConsolidationChartOfAccounts
                                                                                         and Source.BreakdownCategory            = tf103a_rtcur.BreakdownCategory
                                                                                         and tf103a_rtcur.BreakdownCatFieldName  = 'RTCUR'

  //  TF160: Cons. unit master data

    inner join             I_CnsldtnUnit                                                 on  Source.ConsolidationDimension = I_CnsldtnUnit.ConsolidationDimension
                                                                                         and Source.ConsolidationUnit      = I_CnsldtnUnit.ConsolidationUnit


    inner join             I_JournalEntryItem                                 as _acdoca on  Source.SourceLedger        = _acdoca.SourceLedger
                                                                                         and Source.Ledger              = _acdoca.Ledger
                                                                                         and Source.CompanyCode         = _acdoca.CompanyCode
                                                                                         and Source.ReferenceFiscalYear = _acdoca.FiscalYear
                                                                                         and Source.AccountingDocument  = _acdoca.AccountingDocument
                                                                                         and Source.LedgerGLLineItem    = _acdoca.LedgerGLLineItem

  /*association [1..1] to I_JournalEntryItem as _acdoca on  Source.SourceLedger        = _acdoca.SourceLedger
                                                      and Source.Ledger              = _acdoca.Ledger
                                                      and Source.CompanyCode         = _acdoca.CompanyCode
                                                      and Source.ReferenceFiscalYear = _acdoca.FiscalYear
                                                      and Source.AccountingDocument  = _acdoca.AccountingDocument
                                                      and Source.LedgerGLLineItem    = _acdoca.LedgerGLLineItem*/
{
  // Value in transaction currency (TSL): Evaluate breakdown type for RTCUR

  case //only 0 and 2 are possible for RTCUR

      when tf103a_rtcur.BreakdownType = '0'
        or tf103a_rtcur.BreakdownType is null
  //      no breakdown

          then
  //      TSL is never empty: Set local or group currency as default

              case I_CnsldtnUnit.DocumentEntryIsInGroupCurrency
                  when '' then Source.AmountInLocalCurrency
                  when 'X' // The cons. unit provides only values in group currency

                      then Source.AmountInGroupCurrency
              end
      when tf103a_rtcur.BreakdownType = '2'
  //      breakdown required, default allowed

         then Source.AmountInTransactionCurrency
  end                as AmountInTransactionCurrency,

  // Transaction currency key (RTCUR): Evaluate breakdown type

  case  //only 0 and 2 are possible for RTCUR

      when tf103a_rtcur.BreakdownType = '0'
        or tf103a_rtcur.BreakdownType is null
  //      no breakdown

          then
  //    RTCUR is never empty: Set local or group currency as default

              case I_CnsldtnUnit.DocumentEntryIsInGroupCurrency
                  when '' then Source.ConsolidationUnitLocalCurrency
                  when 'X' // The cons. unit provides only values in group currency

                      then Source.GroupCurrency
              end
      when tf103a_rtcur.BreakdownType = '2'
  //      breakdown required, default allowed

          then Source.BalanceTransactionCurrency
  end                as BalanceTransactionCurrency,

  // case

  Source.SubItemCategory,
  Source.SubItem,
  Source.PartnerConsolidationUnit,
  Source.BaseUnit,
  Source.QuantityInBaseUnit,
  Source.FinancialTransactionType,
  Source.FunctionalArea,
  Source.BusinessArea,
  Source.CostCenter,
  Source.GLAccount,
  Source.ProfitCenter,
  Source.Segment,
  Source.AmountInLocalCurrency,
  Source.AmountInGroupCurrency,

  // I_CnsldtnFinStmntItem

  /*Source.BreakdownCategory,*/

  // I_FSItemMappingAssgmtWithVers

  Source.FinancialStatementItem,
  Source.ConsolidationChartOfAccounts,

  // P_ConsolidationUnitCurrency

  Source.ConsolidationUnitLocalCurrency,

  // tfin010

  Source.ConsolidationDimension,
  Source.ConsolidationUnit,

  // I_CnsldtnVersion

  Source.ConsolidationVersion,

  // t881

  Source.ConsolidationLedger,
  Source.GroupCurrency,

  // I_FiscalCalendarDate / Or other source

  Source.FiscalPeriod,
  Source.FiscalYear,

  // mandatory standard fields

  /*Source.BalanceTransactionCurrency,*/
  /*Source.AmountInTransactionCurrency,*/

  // additional fields

  _acdoca.CompanyCode,
  _acdoca.ChartOfAccounts,
  _acdoca.AssignmentReference,
  _acdoca.ControllingArea,
  _acdoca.PartnerCostCenter,
  _acdoca.PartnerProfitCenter,
  _acdoca.PartnerFunctionalArea,
  _acdoca.PartnerBusinessArea,
  _acdoca.PartnerCompany,
  _acdoca.PartnerSegment,
  _acdoca.OrderID,
  _acdoca.Customer,
  _acdoca.Supplier,
  _acdoca.Material,
  _acdoca.MaterialGroup,
  _acdoca.Plant,
  _acdoca.WBSElement as WBSElementExternalID,
  _acdoca.WBSElement,
  _acdoca.Project,
  _acdoca.BillingDocumentType,
  _acdoca.SalesOrganization,
  _acdoca.DistributionChannel,
  _acdoca.OrganizationDivision,
  _acdoca.SoldProduct,
  _acdoca.SoldProductGroup,
  _acdoca.CustomerGroup,
  _acdoca.CustomerSupplierCountry,
  _acdoca.CustomerSupplierIndustry,
  _acdoca.SalesDistrict,
  _acdoca.BillToParty,
  _acdoca.ShipToParty,
  _acdoca.CustomerSupplierCorporateGroup,
  _acdoca.WBSElementInternalID,
  _acdoca.CreationDateTime,

  // specific fileds for this cds view

  /*Source.CompanyCode,*/
  Source.SourceLedger,
  Source.Ledger,
  Source.LedgerGLLineItem,
  Source.AccountingDocument,
  Source.ReferenceFiscalYear

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BREAKDOWNCATEGORYFIELD",
"I_CNSLDTNUNIT",
"I_JOURNALENTRYITEM",
"P_REALTIMERPTDFINDATA_05"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/