P_REALTIMERPTDFINDATA_05

@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'PREALTIMERFD_05'
@AbapCatalog.compiler.compareFilter: true

@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE
//@AccessControl.authorizationCheck: #NOT_ALLOWED

@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true

define view P_RealTimeRptdFinData_05
  with parameters
    P_CreationDateTimeRgFr :timestamp,
    P_CreationDateTimeRgTo :timestamp

  as select from P_RealTimeRptdFinData_04
                    (P_CreationDateTimeRgFr : :P_CreationDateTimeRgFr,
                            P_CreationDateTimeRgTo : :P_CreationDateTimeRgTo) as Source
{
  // begin of bbr n2850362: synchronize subitem and sender fields

  cast(
    case CnsldtnSubitemSource
        when '01' then left(SubItem,3)
        else FinancialTransactionType end
  as rmvct)      as FinancialTransactionType,
  cast(
    case CnsldtnSubitemSource
        when '02' then left(SubItem,16)
        else FunctionalArea end
  as fkber)      as FunctionalArea,
  cast(
    case CnsldtnSubitemSource
        when '03' then left(SubItem,4)
        else BusinessArea end
  as gsber)      as BusinessArea,
  cast(
    case CnsldtnSubitemSource
        when '05' then left(SubItem,10)
        else CostCenter end
  as kostl)      as CostCenter,
  cast(
    case CnsldtnSubitemSource
        when '06' then left(SubItem,10)
        else GLAccount end
  as racct)      as GLAccount,
  cast(
    case CnsldtnSubitemSource
        when '07' then left(SubItem,10)
        else ProfitCenter end
  as prctr)      as ProfitCenter,
  cast(
    case CnsldtnSubitemSource
        when '08' then left(SubItem,10)
        else Segment end
  as fb_segment) as Segment,
  // end of bbr n2850362


  // HSL: Currency RLCURR, field in ACDOCA from customizing for cons. unit

  case Source.CnsldtnUnitLocalCrcySource
    when 'H'
      then Source.AmountInLocalCurrency
    when 'K'
      then Source.AmountInGroupCurrency
    when 'O'
      then Source.osl
    when 'V'
      then Source.vsl
    when 'B'
      then Source.bsl
    when 'C'
      then Source.csl
    when 'D'
      then Source.dsl
    when 'E'
      then Source.esl
    when 'F'
      then Source.fsl
    when 'G'
      then Source.gsl
  end            as AmountInLocalCurrency,

  // KSL: Currrency RGCURR, field in ACDOCA from customizing

  case Source.CnsldtnUnitGroupCrcySource
    when 'H'
      then Source.AmountInLocalCurrency
    when 'K'
      then Source.AmountInGroupCurrency
    when 'O'
      then Source.osl
    when 'V'
      then Source.vsl
    when 'B'
      then Source.bsl
    when 'C'
      then Source.csl
    when 'D'
      then Source.dsl
    when 'E'
      then Source.esl
    when 'F'
      then Source.fsl
    when 'G'
      then Source.gsl
    when ' '
      then case Source.GroupCurrency
        when Source.ConsolidationUnitLocalCurrency
          then Source.AmountInLocalCurrency
        else 0
      end
    else 0
  end            as AmountInGroupCurrency,

  // case

  Source.SubItemCategory,
  Source.SubItem,
  Source.PartnerConsolidationUnit,
  Source.BaseUnit,
  Source.QuantityInBaseUnit,

  // tf110

  /*Source.CnsldtnSubitemSource,*/

  // I_CnsldtnFinStmntItem

  Source.BreakdownCategory,

  // I_FSItemMappingAssgmtWithVers

  Source.FinancialStatementItem,
  Source.ConsolidationChartOfAccounts,

  // P_ConsolidationUnitCurrency

  Source.ConsolidationUnitLocalCurrency,
  /*Source.CnsldtnUnitLocalCrcySource,*/

  // tfin010

  Source.ConsolidationDimension,
  Source.ConsolidationUnit,

  // I_CnsldtnVersion

  Source.ConsolidationVersion,

  // t881

  Source.ConsolidationLedger,
  Source.GroupCurrency,

  // tf168

  /*Source.CnsldtnUnitGroupCrcySource,*/

  // I_FiscalCalendarDate / Or other source

  Source.FiscalPeriod,
  Source.FiscalYear,

  // mandatory standard fields

  Source.BalanceTransactionCurrency,
  /*Source.FinancialTransactionType,*/
  /*Source.FunctionalArea,*/
  /*Source.BusinessArea,*/
  /*Source.CostCenter,*/
  /*Source.GLAccount,*/
  /*Source.ProfitCenter,*/
  Source.AmountInTransactionCurrency,
  /*Source.AmountInLocalCurrency,*/
  /*Source.AmountInGroupCurrency,*/
  /*Source.osl,*/
  /*Source.vsl,*/
  /*Source.bsl,*/
  /*Source.csl,*/
  /*Source.dsl,*/
  /*Source.esl,*/
  /*Source.fsl,*/
  /*Source.gsl,*/
  /*Source.Segment,*/

  // specific fileds for this cds view

  Source.CompanyCode,
  Source.SourceLedger,
  Source.Ledger,
  Source.LedgerGLLineItem,
  Source.AccountingDocument,
  Source.ReferenceFiscalYear

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_REALTIMERPTDFINDATA_04"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/