I_ProfitCenterTP

@AbapCatalog: {
  sqlViewName: 'IFIPRFTCTRTP',
  compiler.compareFilter: true
}

@VDM.viewType: #TRANSACTIONAL

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: [ '_UserCrtedContactCard' ]

@EndUserText.label: 'Profit Center Master Record'

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ClientHandling.algorithm: #SESSION_VARIABLE

// BOPF

@ObjectModel: {
    compositionRoot: true,
    modelCategory: #BUSINESS_OBJECT,
    transactionalProcessingEnabled: true,
    writeDraftPersistence: 'CEPC_DRAFT',
    draftEnabled: true,
    createEnabled: true,
    updateEnabled: 'EXTERNAL_CALCULATION',
    deleteEnabled: 'EXTERNAL_CALCULATION',
    semanticKey: [ 'ValidityEndDate', 'ControllingArea', 'ProfitCenter' ],
    entityChangeStateId: 'EXTERNAL_CALCULATION',
    usageType: {
        sizeCategory: #L,
        serviceQuality: #D,
        dataClass: #ORGANIZATIONAL
    },
    sapObjectNodeType.name: 'ProfitCenter'
}

@Metadata.allowExtensions: true


define view I_ProfitCenterTP
  as select from P_ProfitCenterTP

  association [0..*] to I_ProfitCenterTextTP        as _MultiLangText               on  $projection.ControllingArea = _MultiLangText.ControllingArea
                                                                                    and $projection.ProfitCenter    = _MultiLangText.ProfitCenter
                                                                                    and $projection.ValidityEndDate = _MultiLangText.ValidityEndDate

  association [1]    to I_ControllingArea           as _ControllingAreaForEdit      on  $projection.ControllingAreaForEdit = _ControllingAreaForEdit.ControllingArea
  association [0..*] to I_ProfitCenterHierarchyNode as _ProfitCenterHierNodeForEdit on  $projection.ControllingAreaForEdit = _ProfitCenterHierNodeForEdit.ControllingArea
                                                                                    and $projection.ProfitCenterForEdit    = _ProfitCenterHierNodeForEdit.ProfitCenter

  association [0..*] to I_PrftCtrCompCodeAssgmtTP   as _CompanyCodeAssignment       on  $projection.ControllingArea = _CompanyCodeAssignment.ControllingArea
                                                                                    and $projection.ProfitCenter    = _CompanyCodeAssignment.ProfitCenter
                                                                                    and $projection.ValidityEndDate = _CompanyCodeAssignment.ValidityEndDate

  //Extention Include

  association [1..1] to E_ProfitCenter              as _Extension                   on  $projection.ControllingArea = _Extension.ControllingArea
                                                                                    and $projection.ProfitCenter    = _Extension.ProfitCenter
                                                                                    and $projection.ValidityEndDate = _Extension.ValidityEndDate
{
  key ControllingArea,
  key ProfitCenter,
  key ValidityEndDate,
      @ObjectModel.foreignKey.association: '_ControllingAreaForEdit'
      @ObjectModel.mandatory: true
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.editableFieldFor: 'ControllingArea'
      ControllingArea                                                                              as ControllingAreaForEdit,
      @ObjectModel.hierarchy.association: '_ProfitCenterHierNodeForEdit'
      @ObjectModel.mandatory: true
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.editableFieldFor: 'ProfitCenter'
      ProfitCenter                                                                                 as ProfitCenterForEdit,
      @Semantics.businessDate.to: true
      @ObjectModel.mandatory: true
      @ObjectModel.editableFieldFor: 'ValidityEndDate'
      ValidityEndDate                                                                              as ValidityEndDateForEdit,
      @Semantics.businessDate.from: true
      @ObjectModel.mandatory: true
      ValidityStartDate,
      @ObjectModel.mandatory: true
      ProfitCenterName,
      ProfitCenterLongName,
      //      @ObjectModel.mandatory: true

      //@ObjectModel.foreignKey.association: '_CompanyCode'

      CompanyCode,
      @ObjectModel.mandatory: true
      ProfitCtrResponsiblePersonName,
      ProfitCtrResponsibleUser,
      @ObjectModel.readOnly: true
      ProfitCenterCreationDate,
      @ObjectModel.readOnly: true
      ProfitCenterCreatedByUser,
      Department,
      @ObjectModel.mandatory: true
      ProfitCenterStandardHierarchy,
      Segment,
      ProfitCenterIsBlocked,
      Country,
      FormOfAddress,  //Title anred

      AddressName,    //Name1 name1

      AdditionalName, //Name2 name2

      CityName,       //City  ort01

      District,       //District ort02

      ProfitCenterAddrName3, //Name3 name3

      ProfitCenterAddrName4, //Name4 name4

      StreetAddressName,     //Street stras

      POBox,                 //P.O.Box PFACH

      PostalCode,            //Postal Code PSTLZ

      POBoxPostalCode,
      Region,                //Region REGIO

      TaxJurisdiction, //Tax Jur. TXJCD

      Language,        //Language spras

      TeleboxNumber,   //Telebox   telbx

      PhoneNumber1,    //Telephone 1 telf1

      PhoneNumber2,    //Telephone 2 telf2

      FaxNumber,       //Fax Number telfx

      TelexNumber,     //Telex telx1

      TeletexNumber,
      DataCommunicationPhoneNumber, //Data line datlt

      ProfitCenterPrinterName, //Printer name drnam

      @ObjectModel.readOnly: true
      ControllingAreaName,
      @ObjectModel.readOnly: true
      CompanyCodeName,
      @ObjectModel.readOnly: true
      CreatedByUserFullName,

      cast(concat ( concat( ControllingArea, ProfitCenter), ValidityEndDate ) as hash160)          as ETag,
      ChangeDocObject,

      // following 2 fields are for authority check.

      @ObjectModel.readOnly: true
      ProfitCenterResponsibilityArea,
      @ObjectModel.readOnly: true
      ProfitCenterHierarchyRespyArea,

      cast('' as fac_mpc_tp_action)                                                                as PrftCtrTransaclProcgAction,

      @ObjectModel.readOnly: true
      cast( concat(ValidityStartDate, concat('-',ValidityEndDate)) as profitcentervalidityperiod ) as ProfitCenterValidityPeriod,

      _Text,
      _Country,
      _ControllingArea,
      _ControllingAreaForEdit,
      _ProfitCenterHierarchyNode,
      _ProfitCenterHierNodeForEdit,
      _Language,
      _Company,
      _Region,
      _ControllingAreaText,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _CompanyCodeAssignment,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _MultiLangText,

      _UserCrtedContactCard

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_PROFITCENTERTP"
],
"ASSOCIATED":
[
"E_PROFITCENTER",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COUNTRY",
"I_LANGUAGE",
"I_PRFTCTRCOMPCODEASSGMTTP",
"I_PROFITCENTERHIERARCHYNODE",
"I_PROFITCENTERTEXT",
"I_PROFITCENTERTEXTTP",
"I_REGION",
"I_USERCONTACTCARD"
],
"BASE":
[
"P_PROFITCENTERTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/