@AbapCatalog.sqlViewName: 'PMPEOAEXEC'
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE
@VDM.private: true
@AbapCatalog.compiler.compareFilter: true
define view P_ProcgExecOperationActivity
as select from I_OpActyInstanceStatusBasic as OpActyInstanceStatusBasic
inner join I_OpActyInstceOpActyNtwkElmnt as OpActyInstceOpActyNtwkElmnt on OpActyInstanceStatusBasic.OpActyNtwkInstance = OpActyInstceOpActyNtwkElmnt.OpActyNtwkInstance
and OpActyInstanceStatusBasic.OpActyNtwkElement = OpActyInstceOpActyNtwkElmnt.OpActyNtwkElement
inner join I_OrderOperationDateTime as MfgOrderOperation on MfgOrderOperation.OrderInternalID = OpActyInstceOpActyNtwkElmnt.OrderInternalID
and MfgOrderOperation.OrderOperationInternalID = OpActyInstceOpActyNtwkElmnt.OrderOperationInternalID
inner join I_MfgOrderBasic as LogisticsOrder on LogisticsOrder.ManufacturingOrder = OpActyInstceOpActyNtwkElmnt.ManufacturingOrder
association [1..1] to I_Plant as _ProductionPlant on $projection.ProductionPlant = _ProductionPlant.Plant
association [0..*] to I_MfgOrderDocInfoRecdObjLink as _MfgOrderDocInfoRecdObjLink on $projection.ManufacturingOrder = _MfgOrderDocInfoRecdObjLink.ManufacturingOrder
association [0..*] to I_MfgOrderOpDocInfoRecdObjLink as _MfgOrderOpDocInfoRecdObjLink on $projection.ManufacturingOrder = _MfgOrderOpDocInfoRecdObjLink.ManufacturingOrder
and $projection.OrderOperationInternalID = _MfgOrderOpDocInfoRecdObjLink.OrderOperationInternalID
association [0..*] to I_OpActyDocInfoRecdObjLink as _OpActyDocInfoRecdObjLink on $projection.OpActyNtwkInstance = _OpActyDocInfoRecdObjLink.OpActyNtwkInstance
and $projection.OpActyNtwkElement = _OpActyDocInfoRecdObjLink.OpActyNtwkElement
association [0..1] to I_WorkCenterBySemanticKey as _WorkCenterBySemanticKey on $projection.workcenter = _WorkCenterBySemanticKey.WorkCenter
and $projection.ProductionPlant = _WorkCenterBySemanticKey.Plant
association [0..*] to I_OpActyMainWrkCtrMfgUser as _OpActyMainWrkCtrMfgUser on $projection.OpActyNtwkInstance = _OpActyMainWrkCtrMfgUser.OpActyNtwkInstance
and $projection.OpActyNtwkElement = _OpActyMainWrkCtrMfgUser.OpActyNtwkElement
{
@ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
key OpActyInstceOpActyNtwkElmnt.OpActyNtwkInstance,
key OpActyInstceOpActyNtwkElmnt.OpActyNtwkElement,
@ObjectModel.foreignKey.association: '_OpActyNtwkInternalId'
OpActyInstceOpActyNtwkElmnt.OperationActivityNetwork,
@ObjectModel.foreignKey.association: '_OperationActivityNetwork'
OpActyInstceOpActyNtwkElmnt.OpActyNtwkVersionCounter,
@Semantics.quantity.unitOfMeasure: 'ProductionUnit'
OpActyInstceOpActyNtwkElmnt.OpPlannedScrapQuantity,
@Semantics.quantity.unitOfMeasure: 'ProductionUnit'
OpActyInstceOpActyNtwkElmnt.OpPlannedYieldQuantity,
@Semantics.unitOfMeasure: true
OpActyInstceOpActyNtwkElmnt.ProductionUnit,
@Semantics.durationInSeconds: true
OpActyInstceOpActyNtwkElmnt.OpActyExpdExecDurnInSeconds,
@Semantics.durationInSeconds: true
OpActyInstceOpActyNtwkElmnt.OpActyExpdExecLaborDurnInSecs,
@ObjectModel.foreignKey.association: '_OrderInternalID'
OpActyInstceOpActyNtwkElmnt.OrderInternalID,
OpActyInstceOpActyNtwkElmnt.OrderOperationInternalID,
@ObjectModel.foreignKey.association: '_SASSchema'
OpActyInstceOpActyNtwkElmnt.StatusAndActionSchema,
@ObjectModel.foreignKey.association: '_SASStatus'
OpActyInstanceStatusBasic.StatusAndActionSchemaStatus,
cast(OpActyInstceOpActyNtwkElmnt.OpActyConfIsSFIBased as boolean preserving type) as OpActyConfIsSFIBased,
OpActyInstceOpActyNtwkElmnt.OpActyNtwkElementExternalID,
OpActyInstceOpActyNtwkElmnt.OperationActivity,
OpActyInstceOpActyNtwkElmnt.OperationActyVersionCounter,
OpActyInstceOpActyNtwkElmnt.OpActyNtwkElementElement,
OpActyInstceOpActyNtwkElmnt.OpActyNtwkElementElmntVersCntr,
OpActyInstceOpActyNtwkElmnt.OpActyNtwkSegmentType,
OpActyInstceOpActyNtwkElmnt.OANElementDisplaySqncNumber,
OpActyInstanceStatusBasic._SASStatus.SASStatusCriticality,
OpActyInstanceStatusBasic._SASStatus.SASStatusCategory,
@Semantics.calendarItem.dtStart: true
MfgOrderOperation.OpActualExecutionStartDate,
MfgOrderOperation.OpActualExecutionStartTime,
@Semantics.calendarItem.dtStart: true
MfgOrderOperation.OpLtstSchedldExecStrtDte,
MfgOrderOperation.OpLtstSchedldExecStrtTme,
@Semantics.calendarItem.dtStart: true
MfgOrderOperation.OpLtstSchedldProcgStrtDte,
MfgOrderOperation.OpLtstSchedldProcgStrtTme,
@Semantics.calendarItem.dtStart: true
MfgOrderOperation.OpLtstSchedldTrdwnStrtDte,
MfgOrderOperation.OpLtstSchedldTrdwnStrtTme,
cast( case
when MfgOrderOperation.OpActualExecutionStartDate <> '00000000' then
MfgOrderOperation.OpActualExecutionStartDateTime
when OpActyInstceOpActyNtwkElmnt.OpActyNtwkSegmentType = '1' then
MfgOrderOperation.OpLtstSchedldExecStrtDteTme
when OpActyInstceOpActyNtwkElmnt.OpActyNtwkSegmentType = '2' then
MfgOrderOperation.OpLtstSchedldProcgStrtDteTme
else
MfgOrderOperation.OpLtstSchedldTrdwnStrtDteTme
end as mpe_oper_schedld_start_time preserving type ) as OpLtstSchedldExecStrtDteTme,
cast( case
when MfgOrderOperation.OpActualExecutionStartDate <> '00000000' then 'X'
else ''
end as boolean preserving type ) as DateIsActualDate,
@ObjectModel.foreignKey.association: '_MfgOrder'
@ObjectModel.text.element: 'ManufacturingOrderText'
OpActyInstceOpActyNtwkElmnt.ManufacturingOrder,
LogisticsOrder.ManufacturingOrderText,
LogisticsOrder.ManufacturingOrderImportance,
@ObjectModel.text.element: 'MfgOrderOperationText'
MfgOrderOperation.Operation as ManufacturingOrderOperation,
@Semantics.text: true
MfgOrderOperation.OperationText as MfgOrderOperationText,
MfgOrderOperation.Operation as MfgOrderOperationOrSubOp, --Used for search only
LogisticsOrder.ExtdQualityCheckIsRequired as ExtdQualityCheckIsRequired,
@ObjectModel.foreignKey.association: '_ProductionPlant'
@ObjectModel.text.element: 'ProductionPlantName'
MfgOrderOperation.Plant as ProductionPlant,
MfgOrderOperation.PlantName as ProductionPlantName,
@ObjectModel.foreignKey.association: '_WorkCenter'
MfgOrderOperation.WorkCenterInternalID,
@ObjectModel.foreignKey.association: '_WorkCenterType'
MfgOrderOperation.WorkCenterTypeCode,
@ObjectModel.foreignKey.association: '_WorkCenterBySemanticKey'
MfgOrderOperation._WorkCenter.WorkCenter,
MfgOrderOperation._WorkCenter._Text[1: Language=$session.system_language].WorkCenterText,
MfgOrderOperation._WorkCenter.LaborTrackingIsRequired,
@Semantics.quantity.unitOfMeasure: 'OperationUnit'
MfgOrderOperation.OpPlannedTotalQuantity,
@Semantics.unitOfMeasure: true
MfgOrderOperation.OperationUnit,
OpActyInstceOpActyNtwkElmnt._OpActyNtwkInstance,
OpActyInstceOpActyNtwkElmnt._SASSchema,
OpActyInstanceStatusBasic._SASStatus,
OpActyInstceOpActyNtwkElmnt._OpActyNtwkInternalId,
OpActyInstceOpActyNtwkElmnt._OperationActivityNetwork,
OpActyInstceOpActyNtwkElmnt._OrderInternalID,
OpActyInstceOpActyNtwkElmnt._MfgOrder,
OpActyInstceOpActyNtwkElmnt._OperationActivityText,
_ProductionPlant,
MfgOrderOperation._WorkCenter,
_WorkCenterType,
_WorkCenterBySemanticKey,
_MfgOrderDocInfoRecdObjLink,
_MfgOrderOpDocInfoRecdObjLink,
_OpActyDocInfoRecdObjLink,
_OpActyMainWrkCtrMfgUser
}
where
-- Only "open" Operation Activities
(
OpActyInstanceStatusBasic._SASStatus.SASStatusCategory = 1 -- Initial
or OpActyInstanceStatusBasic._SASStatus.SASStatusCategory = 2 -- In Process
or OpActyInstanceStatusBasic._SASStatus.SASStatusCategory = 5 -- Paused
)
and(
OpActyInstceOpActyNtwkElmnt.OpActyConfirmationIsAllowed = 'X'
or OpActyInstceOpActyNtwkElmnt.OpActyConfNotAllowedReason = 1
or OpActyInstceOpActyNtwkElmnt.OpActyConfNotAllowedReason = 2
or OpActyInstceOpActyNtwkElmnt.OpActyConfNotAllowedReason = 4
or OpActyInstceOpActyNtwkElmnt.OpActyConfNotAllowedReason = 5
)
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MFGORDERBASIC",
"I_OPACTYINSTANCESTATUSBASIC",
"I_OPACTYINSTCEOPACTYNTWKELMNT",
"I_ORDEROPERATIONDATETIME",
"I_SASSTATUS",
"I_WORKCENTER",
"I_WORKCENTERTEXT"
],
"ASSOCIATED":
[
"I_MFGORDER",
"I_MFGORDERDOCINFORECDOBJLINK",
"I_MFGORDEROPDOCINFORECDOBJLINK",
"I_OPACTYDOCINFORECDOBJLINK",
"I_OPACTYMAINWRKCTRMFGUSER",
"I_OPACTYNTWKINSTANCE",
"I_OPACTYNTWKINTERNALID",
"I_OPERATIONACTIVITYNETWORK",
"I_OPERATIONACTIVITYTEXT",
"I_ORDINTERNALBILLOFOPERATIONS",
"I_PLANT",
"I_SASSCHEMA",
"I_SASSTATUS",
"I_WORKCENTER",
"I_WORKCENTERBYSEMANTICKEY",
"I_WORKCENTERTYPE"
],
"BASE":
[
"I_OPACTYINSTANCESTATUSBASIC",
"I_OPACTYINSTCEOPACTYNTWKELMNT",
"I_ORDEROPERATIONDATETIME"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/