I_ProfitCenterToProject

@AbapCatalog.sqlViewName: 'IFINOCRTPRO'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@EndUserText.label: 'Assgmt of PrftCtr to Project'
@VDM.viewType: #BASIC
@Analytics: {
  dataCategory: #DIMENSION
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #MANDATORY 
@ObjectModel.representativeKey: 'ProjectInternalID'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
  dataClass: #TRANSACTIONAL,
  serviceQuality: #C,
  sizeCategory: #L
}
@Analytics.internalName:#LOCAL


@ObjectModel:{
  supportedCapabilities: [ #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ],
  modelingPattern:  #ANALYTICAL_DIMENSION 
}
@Metadata.allowExtensions:true
define view I_ProfitCenterToProject
  as select from finoc_rt_pro
  association [1]    to I_OrglChangeReassignmentStatus as _OrglChgReassignmentStatus    on  $projection.OrglChangeReassignmentStatus = _OrglChgReassignmentStatus.OrglChangeReassignmentStatus
  association [0..1] to I_ProfitCtrDerivationSrceType  as _ProfitCtrDerivationSrceType  on  $projection.ProfitCenterDerivationSrceType = _ProfitCtrDerivationSrceType.ProfitCenterDerivationSrceType
  association [1]    to I_ProjectBasicData             as _ProjectBasicData             on  $projection.ProjectInternalID = _ProjectBasicData.ProjectInternalID
  association [0..1] to I_OrganizationalChange         as _OrglChange                   on  $projection.OrganizationalChange = _OrglChange.OrganizationalChange
  association [0..1] to I_CompanyCode                  as _CompanyCode                  on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1]    to I_ControllingArea              as _ControllingArea              on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_ProfitCenter                 as _ProfitCtr                    on  $projection.ControllingArea   =  _ProfitCtr.ControllingArea
                                                                                        and $projection.ProfitCenter      =  _ProfitCtr.ProfitCenter
                                                                                        and $projection.ValidityStartDate >= _ProfitCtr.ValidityStartDate
                                                                                        and $projection.ValidityStartDate <= _ProfitCtr.ValidityEndDate
  association [0..1] to I_ProfitCenter                 as _ProfitCenterBeforeOrglChange on  $projection.ControllingArea              =  _ProfitCenterBeforeOrglChange.ControllingArea
                                                                                        and $projection.ProfitCenterBeforeOrglChange =  _ProfitCenterBeforeOrglChange.ProfitCenter
                                                                                        and $projection.ValidityStartDate            >= _ProfitCenterBeforeOrglChange.ValidityStartDate
                                                                                        and $projection.ValidityStartDate            <= _ProfitCenterBeforeOrglChange.ValidityEndDate
{
  key cast (ps_prj_pnr as ps_s4_proj_pspnr preserving type) as ProjectInternalID,
      @Semantics.businessDate.from:true
  key valid_from                                            as ValidityStartDate,
      @Semantics.businessDate.to:true
      valid_to                                              as ValidityEndDate,
      kokrs                                                 as ControllingArea,
      bukrs                                                 as CompanyCode,
      prctr_old                                             as ProfitCenterBeforeOrglChange,
      prctr                                                 as ProfitCenter,
      orgl_change                                           as OrganizationalChange,
      reassgmt_status                                       as OrglChangeReassignmentStatus,
      prctr_drvtn_source_type                               as ProfitCenterDerivationSrceType,
      _OrglChgReassignmentStatus,
      _ProfitCtrDerivationSrceType,
      _ProjectBasicData,
      _OrglChange,
      _CompanyCode,
      _ControllingArea,
      _ProfitCtr,
      _ProfitCenterBeforeOrglChange
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FINOC_RT_PRO"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_ORGANIZATIONALCHANGE",
"I_ORGLCHANGEREASSIGNMENTSTATUS",
"I_PROFITCENTER",
"I_PROFITCTRDERIVATIONSRCETYPE",
"I_PROJECTBASICDATA"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/