P_PurOrdSchedLineEnhdDocCat

@AbapCatalog.sqlViewName: 'PPURORDSCHENH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory:  #XL
@VDM.private : true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Time Variance details for various document categoty'
define view P_PurOrdSchedLineEnhdDocCat
  with parameters
    P_StartDate : bedat,
    P_EndDate   : bedat
  as select from I_PurOrdScheduleLineEnhanced as PurchaseOrder

{
      /* Key fields*/
  key PurchaseOrder,
  key PurchaseOrderItem,
  key ScheduleLine,
      cast(concat(PurchaseOrder ,  PurchaseOrderItem ) as char14 ) as PurchaseOrderItemUniqueID,
      PurchaseOrderDate,
      NetAmount,
      DocumentCurrency,
      SchedLineStscDeliveryDate,
      ScheduleLineDeliveryDate,

      OriglPOSchdLnDelivDte,
      OriglPOSchedLineStstclDelivDte,

      cast ( '1' as mmpur_ana_de_se_doc_config )                   as SuplrEvalRelevantDocCategory,
      /* Org Data*/
      PurchasingOrganization,
      PurchasingGroup,
      CompanyCode,

      /* Supplier */
      Supplier,

      /* Material */
      Material,
      MaterialGroup,
      Plant,

      ScheduleLineOrderQuantity,
      PurchaseOrderQuantityUnit,

      PurOrdItmFirstGRPostingDate,
      PurOrdItmFinalGRPostingDate,

      OriglPurOrdItm1stGRPostgDte,
      OriglPurOrdItmFnlGRPostgDte,

      TimeVarianceInDays,
      TimeVarianceInPct,
      TimeVarianceInPctByDelivDate,

      TimeVarianceScore,
      TimeVarianceScoreByDelivDate,
      PurchaseOrderCategory                                        as PurchasingDocumentCategory

}
where
         PurchaseOrderDate            >= $parameters.P_StartDate
  and    PurchaseOrderDate            <= $parameters.P_EndDate
  and(
         PurOrdItmFirstGRPostingDate  > '00000000'
    or   PurOrdItmFirstGRPostingDate != '00000000'
  )
  and    IsReturnsItem                = ''
  and    SupplyingPlant               = ''
  and    not(
       ProductTypeCode                = '2'
       or(
            PurchaseOrderItemCategory = '9'
         or PurchaseOrderItemCategory = '1'
         or PurchaseOrderItemCategory = 'A'
       )
     )

union all select from I_SchedgAgrmtSchedLineEnhcd as PurchaseOrder

{
      /* Key fields*/
  key SchedulingAgreement                                                      as PurchaseOrder,
  key SchedulingAgreementItem                                                  as PurchaseOrderItem,
  key ScheduleLine,
      cast(concat(SchedulingAgreement ,  SchedulingAgreementItem ) as char14 ) as PurchaseOrderItemUniqueID,
      PurchaseOrderDate,
      NetAmount,
      DocumentCurrency,
      SchedLineStscDeliveryDate,
      ScheduleLineDeliveryDate,

      OriglPurgDocSchedLineDelivDte                                            as OriglPOSchdLnDelivDte,
      OriglPurgDocItemStstclDelivDte                                           as OriglPOSchedLineStstclDelivDte,

      cast ( '2' as mmpur_ana_de_se_doc_config )                               as SuplrEvalRelevantDocCategory,
      /* Org Data*/
      PurchasingOrganization,
      PurchasingGroup,
      CompanyCode,

      /* Supplier */
      Supplier,

      /* Material */
      Material,
      MaterialGroup,
      Plant,

      ScheduleLineOrderQuantity,
      PurgDocOrderQuantityUnit                                                 as PurchaseOrderQuantityUnit,

      PurDocItmFirstGRPostingDate                                              as PurOrdItmFirstGRPostingDate,
      PurDocItmFinalGRPostingDate                                              as PurOrdItmFinalGRPostingDate,

      OriglPurgDocItm1stGRPostgDte                                             as OriglPurOrdItm1stGRPostgDte,
      OriglPurgDocItmFnlGRPostgDte                                             as OriglPurOrdItmFnlGRPostgDte,

      TimeVarianceInDays,
      TimeVarianceInPct,
      TimeVarianceInPctByDelivDate,

      TimeVarianceScore,
      TimeVarianceScoreByDelivDate,
      PurchasingDocumentCategory

}
where
         PurchaseOrderDate                 >= $parameters.P_StartDate
  and    PurchaseOrderDate                 <= $parameters.P_EndDate
  and(
         PurDocItmFirstGRPostingDate       > '00000000'
    or   PurDocItmFinalGRPostingDate != '00000000'
  )
  and    IsReturnsItem                     = ''
  and    SupplyingPlant                    = ''
  and    not(
       ProductTypeCode                     = '2'
       or(
            PurchasingDocumentItemCategory = '9'
         or PurchasingDocumentItemCategory = '1'
         or PurchasingDocumentItemCategory = 'A'
       )
     )


union all select from I_PurgDocScheduleLineEnhanced as PurchaseOrder

{
      /* Key fields*/
  key PurchasingDocument                                                     as PurchaseOrder,
  key PurchasingDocumentItem                                                 as PurchaseOrderItem,
  key ScheduleLine,
      cast(concat(PurchasingDocument ,  PurchasingDocumentItem ) as char14 ) as PurchaseOrderItemUniqueID,
      PurchaseOrderDate,
      NetAmount,
      DocumentCurrency,
      SchedLineStscDeliveryDate,
      ScheduleLineDeliveryDate,

      OriglPurgDocSchedLineDelivDte                                          as OriglPOSchdLnDelivDte,
      OriglPurgDocItemStstclDelivDte                                         as OriglPOSchedLineStstclDelivDte,

      cast ( '3' as mmpur_ana_de_se_doc_config )                             as SuplrEvalRelevantDocCategory,
      /* Org Data*/
      PurchasingOrganization,
      PurchasingGroup,
      CompanyCode,

      /* Supplier */
      Supplier,

      /* Material */
      Material,
      MaterialGroup,
      Plant,

      ScheduleLineOrderQuantity,
      PurgDocOrderQuantityUnit                                               as PurchaseOrderQuantityUnit,

      PurDocItmFirstGRPostingDate                                            as PurOrdItmFirstGRPostingDate,
      PurDocItmFinalGRPostingDate                                            as PurOrdItmFinalGRPostingDate,

      OriglPurgDocItm1stGRPostgDte                                           as OriglPurOrdItm1stGRPostgDte,
      OriglPurgDocItmFnlGRPostgDte                                           as OriglPurOrdItmFnlGRPostgDte,

      TimeVarianceInDays,
      TimeVarianceInPct,
      TimeVarianceInPctByDelivDate,

      TimeVarianceScore,
      TimeVarianceScoreByDelivDate,
      PurchasingDocumentCategory

}
where
         PurchaseOrderDate                 >= $parameters.P_StartDate
  and    PurchaseOrderDate                 <= $parameters.P_EndDate
  and(
         PurDocItmFirstGRPostingDate       > '00000000'
    or   PurDocItmFinalGRPostingDate != '00000000'
  )
  and    IsReturnsItem                     = ''
  and    SupplyingPlant                    = ''
  and    not(
       ProductTypeCode                     = '2'
       or(
            PurchasingDocumentItemCategory = '9'
         or PurchasingDocumentItemCategory = '1'
         or PurchasingDocumentItemCategory = 'A'
       )
     )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURGDOCSCHEDULELINEENHANCED",
"I_PURORDSCHEDULELINEENHANCED",
"I_SCHEDGAGRMTSCHEDLINEENHCD"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/