I_MfgOrderOpDocInfoRecdObjLink

@AbapCatalog.sqlViewName: 'IPPMFGOROPDOCOBL'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: ['_CreatedUser', '_ChangedUser']
@Analytics.dataCategory: #DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.representativeKey:'LinkedSAPObjectKey'
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Mfg Order Operation Document Info Record Object Link'

/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ]  } */
define view I_MfgOrderOpDocInfoRecdObjLink
  as select from P_MfgOrderDocInfoRecdObjLink as doc

  association [1..1] to I_ManufacturingOrder          as _MfgOrder           on  $projection.ManufacturingOrder = _MfgOrder.ManufacturingOrder
  association [1..1] to I_ManufacturingOrderSequence  as _MfgOrderSequence   on  $projection.ManufacturingOrder         = _MfgOrderSequence.ManufacturingOrder
                                                                             and $projection.ManufacturingOrderSequence = _MfgOrderSequence.ManufacturingOrderSequence
  association [1..1] to I_MfgOrderOperationBySemanKey as _MfgOrderOperation  on  $projection.ManufacturingOrder          = _MfgOrderOperation.ManufacturingOrder
                                                                             and $projection.ManufacturingOrderSequence  = _MfgOrderOperation.ManufacturingOrderSequence
                                                                             and $projection.ManufacturingOrderOperation = _MfgOrderOperation.ManufacturingOrderOperation
  association [1..1] to I_MfgOrderOperationBySemKey   as _MfgOrderOperation2 on  $projection.ManufacturingOrder            = _MfgOrderOperation2.ManufacturingOrder
                                                                             and $projection.ManufacturingOrderSequence    = _MfgOrderOperation2.ManufacturingOrderSequence
                                                                             and $projection.ManufacturingOrderOperation_2 = _MfgOrderOperation2.ManufacturingOrderOperation
  association [0..1] to I_ChangeMaster                as _ChangeNumber       on  $projection.ChangeNumber = _ChangeNumber.ChangeNumber
  association [0..1] to I_User                        as _CreatedUser        on  $projection.CreatedByUser = _CreatedUser.UserID
  association [0..1] to I_User                        as _ChangedUser        on  $projection.ChangedBy = _ChangedUser.UserID
{
--    @ObjectModel.text.association: '_Text'
  key doc.LinkedSAPObjectKey,
      @ObjectModel.foreignKey.association: '_DocumentType'
  key doc.DocumentType,
      @ObjectModel.foreignKey.association: '_DocumentNumber'
  key doc.DocumentInfoRecord,
      @ObjectModel.foreignKey.association: '_DocumentPart'
  key cast(doc.DocumentPart    as pph_doktl preserving type)             as DocumentPart,
      @ObjectModel.foreignKey.association: '_DocumentVersion'
  key cast(doc.DocumentVersion as pph_dokvr preserving type)             as DocumentVersion,

      // Administrative Data

      @Semantics.systemDateTime.createdAt: true
      cast(doc.CreationDateTime  as hp_created_at preserving type)       as CreationDateTime,
      @Semantics.user.createdBy: true
      cast(doc.CreatedByUser     as ernam         preserving type)       as CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      cast(doc.ChangedDateTime   as hp_changed_at preserving type)       as ChangedDateTime,
      @Semantics.user.lastChangedBy: true
      cast(doc.LastChangedByUser as aenam         preserving type)       as ChangedBy,

      // Document Data

      doc.InternalDocumentStatus,
      @ObjectModel.foreignKey.association: '_ChangeNumber'
      doc.ChangeNumber,
      doc.AuthorizationGroup,
      @Semantics.user.responsible: true
      cast(doc.ResponsiblePersonName as pph_dwnam preserving type)       as ResponsiblePersonName,

      // Miscellaneous Data

      doc.DocInfoRecdLinkStatus,
      doc.DocInfoRecdObjectLinkStatus,
      doc.ObjectTypeDatabaseTable,
      @Semantics.booleanIndicator 
      doc.DocLinkDirectionIsActive,
      doc.IsDefaultDocument,
      @Semantics.booleanIndicator
      doc.DocInfoRecdIsMarkedForDeletion,

      // Mfg Order Operation Data

      @ObjectModel.foreignKey.association: '_MfgOrder'
      cast(doc.ManufacturingOrder          as co_aufnr  preserving type) as ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_MfgOrderSequence'
      cast(doc.ManufacturingOrderSequence  as plnfolge  preserving type) as ManufacturingOrderSequence,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'ManufacturingOrderOperation_2'
      cast(doc.ManufacturingOrderOperation as vornr_auf preserving type) as ManufacturingOrderOperation,   // with conv. exit

      @ObjectModel.foreignKey.association: '_MfgOrderOperation2'
      cast(doc.ManufacturingOrderOperation as vdm_vornr preserving type) as ManufacturingOrderOperation_2, // w/o conv. exit

      case
        when doc.OrderOperationInternalID = '' or doc.OrderOperationInternalID = '        '
          then cast('00000000' as co_aplzl preserving type)
        else cast(doc.OrderOperationInternalID as co_aplzl)
      end                                                                as OrderOperationInternalID,
      @ObjectModel.foreignKey.association: '_MfgOrderCategory'
      doc.ManufacturingOrderCategory,
      @ObjectModel.foreignKey.association: '_MfgOrderType'
      doc.ManufacturingOrderType,

      // Associations

      _CreatedUser,
      _ChangedUser,
      doc._DocumentNumber,
      doc._DocumentType,
      doc._DocumentVersion,
      doc._DocumentPart,
      _ChangeNumber,
      _MfgOrder,
      _MfgOrderSequence,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_MfgOrderOperation2'
      _MfgOrderOperation,
      _MfgOrderOperation2,
      doc._MfgOrderCategory,
      doc._MfgOrderType,
      doc._Text
}
where
  doc.MfgOrderLinkedObjType = 'O'; // doc links on operation level only

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_MFGORDERDOCINFORECDOBJLINK"
],
"ASSOCIATED":
[
"I_CHANGEMASTER",
"I_DOCUMENTINFORECORDDESC",
"I_DOCUMENTINFORECORDDOCNUMBER",
"I_DOCUMENTINFORECORDDOCPRT",
"I_DOCUMENTINFORECORDDOCTYPE",
"I_DOCUMENTINFORECORDDOCVERSION",
"I_MANUFACTURINGORDER",
"I_MANUFACTURINGORDERSEQUENCE",
"I_MFGORDERCATEGORY",
"I_MFGORDEROPERATIONBYSEMANKEY",
"I_MFGORDEROPERATIONBYSEMKEY",
"I_MFGORDERTYPE",
"I_USER"
],
"BASE":
[
"P_MFGORDERDOCINFORECDOBJLINK"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/