P_MaterialDocumentItem_2

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl: {
                   authorizationCheck: #CHECK,
                   personalData.blocking: #NOT_REQUIRED
                }


@ObjectModel: {
                usageType: {
                             sizeCategory: #XXL,
                             serviceQuality: #C,
                             dataClass:#TRANSACTIONAL
                           },
                representativeKey: 'MaterialDocumentItem',
                modelingPattern: #ANALYTICAL_DIMENSION,
                supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE]
}

@Search.searchable: true

@VDM: {
        viewType: #COMPOSITE,
        private: true
      }

@Metadata: {
             ignorePropagatedAnnotations: true
           }
@EndUserText.label: 'RAP Material Document Item'
define view entity P_MaterialDocumentItem_2
  as select from I_MaterialDocumentRecord
  association [1..1] to I_MaterialDocumentYear     as _MaterialDocumentYear    on  $projection.MaterialDocumentYear = _MaterialDocumentYear.MaterialDocumentYear
  association [1..1] to I_MaterialDocumentHeader_2 as _MaterialDocumentHeader  on  $projection.MaterialDocumentYear = _MaterialDocumentHeader.MaterialDocumentYear
                                                                               and $projection.MaterialDocument     = _MaterialDocumentHeader.MaterialDocument
  association [0..1] to I_MaterialDocumentHeader_2 as _ReversedMatDoc          on  $projection.ReversedMaterialDocumentYear = _ReversedMatDoc.MaterialDocumentYear
                                                                               and $projection.ReversedMaterialDocument     = _ReversedMatDoc.MaterialDocument
  association [0..1] to I_MaterialDocumentItem_2   as _ReversedMatDocItem      on  $projection.ReversedMaterialDocumentYear = _ReversedMatDocItem.MaterialDocumentYear
                                                                               and $projection.ReversedMaterialDocument     = _ReversedMatDocItem.MaterialDocument
                                                                               and $projection.ReversedMaterialDocumentItem = _ReversedMatDocItem.MaterialDocumentItem
  association [0..1] to I_Product                  as _Product                 on  $projection.Material = _Product.Product
  association [0..1] to I_ReservationDocumentItem  as _ReservationItem         on  $projection.Reservation     = _ReservationItem.Reservation
                                                                               and $projection.ReservationItem = _ReservationItem.ReservationItem
  association [0..1] to I_GoodsMovementReasonCode  as _GoodsMovementReasonCode on  $projection.GoodsMovementType       = _GoodsMovementReasonCode.GoodsMovementType
                                                                               and $projection.GoodsMovementReasonCode = _GoodsMovementReasonCode.GoodsMovementReasonCode
{
      @ObjectModel.foreignKey.association: '_MaterialDocumentYear'
  key MaterialDocumentYear,
      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.9,
                    ranking: #HIGH
               }
      @ObjectModel.foreignKey.association: '_MaterialDocumentHeader'
  key MaterialDocument,
  key MaterialDocumentItem,
      MaterialDocumentLine,
      MaterialDocumentParentLine,
      @Consumption.hidden: true
      HierarchyNodeLevel,

      @Semantics.text: true
      MaterialDocumentItemText,

      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.7,
                    ranking: #HIGH
               }
      Material,

      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.9,
                    ranking: #HIGH
               }
      Plant,
      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.9,
                    ranking: #HIGH
               }
      StorageLocation,
      StorageType,
      StorageBin,

      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.8,
                    ranking: #MEDIUM
               }
      Batch,
      ShelfLifeExpirationDate,
      ManufactureDate,

      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.8,
                    ranking: #MEDIUM
               }
      Supplier,

      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.9,
                    ranking: #MEDIUM
               }
      SalesOrder,
      SalesOrderItem,
      SalesOrderScheduleLine,

      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.9,
                    ranking: #MEDIUM
               }

      // casting of the WBSElementInternalID to a NSDM data element to get rid of the conversion exit behind the original data element MAT_PSPNR

      // required for the Reservation RAP object which does associate this view

      cast(WBSElementInternalID as nsdm_wbselement_internal_id preserving type) as WBSElementInternalID,
      _WBSElement.WBSElement,
      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.8,
                    ranking: #MEDIUM
               }
      Customer,
      InventorySpecialStockType,
      InventoryStockType,

      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.8,
                    ranking: #MEDIUM
               }
      StockOwner,

      GoodsMovementType,
      DebitCreditCode,
      InventoryUsabilityCode,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @DefaultAggregation: #SUM
      QuantityInBaseUnit,
      @ObjectModel.foreignKey.association: '_MaterialBaseUnit'
      MaterialBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      @DefaultAggregation: #SUM
      QuantityInEntryUnit,
      @ObjectModel.foreignKey.association: '_EntryUnit'
      EntryUnit,

      @Semantics.businessDate.at: true
      PostingDate,
      @Semantics.businessDate.at: true
      DocumentDate,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      @DefaultAggregation: #SUM
      TotalGoodsMvtAmtInCCCrcy,
      @ObjectModel.foreignKey.association: '_Currency'
      CompanyCodeCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      GdsMvtExtAmtInCoCodeCrcy,
      InventoryValuationType,
      ReservationIsFinallyIssued,

      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.9,
                    ranking: #MEDIUM
                }
      PurchaseOrder,
      PurchaseOrderItem,

      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.9,
                    ranking: #MEDIUM
               }
      ProjectNetwork,

      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.9,
                    ranking: #MEDIUM
               }
      ManufacturingOrder,
      ManufacturingOrderItem,

      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.9,
                    ranking: #MEDIUM
               }
      Reservation,
      ReservationItem,

      OriginalMaterialDocumentItem,

      SpecialStockIdfgSalesOrder,
      SpecialStockIdfgSalesOrderItem,

      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.9,
                    ranking: #MEDIUM
               }
      DeliveryDocument,
      DeliveryDocumentItem,

      ReversedMaterialDocumentYear,

      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.9,
                    ranking: #MEDIUM
               }
      ReversedMaterialDocument,
      ReversedMaterialDocumentItem,

      RvslOfGoodsReceiptIsAllowed,

      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.7,
                    ranking: #MEDIUM
               }
      GoodsRecipientName,

      @Search: {
                    defaultSearchElement: true,
                    fuzzinessThreshold: 0.7,
                    ranking: #MEDIUM
               }
      UnloadingPointName,
      CostCenter,
      GLAccount,

      //Reference Document

      ReferenceDocumentFiscalYear,
      InvtryMgmtRefDocumentItem,
      InvtryMgmtReferenceDocument,

      ServicePerformer,
      PersonWorkAgreement,

      AccountAssignmentCategory,
      WorkItem,
      ServicesRenderedDate,

      //EWM Data

      EWMWarehouse,
      EWMStorageBin,

      IssgOrRcvgMaterial,
      IssuingOrReceivingPlant,
      IssuingOrReceivingStorageLoc,
      IssgOrRcvgBatch,
      IssgOrRcvgSpclStockInd,
      IssuingOrReceivingValType,

      CompanyCode,
      BusinessArea,
      ControllingArea,
      CostObject,
      ProfitabilitySegment,
      ProfitCenter,
      FunctionalArea,

      GoodsMovementIsCancelled,

      FiscalYear,
      @Semantics.fiscal.yearPeriod: true
      FiscalYearPeriod,
      @Semantics.fiscal.yearVariant: true
      FiscalYearVariant,

      GoodsMovementRefDocType,
      GoodsMovementReasonCode,

      IsCompletelyDelivered,
      @Semantics.booleanIndicator
      IsAutomaticallyCreated,

      @Consumption.hidden: true
      GoodsReceiptType,
      @Consumption.hidden: true
      ConsumptionPosting,

      @Consumption.hidden: true
      MultiAcctAssgmtOriglMatlDocItm,
      @Consumption.hidden: true
      MultipleAccountAssignmentCode,
      MaterialDocumentPostingType,
      _Product.ProductStandardID,
      SerialNumbersAreCreatedAutomly,
      _ReservationItem.EntryUnit                                                as ReservationEntryUnit,
      @Semantics.quantity.unitOfMeasure: 'ReservationEntryUnit'
      _ReservationItem.ResvnItmRequiredQtyInEntryUnit,
      _ReservationItem.BaseUnit                                                 as ReservationBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'ReservationBaseUnit'
      _ReservationItem.ResvnItmWithdrawnQtyInBaseUnit,
      //      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'

      //      MatlStkChangeQtyInBaseUnit,


      _MaterialDocumentYear,
      @ObjectModel.association.type:[#TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT]
      _MaterialDocumentHeader,

      _Material,
      _IssgOrRcvgMaterial,

      //_MATERIALSTOCKINFO,

      //search model

      _Plant,
      _IssuingOrReceivingPlant,
      _StorageLocation,
      _IssuingOrReceivingStorageLoc,

      _Supplier,
      _Customer,

      @Consumption.hidden: true
      _SupplierCompanyByPlant,
      @Consumption.hidden: true
      _CustomerCompanyByPlant,

      _BPStockOwner,

      _InventorySpecialStockType,
      _IssgOrRcvgSpclStockInd,
      _InventoryStockType,
      _InventoryValuationType,

      _GoodsMovementType,
      _GoodsMovementReasonCode,
      _DebitCreditCode,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_StockType_2'
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_StockType_2'
      _StockType,
      _StockType_2,

      _MaterialBaseUnit,
      _EntryUnit,

      _GLAccount,
      _CostCenter,

      _BusinessPartner,
      _PersonWorkAgreement,
      _AccountAssignmentCategory,
      _WorkItem,

      _ReservationItem,

      _CompanyCode,
      _BusinessArea,
      _ControllingArea,

      _SalesOrder,
      _SalesOrderItem,
      _SalesOrderScheduleLine,
      _WBSElement,

      _PurchaseOrder,
      _PurchaseOrderItem,
      _ProjectNetwork,
      _ManufacturingOrder,
      _ManufacturingOrderItem,
      _DeliveryDocument,
      _DeliveryDocumentItem,

      _ReversedMatDoc,
      _ReversedMatDocItem,
      _GoodsMvtTypeBySpclStkIndT,
      _Currency,
      _Product

}
where
  MaterialDocumentRecordType = 'MDOC'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIALDOCUMENTRECORD",
"I_PRODUCT",
"I_RESERVATIONDOCUMENTITEM",
"I_WBSELEMENTBYINTERNALKEY"
],
"ASSOCIATED":
[
"I_ACCOUNTASSIGNMENTCATEGORY",
"I_BUSINESSAREA",
"I_BUSINESSPARTNER",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_CURRENCY",
"I_CUSTOMER",
"I_CUSTOMERCOMPANYBYPLANT",
"I_DEBITCREDITCODE",
"I_DELIVERYDOCUMENT",
"I_DELIVERYDOCUMENTITEM",
"I_GLACCOUNT",
"I_GOODSMOVEMENTREASONCODE",
"I_GOODSMOVEMENTTYPE",
"I_GOODSMVTTYPEBYSPCLSTKINDT",
"I_INVENTORYSPECIALSTOCKTYPE",
"I_INVENTORYSTOCKTYPE",
"I_INVENTORYVALUATIONTYPE",
"I_MANUFACTURINGORDER",
"I_MANUFACTURINGORDERITEM",
"I_MATERIAL",
"I_MATERIALDOCUMENTHEADER_2",
"I_MATERIALDOCUMENTITEM_2",
"I_MATERIALDOCUMENTYEAR",
"I_PERSONWORKAGREEMENT_1",
"I_PLANT",
"I_PRODUCT",
"I_PROJECTNETWORK",
"I_PURCHASEORDER",
"I_PURCHASEORDERITEM",
"I_RESERVATIONDOCUMENTITEM",
"I_SALESORDER",
"I_SALESORDERITEM",
"I_SALESORDERSCHEDULELINE",
"I_STOCKTYPE",
"I_STOCKTYPE_2",
"I_STORAGELOCATION",
"I_SUPPLIER",
"I_SUPPLIERCOMPANYBYPLANT",
"I_UNITOFMEASURE",
"I_WBSELEMENTBYINTERNALKEY",
"I_WORKITEM"
],
"BASE":
[
"I_MATERIALDOCUMENTRECORD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/