P_ProfitCenterTP

@AbapCatalog.sqlViewName: 'PFIPRFTCTRTP'
@AbapCatalog.compiler.compareFilter: true
//@EndUserText.label: 'Private view for Profit Center TP'

@VDM.private: true
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.dataClass: #ORGANIZATIONAL
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: [ '_UserCrtedContactCard' ]

define view P_ProfitCenterTP

  as select from I_ProfitCenter

  //  association [0..1] to I_UserContactCard as _UserRespContactCard  on $projection.CostCtrResponsibleUser = _UserRespContactCard.ContactCardID

  association [0..1] to I_UserContactCard as _UserCrtedContactCard on $projection.ProfitCenterCreatedByUser = _UserCrtedContactCard.ContactCardID


{
      @ObjectModel.foreignKey.association: '_ControllingArea'
  key ControllingArea,
      @ObjectModel.hierarchy.association: '_ProfitCenterHierarchyNode'
  key ProfitCenter,
  key ValidityEndDate,
      ValidityStartDate,
      cast ( ProfitCtrResponsiblePersonName as verak)                                                                  as ProfitCtrResponsiblePersonName,
      @ObjectModel.foreignKey.association: '_Company'
      CompanyCode,
      ProfitCtrResponsibleUser,
      Department,
      cast( ProfitCenterStandardHierarchy as fac_mpc_pcg preserving type )                                             as ProfitCenterStandardHierarchy,
      @ObjectModel.foreignKey.association: '_Segment'
      Segment,
      cast ( ProfitCenterIsBlocked as fac_mpc_lock_indicator )                                                         as ProfitCenterIsBlocked,
      FormulaPlanningTemplate,
      FormOfAddress,
      AddressName,
      AdditionalName,
      ProfitCenterAddrName3,
      ProfitCenterAddrName4,
      StreetAddressName,
      POBox,
      CityName,
      PostalCode,
      POBoxPostalCode,
      District,
      @ObjectModel.foreignKey.association: '_Country'
      cast(Country as fis_land1 preserving type )                                                                      as Country,
      @ObjectModel.foreignKey.association: '_Region'
      Region,
      TaxJurisdiction,
      @ObjectModel.foreignKey.association: '_Language'
      Language,
      PhoneNumber1,
      PhoneNumber2,
      cast( TeleboxNumber as fac_mpc_comm_telbx preserving type )                                                      as TeleboxNumber,
      cast( TelexNumber as fac_mpc_comm_telx1 preserving type )                                                        as TelexNumber,
      cast( TeletexNumber as fac_mpc_teltx preserving type )                                                           as TeletexNumber,
      FaxNumber,
      cast( DataCommunicationPhoneNumber as fac_mpc_comm_data_line preserving type )                                   as DataCommunicationPhoneNumber,
      cast( ProfitCenterPrinterName as fac_mpc_comm_printer preserving type )                                          as ProfitCenterPrinterName,
      @ObjectModel.foreignKey.association: '_UserCrtedContactCard'
      ProfitCenterCreatedByUser,
      cast ( ProfitCenterCreationDate as ersda)                                                                        as ProfitCenterCreationDate,
      _UserCrtedContactCard.FullName                                                                                   as CreatedByUserFullName,

      case( length( ControllingArea ) )
      when 2 then cast( concat_with_space(ControllingArea, ProfitCenter, 2 ) as cdobjectv )
      when 3 then cast( concat_with_space(ControllingArea, ProfitCenter, 1 ) as cdobjectv )
      else cast( concat(ControllingArea, ProfitCenter) as cdobjectv ) end                                              as ChangeDocObject,

      cast( concat('PC', concat(ControllingArea, ProfitCenter)) as fac_mpc_resparea )                                  as ProfitCenterResponsibilityArea,
      cast( concat('PH', concat(ControllingArea, ProfitCenterStandardHierarchy)) as fac_mpc_hier_resparea )            as ProfitCenterHierarchyRespyArea,

      _Text[1:Language=$session.system_language].ProfitCenterName,
      cast( _Text[1:Language=$session.system_language].ProfitCenterLongName as fac_prctr_ltext_short preserving type ) as ProfitCenterLongName,
      _ControllingAreaText.ControllingAreaName,
      _Company.CompanyCodeName,


      _Text,
      _Country,
      _ControllingArea,
      _ProfitCenterHierarchyNode,
      _Language,
      _Company,
      _Segment,
      _Region,
      _ControllingAreaText,
      _SegmentText,

      _UserCrtedContactCard
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_PROFITCENTER",
"I_PROFITCENTERTEXT",
"I_USERCONTACTCARD"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COUNTRY",
"I_LANGUAGE",
"I_PROFITCENTERHIERARCHYNODE",
"I_PROFITCENTERTEXT",
"I_REGION",
"I_SEGMENT",
"I_SEGMENTTEXT",
"I_USERCONTACTCARD"
],
"BASE":
[
"I_PROFITCENTER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/