P_ProfitCenterChangeLog

@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel.usageType: {
  dataClass: #TRANSACTIONAL,
  serviceQuality: #C,
  sizeCategory: #L
}
@VDM: {
  private: true,
  viewType: #CONSUMPTION
}
define view entity P_ProfitCenterChangeLog
  as select from I_ChangeDocumentItem
{
  key I_ChangeDocumentItem.ChangeDocObject,
  key I_ChangeDocumentItem.ChangeDocObjectClass,
  key I_ChangeDocumentItem.ChangeDocument,
  key I_ChangeDocumentItem.DatabaseTable,
  key I_ChangeDocumentItem.ChangeDocTableKey,
  key I_ChangeDocumentItem.ChangeDocDatabaseTableField,
  key I_ChangeDocumentItem.ChangeDocItemChangeType,

      I_ChangeDocumentItem.ChangeDocPreviousUnit,
      I_ChangeDocumentItem.ChangeDocNewUnit,
      I_ChangeDocumentItem.ChangeDocPreviousCurrency,
      I_ChangeDocumentItem.ChangeDocNewCurrency,
      cast ( I_ChangeDocumentItem.ChangeDocPreviousFieldValue as fis_cc_old_fieldval preserving type ) as ChangeDocPreviousFieldValue,
      cast ( I_ChangeDocumentItem.ChangeDocNewFieldValue as fis_cc_new_fieldval preserving type )      as ChangeDocNewFieldValue,
      cast ( substring(I_ChangeDocumentItem.ChangeDocTableKey, 1, 3) as mandt )                        as ChangeDocumentSAPClient,
      cast ( substring(I_ChangeDocumentItem.ChangeDocTableKey, 4, 4) as kokrs )                        as ControllingArea,
      cast ( substring(I_ChangeDocumentItem.ChangeDocTableKey, 8, 10) as prctr )                       as ProfitCenter,
      cast ( substring(I_ChangeDocumentItem.ChangeDocTableKey, 18, 8) as datbis )                      as ValidityEndDate,
      cast ( substring(I_ChangeDocumentItem.ChangeDocTableKey, 26, 8) as datab )                       as ValidityStartDate,
      I_ChangeDocumentItem.ChangeDocDatabaseTableField                                                 as DatabaseTableFieldName,
      I_ChangeDocumentItem.DatabaseTable                                                               as ObjectDatabaseTable,

      /* Associations */
      _ChangeDocument.CreatedByUser,
      _ChangeDocument.CreationDate,
      _ChangeDocument.CreationTime,
      _ChangeDocument.ChangeDocLanguage,
      _ChangeDocLongTableKey,
      _ChangeDocument,
      _ChangeDocumentItemExtension
}
where
      I_ChangeDocumentItem.ChangeDocObjectClass = 'PRCTR'
  and I_ChangeDocumentItem.DatabaseTable        = 'CEPCB'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEDOCUMENT",
"I_CHANGEDOCUMENTITEM"
],
"ASSOCIATED":
[
"I_CHANGEDOCLONGTABLEKEY",
"I_CHANGEDOCUMENT",
"I_CHANGEDOCUMENTITEMEXTENSION"
],
"BASE":
[
"I_CHANGEDOCUMENTITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/