P_PostingPeriodChangeLogRecord

DDL: P_POSTINGPERIODCHANGELOGRECORD SQL: PPOPERCHLG Type: view COMPOSITE

P_PostingPeriodChangeLogRecord is a Composite CDS View in SAP S/4HANA. It reads from 1 data source (I_ChangeDocumentItem) and exposes 18 fields with key fields ChangeDocObject, ChangeDocObjectClass, ChangeDocument, DatabaseTable, ChangeDocTableKey.

1 data source(s) 18 fields

Data Sources (1)

SourceAliasJoin Type
I_ChangeDocumentItem I_ChangeDocumentItem from

Annotations (11)

NameValueLevelField
AbapCatalog.sqlViewName PPOPERCHLG view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #NOT_REQUIRED view
ClientHandling.algorithm #SESSION_VARIABLE view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
VDM.viewType #COMPOSITE view
VDM.private true view

Fields (18)

KeyFieldSource TableSource FieldDescription
KEY ChangeDocObject ChangeDocObject
KEY ChangeDocObjectClass ChangeDocObjectClass
KEY ChangeDocument ChangeDocument
KEY DatabaseTable DatabaseTable
KEY ChangeDocTableKey ChangeDocTableKey
KEY ChangeDocDatabaseTableField ChangeDocDatabaseTableField
KEY ChangeDocItemChangeType ChangeDocItemChangeType
ChangeDocNewFieldValue ChangeDocNewFieldValue
ChangeDocPreviousFieldValue ChangeDocPreviousFieldValue
TableChangeLogDate _ChangeDocument CreationDate
TableChangeLogTime _ChangeDocument CreationTime
TableChangeLogUser _ChangeDocument CreatedByUser
SAPClient
CompanyCode
Ledger
BusinessTransactionType
FiscalYear
FiscalPeriod 
@AbapCatalog.sqlViewName: 'PPOPERCHLG'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@VDM.viewType: #COMPOSITE
@VDM.private:true
define view P_PostingPeriodChangeLogRecord
  as select from I_ChangeDocumentItem
  
{

  key ChangeDocObject,
  key ChangeDocObjectClass,

  key ChangeDocument,
  key DatabaseTable,
  key ChangeDocTableKey,
  key ChangeDocDatabaseTableField,
  key ChangeDocItemChangeType,

      ChangeDocNewFieldValue,
      ChangeDocPreviousFieldValue,
      
      _ChangeDocument.CreationDate as TableChangeLogDate,
      _ChangeDocument.CreationTime as TableChangeLogTime,
      _ChangeDocument.CreatedByUser as TableChangeLogUser,

  
  //500  880LAAAT2020001 - specific for our app Manage Posting Periods

  cast(left(ChangeDocTableKey,3) as vdm_v_sap_client) as SAPClient,
  cast(substring(ChangeDocTableKey,4,4) as bukrs) as CompanyCode,
  cast(substring(ChangeDocTableKey,8,2) as fins_ledger) as Ledger,
  cast(substring(ChangeDocTableKey,10,4) as fins_bttype) as BusinessTransactionType,
  cast(substring(ChangeDocTableKey,14,4) as gjahr) as FiscalYear,
  cast(substring(ChangeDocTableKey,18,3) as poper) as FiscalPeriod
  
}
where ChangeDocObjectClass = 'OPENPOSTGPERIOD'
  and ChangeDocDatabaseTableField = 'PERIODSTATUS';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEDOCUMENT",
"I_CHANGEDOCUMENTITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More