I_SCHEDGAGRMTSCHEDLINEENHCD
Scheduling Agreement from Analytical table
I_SCHEDGAGRMTSCHEDLINEENHCD is a CDS View in S/4HANA. Scheduling Agreement from Analytical table. 2 CDS views read from this table.
CDS Views using this table (2)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_SchdAgrSchdLnEnhcdAPI01 | view | from | COMPOSITE | Sched Agreement with Schedule Line Details |
| P_PurOrdSchedLineEnhdDocCat | view | union_all | CONSUMPTION | Time Variance details for various document categoty |
@AbapCatalog.sqlViewName: 'ISCHEDGAGRMTENHD'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Scheduling Agreement from Analytical table'
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
define view I_SchedgAgrmtSchedLineEnhcd
as select from mmpur_ana_eket as ScheduleLineEnhanced
association [1..1] to I_PurchasingOrganization as _PurchasingOrganization on $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization
association [1..1] to I_PurchasingGroup as _PurchasingGroup on $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
association [1..1] to I_Supplier as _Supplier on $projection.Supplier = _Supplier.Supplier
association [1..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_Plant as _Plant on $projection.Plant = _Plant.Plant
association [1..1] to I_Material as _Material on $projection.Material = _Material.Material
association [1..1] to I_MaterialGroup as _MaterialGroup on $projection.MaterialGroup = _MaterialGroup.MaterialGroup
association [1..1] to I_Currency as _AnalyticalReportingCurrency on $projection.AnalyticalReportingCurrency = _AnalyticalReportingCurrency.Currency
association [1..1] to I_Currency as _AnalyticalReportingCurrency2 on $projection.AnalyticalReportingCurrency2 = _AnalyticalReportingCurrency2.Currency
association [1..1] to I_Currency as _CompanyCodeCurrency on $projection.CompanyCodeCurrency = _CompanyCodeCurrency.Currency
association [1..1] to I_Currency as _DocumentCurrency on $projection.DocumentCurrency = _DocumentCurrency.Currency
association [1..1] to I_UnitOfMeasure as _OrderQuantityUnit on $projection.OrderQuantityUnit = _OrderQuantityUnit.UnitOfMeasure
association [1..1] to I_UnitOfMeasure as _PurgDocQuantityUnit on $projection.PurgDocOrderQuantityUnit = _PurgDocQuantityUnit.UnitOfMeasure
association [0..1] to I_PurgDocumentItemCategory as _PurgDocumentItemCategory on $projection.PurchasingDocumentItemCategory = _PurgDocumentItemCategory.PurchasingDocumentItemCategory
association [1..1] to I_PurchasingDocumentCategory as _PurchasingDocumentCategory on $projection.PurchasingDocumentCategory = _PurchasingDocumentCategory.PurchasingDocumentCategory
association [0..1] to I_PurchasingDocumentType as _PurchasingDocumentType on $projection.PurchasingDocumentCategory = _PurchasingDocumentType.PurchasingDocumentCategory
and $projection.PurchasingDocumentType = _PurchasingDocumentType.PurchasingDocumentType
association [1..1] to I_Deliverydatecategory as _DeliveryDateCategory on $projection.DelivDateCategory = _DeliveryDateCategory.DelivDateCategory
association [0..1] to I_Purchaserequisitionitem as _PurchaseRequisitionItem on $projection.PurchaseRequisition = _PurchaseRequisitionItem.PurchaseRequisition
and $projection.PurchaseRequisitionItem = _PurchaseRequisitionItem.PurchaseRequisitionItem
association [1..1] to I_Purchaserequisition as _PurchaseRequisition on $projection.PurchaseRequisition = _PurchaseRequisition.PurchaseRequisition
association [1..1] to I_BackendSourceSystem as _BackendSourceSystem on $projection.ProcurementHubSourceSystem = _BackendSourceSystem.ProcurementHubSourceSystem
{
key ScheduleLineEnhanced.ebeln as SchedulingAgreement,
key ScheduleLineEnhanced.ebelp as SchedulingAgreementItem,
key ScheduleLineEnhanced.etenr as ScheduleLine,
@ObjectModel.foreignKey.association: '_BackendSourceSystem'
key be_source_sys as ProcurementHubSourceSystem,
ScheduleLineEnhanced.uniqueid as ScheduleLineUniqueID,
//MMPUR_S_ANA_DIMENSION_ATTR
@ObjectModel.foreignKey.association: '_PurchasingOrganization'
ScheduleLineEnhanced.ekorg as PurchasingOrganization,
@ObjectModel.foreignKey.association: '_PurchasingGroup'
ScheduleLineEnhanced.ekgrp as PurchasingGroup,
@ObjectModel.foreignKey.association: '_CompanyCode'
ScheduleLineEnhanced.bukrs as CompanyCode,
@ObjectModel.foreignKey.association: '_Supplier'
ScheduleLineEnhanced.lifnr as Supplier,
@ObjectModel.foreignKey.association: '_Plant'
ScheduleLineEnhanced.werks as Plant,
@ObjectModel.foreignKey.association: '_Material'
ScheduleLineEnhanced.matnr as Material,
@ObjectModel.foreignKey.association: '_MaterialGroup'
ScheduleLineEnhanced.matkl as MaterialGroup,
ScheduleLineEnhanced.serviceperformer as ServicePerformer,
//MMPUR_S_ANA_REPCURR_ATTR
zero_val_repcurr_ind as AnlytlCrcyExchangeRateStatus,
//Currency
@Semantics.currencyCode: true
@ObjectModel.foreignKey.association: '_AnalyticalReportingCurrency'
waers_repcurr1 as AnalyticalReportingCurrency,
@Semantics.currencyCode: true
@ObjectModel.foreignKey.association: '_AnalyticalReportingCurrency2'
waers_repcurr2 as AnalyticalReportingCurrency2,
@Semantics.currencyCode: true
@ObjectModel.foreignKey.association: '_DocumentCurrency'
waers as DocumentCurrency,
@Semantics.currencyCode: true
@ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
waers_base as CompanyCodeCurrency,
// Net Price
@Semantics.amount.currencyCode: 'AnalyticalReportingCurrency'
netpr_repcurr1 as NetPriceInReportingCurrency,
@Semantics.amount.currencyCode: 'AnalyticalReportingCurrency2'
netpr_repcurr2 as NetPriceInReportingCurrency2,
@Semantics.amount.currencyCode: 'DocumentCurrency'
netpr as NetPriceAmount,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
netpr_base as NetPriceInCompanyCodeCrcy,
// Net Amount
@Semantics.amount.currencyCode: 'AnalyticalReportingCurrency'
netwr_sl_repcurr1 as NetAmountInReportingCurrency,
@Semantics.amount.currencyCode: 'AnalyticalReportingCurrency2'
netwr_sl_repcurr2 as NetAmountInReportingCurrency2,
@Semantics.amount.currencyCode: 'DocumentCurrency'
netwr as NetAmount,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
netwr_base as NetAmountInCoCodeCurrency,
//Open Amount
@Semantics.amount.currencyCode: 'AnalyticalReportingCurrency'
obmng_netwr_repcurr1 as OpenAmountInReportingCurrency,
@Semantics.amount.currencyCode: 'AnalyticalReportingCurrency2'
obmng_netwr_repcurr2 as OpenAmountInReportingCurrency2,
@Semantics.amount.currencyCode: 'DocumentCurrency'
obmng_netwr as OpenAmountInDocumentCurrency,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
obmng_netwr_base as OpenAmountInCompanyCodeCrcy,
//MMPUR_S_ANA_OTHER_ATTRIBUTES
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
obmng as ScheduleLineOpenQuantity,
@Semantics.unitOfMeasure: true
@ObjectModel.foreignKey.association: '_OrderQuantityUnit'
meins as OrderQuantityUnit,
elikz as IsCompletelyDelivered,
wepos as GoodsReceiptIsExpected,
loekz as PurchasingDocumentDeletionCode,
memory as PurchasingCompletenessStatus,
@ObjectModel.foreignKey.association: '_PurchasingDocumentCategory'
bstyp as PurchasingDocumentCategory,
@ObjectModel.foreignKey.association: '_PurchasingDocumentType'
bsart as PurchasingDocumentType,
@ObjectModel.foreignKey.association: '_PurgDocumentItemCategory'
pstyp as PurchasingDocumentItemCategory,
knttp as AccountAssignmentCategory,
@Semantics.systemDate.createdAt: true
aedat as CreationDate,
statu as PurchasingDocumentOrigin, // Previously PurchasingDocumentStatus
@Semantics.user.createdBy: true
ernam as CreatedByUser,
lastchangedatetime as LastChangeDateTime,
procstat as PurchasingProcessingStatus,
bedat_pohdr as PurchasingDocumentOrderDate,
isaged as PurchasingDocumentIsAged,
@Semantics.quantity.unitOfMeasure: 'PurgDocOrderQuantityUnit'
menge_ekpo as OrderQuantity,
@Semantics.unitOfMeasure: true
@ObjectModel.foreignKey.association: '_PurgDocQuantityUnit'
meins_ekpo as PurgDocOrderQuantityUnit,
producttype as ProductTypeCode,
frgrl as ReleaseIsNotCompleted,
retpo as IsReturnsItem,
ndd as PurgDocSchdLnHasNextDelivery,
// MMPUR_ANA_EKETDATA
eindt as ScheduleLineDeliveryDate,
slfdt as SchedLineStscDeliveryDate,
or_eindt as OriglPurgDocSchedLineDelivDte,
or_slfdt as OriglPurgDocItemStstclDelivDte,
@ObjectModel.foreignKey.association: '_DeliveryDateCategory'
lpein as DelivDateCategory,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
menge as ScheduleLineOrderQuantity,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
ameng as PrevDelivQtyOfScheduleLine,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
wemng as GoodsReceiptQuantity,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
wamng as ScheduleLineIssuedQuantity,
uzeit as ScheduleLineDeliveryTime,
@ObjectModel.foreignKey.association: '_PurchaseRequisition'
banfn as PurchaseRequisition,
@ObjectModel.foreignKey.association: '_PurchaseRequisitionItem'
bnfpo as PurchaseRequisitionItem,
lgort as StorageLocation,
estkz as SourceOfCreation,
mahnz as PurchasingSchdLnNrOfReminders, //Previously NoOfRemindersOfScheduleLine
abart as SchedulingAgreementReleaseType,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
mng02 as ScheduleLineCommittedQuantity,
mbdat as ProductAvailabilityDate,
mbuhr as ProductAvailabilityTime,
lddat as LoadingDate,
lduhr as LoadingTime,
tddat as TransportationPlanningDate,
tduhr as TransportationPlanningTime,
wadat as GoodsIssueDate,
wauhr as GoodsIssueTime,
eldat as STOLatestPossibleGRDate,
eluhr as STOLatestPossibleGRTime,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
wemng as RoughGoodsReceiptQty,
ktpnr as PurchaseContractItem,
konnr as PurchaseContract,
vrtkz as MultipleAcctAssgmtDistribution,
bedat as PurchaseOrderDate,
bpumz as OrderPriceUnitToOrderUnitNmrtr,
bpumn as OrdPriceUnitToOrderUnitDnmntr,
@Semantics.quantity.unitOfMeasure: 'OrderPriceUnit'
peinh as NetPriceQuantity,
@Semantics.unitOfMeasure: true
bprme as OrderPriceUnit,
startdate as PerformancePeriodStartDate,
enddate as PerformancePeriodEndDate,
reswk as SupplyingPlant,
dimension_ind as PurgDocItmAnlytsIndIsActv,
//Time Variance Data
firstgrpostingdate as PurDocItmFirstGRPostingDate,
finalgrpostingdate as PurDocItmFinalGRPostingDate,
or_firstgrpostingdate as OriglPurgDocItm1stGRPostgDte,
or_finalgrpostingdate as OriglPurgDocItmFnlGRPostgDte,
timevarianceindays as TimeVarianceInDays,
timevarianceinpct as TimeVarianceInPct,
timevarianceinpctbydelivdate as TimeVarianceInPctByDelivDate,
timevariancescore as TimeVarianceScore,
timevariancescorebydelivdate as TimeVarianceScoreByDelivDate,
_BackendSourceSystem,
_PurchaseRequisition,
_PurchaseRequisitionItem,
_DeliveryDateCategory,
_PurgDocQuantityUnit,
_PurchasingOrganization,
_PurchasingGroup,
_CompanyCode,
_Supplier,
_Plant,
_Material,
_MaterialGroup,
_PurchasingDocumentCategory,
_PurchasingDocumentType,
_PurgDocumentItemCategory,
_AnalyticalReportingCurrency,
_AnalyticalReportingCurrency2,
_DocumentCurrency,
_CompanyCodeCurrency,
_OrderQuantityUnit
}
where
bstyp = 'L'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MMPUR_ANA_EKET"
],
"ASSOCIATED":
[
"I_BACKENDSOURCESYSTEM",
"I_COMPANYCODE",
"I_CURRENCY",
"I_DELIVERYDATECATEGORY",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_PLANT",
"I_PURCHASEREQUISITION",
"I_PURCHASEREQUISITIONITEM",
"I_PURCHASINGDOCUMENTCATEGORY",
"I_PURCHASINGDOCUMENTTYPE",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_PURGDOCUMENTITEMCATEGORY",
"I_SUPPLIER",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/