P_OpActyInstanceAssembledComp2

@AbapCatalog.sqlViewName: 'PMPEOAIAMAT2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.viewType: #COMPOSITE
@VDM.private: true
define view P_OpActyInstanceAssembledComp2
  as select from P_OpActyInstanceAssembledComp as OpActyInstanceAssembledComp
    inner join   I_OpActyInstceNtwkElmntBasic  as OpActyInstceOpActyNtwkElmnt on  OpActyInstanceAssembledComp.OpActyNtwkInstance = OpActyInstceOpActyNtwkElmnt.OpActyNtwkInstance
                                                                              and OpActyInstanceAssembledComp.OpActyNtwkElement  = OpActyInstceOpActyNtwkElmnt.OpActyNtwkElement
    inner join   I_LogisticsOrderBasic         as LogisticsOrderBasic         on LogisticsOrderBasic.OrderID = OpActyInstceOpActyNtwkElmnt.ManufacturingOrder
    inner join   I_MatlPlntCompAssembleControl as MfgOrderProductPlant        on  OpActyInstanceAssembledComp.Material = MfgOrderProductPlant.Product
                                                                              and OpActyInstanceAssembledComp.Plant    = MfgOrderProductPlant.Plant
    inner join   I_OrderOperationBasic         as OrderOperationBasic         on  OrderOperationBasic.OrderInternalID          = OpActyInstceOpActyNtwkElmnt.OrderInternalID
                                                                              and OrderOperationBasic.OrderOperationInternalID = OpActyInstceOpActyNtwkElmnt.OrderOperationInternalID

  association [0..1] to I_ReservationDocumentHeader    as _Reservation                  on  $projection.Reservation = _Reservation.Reservation
  association [1..1] to I_Material                     as _Material                     on  $projection.Material = _Material.Material
  association [0..1] to I_Plant                        as _Plant                        on  $projection.Plant = _Plant.Plant
  association [0..1] to I_StorageLocation              as _StorageLocation              on  $projection.Plant           = _StorageLocation.Plant
                                                                                        and $projection.StorageLocation = _StorageLocation.StorageLocation
  association [0..*] to I_OpActyCompInstceAssignment   as _OpActyCompInstceAssignment   on  $projection.Reservation        = _OpActyCompInstceAssignment.Reservation
                                                                                        and $projection.ReservationItem    = _OpActyCompInstceAssignment.ReservationItem
                                                                                        and $projection.RecordType         = _OpActyCompInstceAssignment.RecordType
                                                                                        and $projection.OpActyNtwkInstance = _OpActyCompInstceAssignment.OpActyNtwkInstance
                                                                                        and $projection.OpActyNtwkElement  = _OpActyCompInstceAssignment.OpActyNtwkElement
  association [0..*] to I_OpActyBOOOpBOMIndivItmAssgmt as _OpActyBOOOpBOMIndivItmAssgmt on  $projection.OperationActivity           = _OpActyBOOOpBOMIndivItmAssgmt.OperationActivity
                                                                                        and $projection.OperationActyVersionCounter = _OpActyBOOOpBOMIndivItmAssgmt.OperationActyVersionCounter
                                                                                        and $projection.BillOfOperationsType        = _OpActyBOOOpBOMIndivItmAssgmt.BillOfOperationsType
                                                                                        and $projection.BillOfOperationsGroup       = _OpActyBOOOpBOMIndivItmAssgmt.BillOfOperationsGroup
                                                                                        and $projection.BOOOpBOMItemInternalID      = _OpActyBOOOpBOMIndivItmAssgmt.BOOOpBOMItemInternalID
  association [0..*] to C_MfgOrderCompAssemblyAggrgn   as _MfgOrderCompAssemblyAggrgn   on  $projection.Reservation                           = _MfgOrderCompAssemblyAggrgn.Reservation
                                                                                        and $projection.ReservationItem                       = _MfgOrderCompAssemblyAggrgn.ReservationItem
                                                                                        and $projection.RecordType                            = _MfgOrderCompAssemblyAggrgn.RecordType
                                                                                        and $projection.OpActyNtwkInstance                    = _MfgOrderCompAssemblyAggrgn.OpActyNtwkInstance
                                                                                        and $projection.OpActyNtwkElement                     = _MfgOrderCompAssemblyAggrgn.OpActyNtwkElement
                                                                                        and $projection.Material                              = _MfgOrderCompAssemblyAggrgn.Material
                                                                                        and _MfgOrderCompAssemblyAggrgn.AssemblyShopFloorItem = 0
  association [1..1] to I_MatlCompAssembleControl      as _MatlCompAssembleControl      on  $projection.MatlCompAssembleControl = _MatlCompAssembleControl.MatlCompAssembleControl

  association [0..1] to I_OrderComponent               as _OrderComponent               on  $projection.Reservation     = _OrderComponent.Reservation
                                                                                        and $projection.ReservationItem = _OrderComponent.ReservationItem
                                                                                        and $projection.RecordType      = _OrderComponent.RecordType
  association [0..1] to I_BOMItmMfgRefStrucItmAssgmt   as _BOMItmMfgRefStrucItmAssgmt   on  $projection.MfgRefStrucBOMLeafAssgmtUUID = _BOMItmMfgRefStrucItmAssgmt.MfgRefStrucBOMLeafAssgmtUUID
  association [0..1] to I_MfgRefStrucItemWithDetails   as _MfgRefStrucItemWithDetails   on  $projection.MfgRefStructureItemDetailUUID = _MfgRefStrucItemWithDetails.MfgRefStructureItemUUID
                                                                                        and $projection.MfgRefStrucItmDetIsContextual = ''
  association [0..1] to I_MfgRefHierItemWithDetails    as _MfgRefHierItemWithDetails    on  $projection.MfgRefStructureItemDetailUUID = _MfgRefHierItemWithDetails.MfgRefHierarchyItemUUID
                                                                                        and $projection.MfgRefStrucItmDetIsContextual = 'X'
{
  key OpActyInstceOpActyNtwkElmnt.OpActyNtwkInstance,
  key OpActyInstceOpActyNtwkElmnt.OpActyNtwkElement,
  key OpActyInstanceAssembledComp.Reservation,
  key OpActyInstanceAssembledComp.ReservationItem,
  key OpActyInstanceAssembledComp.RecordType,
  key OpActyInstanceAssembledComp.Material,
  key OpActyInstanceAssembledComp.Plant,
      OpActyInstanceAssembledComp.StorageLocation,
      OpActyInstanceAssembledComp.BOOOpBOMItemInternalID,
      OpActyInstanceAssembledComp.MfgOrderComponentUsageNetQty,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      cast( LogisticsOrderBasic.OrderPlannedTotalQty as esmng ) * OpActyInstanceAssembledComp.MfgOrderComponentUsageNetQty as RequiredQuantity,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      cast(case _OrderComponent.MaterialCompIsVariableSized
      -- Variable-size item: Assembly typically has to be done in PC, but base unit e.g. is square meter
          when 'X' then OpActyInstanceAssembledComp.QuantityInEntryUnit
          else OpActyInstanceAssembledComp.MaterialComponentQuantity
        end as mpe_consumed_qty preserving type)                                                                           as MaterialComponentQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      cast(OpActyInstanceAssembledComp.MaterialComponentQuantity as mpe_consumed_qty_in_base_unit preserving type)         as ResvnItmWithdrawnQtyInBaseUnit,
      @Semantics.unitOfMeasure: true
      OpActyInstanceAssembledComp.BaseUnit,
      @Semantics.unitOfMeasure: true
      OpActyInstanceAssembledComp.EntryUnit,
      OpActyInstanceAssembledComp.MatlCompIsMarkedForBackflush,
      OpActyInstanceAssembledComp.GoodsMovementIsAllowed,
      OpActyInstanceAssembledComp.MatlCompInstceAssyIsRequired,
      OpActyInstceOpActyNtwkElmnt.ManufacturingOrder,
      cast( OrderOperationBasic.Operation as mpe_vornr_char  preserving type )                                             as ManufacturingOrderOperation,
      OrderOperationBasic.OperationText                                                                                    as MfgOrderOperationText,
      OpActyInstceOpActyNtwkElmnt.OperationActivity,
      OpActyInstceOpActyNtwkElmnt.OperationActyVersionCounter,
      OpActyInstceOpActyNtwkElmnt.OpActyNtwkElementElement,
      OpActyInstceOpActyNtwkElmnt.OpActyNtwkElementElmntVersCntr,
      OpActyInstceOpActyNtwkElmnt.BillOfOperationsType,
      OpActyInstceOpActyNtwkElmnt.BillOfOperationsGroup,
      cast(case OpActyInstanceAssembledComp.MatlCompIsMarkedForBackflush
        when 'X' then 4
        else MfgOrderProductPlant.MatlCompAssembleControl
      end as mpe_comp_assemble_control preserving type )                                                                   as MatlCompAssembleControl,
      MfgOrderProductPlant.SerialNumberProfile,
      MfgOrderProductPlant.SerialNumberIsRqdForAssembly,
      MfgOrderProductPlant.IsBatchManagementRequired,
      MfgOrderProductPlant.StockCheckMessageType,
      _OrderComponent.BillOfMaterialCategory                                                                               as BillOfMaterialCategory,
      _OrderComponent.BillOfMaterialVariant                                                                                as BillOfMaterialVariant,
      _OrderComponent.BillOfMaterialVersion                                                                                as BillOfMaterialVersion,
      _OrderComponent.InheritedBOMItemNode                                                                                 as InheritedBOMItemNode,
      cast( _OrderComponent.BillOfMaterialInternalID as mpe_exec_stnum preserving type )                                   as BillOfMaterialInternalID,
      _OrderComponent.BOMItem,
      _OrderComponent.BOMItemInternalChangeCount,
      _OrderComponent.BOMItemCategory                                                                                      as BOMItemCategory,
      -- Variable-Size Item Fields
      _OrderComponent.MaterialCompIsVariableSized,
      -- _OrderComponent.VariableSizeItemUnit,
      _OrderComponent.FormulaKey,
      _OrderComponent.VariableSizeDimension1,
      _OrderComponent.VariableSizeDimension2,
      _OrderComponent.VariableSizeDimension3,
      _OrderComponent.VariableSizeDimensionUnit,
      _OrderComponent.VariableSizeComponentQuantity,
      _OrderComponent.VariableSizeComponentUnit,

      OpActyInstanceAssembledComp.MfgRefStrucBOMLeafAssgmtUUID,
      OpActyInstanceAssembledComp.MfgRefStructureItemDetailUUID,
      OpActyInstanceAssembledComp.MfgRefStrucItmDetIsContextual,

      OpActyInstceOpActyNtwkElmnt._OpActyNtwkInstance,
      OpActyInstceOpActyNtwkElmnt._OperationActivityInstance,
      OpActyInstceOpActyNtwkElmnt._OperationActivityText,
      OpActyInstceOpActyNtwkElmnt._MfgOrder,
      _Reservation,
      _Material,
      _Plant,
      _StorageLocation,
      _OpActyCompInstceAssignment,
      _OpActyBOOOpBOMIndivItmAssgmt,
      _MfgOrderCompAssemblyAggrgn,
      _MatlCompAssembleControl,
      _OrderComponent,
      _OrderComponent._BOMItemCategory,
      _BOMItmMfgRefStrucItmAssgmt,
      _MfgRefStrucItemWithDetails,
      _MfgRefHierItemWithDetails
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LOGISTICSORDERBASIC",
"I_MATLPLNTCOMPASSEMBLECONTROL",
"I_OPACTYINSTCENTWKELMNTBASIC",
"I_ORDERCOMPONENT",
"I_ORDEROPERATIONBASIC",
"P_OPACTYINSTANCEASSEMBLEDCOMP"
],
"ASSOCIATED":
[
"C_MFGORDERCOMPASSEMBLYAGGRGN",
"I_BILLOFMATERIALITEMCATEGORY",
"I_BOMITMMFGREFSTRUCITMASSGMT",
"I_MATERIAL",
"I_MATLCOMPASSEMBLECONTROL",
"I_MFGORDER",
"I_MFGREFHIERITEMWITHDETAILS",
"I_MFGREFSTRUCITEMWITHDETAILS",
"I_OPACTYBOOOPBOMINDIVITMASSGMT",
"I_OPACTYCOMPINSTCEASSIGNMENT",
"I_OPACTYNTWKINSTANCE",
"I_OPERATIONACTIVITYINSTANCE",
"I_OPERATIONACTIVITYTEXT",
"I_ORDERCOMPONENT",
"I_PLANT",
"I_RESERVATIONDOCUMENTHEADER",
"I_STORAGELOCATION"
],
"BASE":
[
"I_OPACTYINSTCENTWKELMNTBASIC",
"I_ORDERCOMPONENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/