P_OrglChangeReportWBStoPROJ

@AbapCatalog.sqlViewName: 'POCRWBS2PRJ'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType: {
  serviceQuality: #C,
  sizeCategory : #L,
  dataClass: #MASTER
}

@VDM.private: true
@VDM.viewType: #CONSUMPTION

@EndUserText.label: 'Dependent WBS Element to Root Project'
define view P_OrglChangeReportWBStoPROJ
  as select from  I_ProfitCenterToWBSElement
  
  association [1] to I_ProfitCenterToProject as _RootProfitCenterToProject
                  on  _RootProfitCenterToProject.OrganizationalChange = $projection.OrganizationalChange
                  and _RootProfitCenterToProject.ProjectInternalID = $projection.SourceProjectInternalID
                  and _RootProfitCenterToProject.ValidityStartDate = $projection.ValidityStartDate
                                                                                    
  association [0..*] to I_OrglChgReassignmentStsText as _OrglChgReassignmentStsText 
                     on $projection.OrglChangeReassignmentStatus = _OrglChgReassignmentStsText.OrglChangeReassignmentStatus 

{
  key OrganizationalChange,
  key WBSElementInternalID,
  key ValidityStartDate,
  
    //Hierarchy fields for TreeTable Hierarchy

    cast( WBSElementInternalID as finoc_object_id ) as DependentObjectID,
    cast( 'PR' as finoc_dependent_object_type ) as OrglChgRptDependentObjectType,
    ProfitCenterDerivationSrceType as OrglChgRptRootObjectType,

    SourceProjectInternalID,
    cast( SourceProjectInternalID as finoc_object_id ) as RootObjectID,

    _WBSElement.WBSElement,
    _WBSElement.WBSElementExternalID,
    _WBSElement.WBSDescription,
    _WBSElement.WBSElement as OrglChgRptNodeDescription,

    ValidityEndDate,
    ControllingArea,
    _ControllingArea.ControllingAreaName,
    CompanyCode,
    _CompanyCode.CompanyCodeName,
    ProfitCenterBeforeOrglChange,
    _ProfitCenterBeforeOrglChange._Text[1:Language=$session.system_language].ProfitCenterName as ProfitCenterBfrOrglChangeName,
    ProfitCenter,
    _ProfitCtr._Text[1:Language=$session.system_language].ProfitCenterName,
    OrglChangeReassignmentStatus,
    _OrglChgReassignmentStsText[1:Language=$session.system_language].OrglChgReassignmentStatusName,
    ProfitCenterDerivationSrceType,

    cast( 'WBSElement' as finoc_semantic_object ) as SemanticObject,

    // root PROJECT attributes

    _RootProfitCenterToProject.ProjectInternalID              as RootProjectInternalID,
    _RootProfitCenterToProject.ValidityStartDate              as RootValidityStartDate,
    _RootProfitCenterToProject.ValidityEndDate                as RootValidityEndDate,
    _RootProfitCenterToProject.ControllingArea                as RootControllingArea,
    _RootProfitCenterToProject.CompanyCode                    as RootCompanyCode,
    _RootProfitCenterToProject.ProfitCenterBeforeOrglChange   as RootProfitCenterBeforeOrglChng,
    _RootProfitCenterToProject.ProfitCenter                   as RootProfitCenter,
    _RootProfitCenterToProject.OrganizationalChange           as RootOrganizationalChange,
    _RootProfitCenterToProject.OrglChangeReassignmentStatus   as RootOrglChangeReassignmentSts,
    _RootProfitCenterToProject._ProjectBasicData.Project,
    _RootProfitCenterToProject._ProjectBasicData.ProjectDescription

}
where
      OrganizationalChange           <> ''
  and ProfitCenterDerivationSrceType =  'PD'  //Root is Project

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_ORGLCHGREASSIGNMENTSTSTEXT",
"I_PROFITCENTER",
"I_PROFITCENTERTEXT",
"I_PROFITCENTERTOPROJECT",
"I_PROFITCENTERTOWBSELEMENT",
"I_PROJECTBASICDATA",
"I_WBSELEMENTBASICDATA"
],
"ASSOCIATED":
[
"I_ORGLCHGREASSIGNMENTSTSTEXT",
"I_PROFITCENTERTOPROJECT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/