P_ML_Balance_Bcf

@AbapCatalog: {
  sqlViewName: 'PMLBALBCF',
  compiler.compareFilter:true,
  preserveKey:true
}
@VDM: {
  viewType: #COMPOSITE,
  private:true
}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

define view P_ML_Balance_Bcf
  with parameters
    P_CalendarDate : calendardate

  as select from P_ML_CoCode_Ledger_BCF(P_CalendarDate : $parameters.P_CalendarDate ) as ml
    inner join   I_GLAccountLineItemRawData                                           as it on  it.CompanyCode  = ml.CompanyCode
                                                                                            and it.SourceLedger = ml.Ledger


  association [0..1] to I_MaterialValuation       as _MaterialValuation       on  _MaterialValuation.CostEstimate  = it.CostEstimate
                                                                              and _MaterialValuation.Material      = it.Product
                                                                              and _MaterialValuation.ValuationArea = it.ValuationArea

  association [0..1] to I_BusinessTransactionType as _BusinessTransactionType on  _BusinessTransactionType.BusinessTransactionType = it.BusinessTransactionType

{
  key it.CompanyCode,
  key it.SourceLedger                               as Ledger,
  key it.GLAccount,
  key it.FiscalYear,
  key it.AccountingDocument,
  key it.LedgerGLLineItem,
  key it.Product,
      @VDM.lifecycle: {
        status: #DEPRECATED,
        successor: 'Product' }
      it.Product                                    as Material,
      it.CostEstimate,
      it.ChartOfAccounts,
      it.AccountingDocumentType,
      it.ValuationArea,
      it.InventoryValuationType,
      it.FiscalPeriod,
      it.FiscalYearVariant,
      it.LedgerFiscalYear,
      it.PostingDate,
      it.PostingDate                                as MatlDocLatestPostgDate,
      it.ReferenceDocument,
      it.ReferenceDocumentType,
      it.BusinessTransactionType,
      it.DocumentDate,
      it.ProfitCenter,
      it.CostCenter,
      it.Segment,
      it.AccountingDocCreatedByUser,
      it.LastChangeDateTime,
      it.FiscalYearPeriod,
      it.PurchasingDocument,
      it.OrderID                                    as ProductionOrder,
      it.TransactionTypeDetermination,
      @VDM.lifecycle: {
        status: #DEPRECATED,
        successor: 'ProductGroup' }
      it.ProductGroup                               as MaterialGroup,
      it.ProductGroup                               as ProductGroup,
      _MaterialValuation.MaterialValuationClass     as MaterialValuationClass,
      _MaterialValuation.InventoryValuationCategory as InventoryValuationCategory,
      it.ControllingArea,
      it.Plant,
      it.MaterialLedgerProcessType,
      it.MaterialLedgerCategory,
      it.IsSupplierStockValuation,
      it.InventorySpecialStockValnType,
      it.InventorySpclStkSalesDocument,
      it.InventorySpclStkSalesDocItm,
      it.InvtrySpclStockWBSElmntIntID,
      it.InventorySpecialStockSupplier,
      ml.FromFiscalYear,
      ml.CompanyCodeCurrencyRole,
      ml.GlobalCurrencyRole,
      ml.FreeDefinedCurrency1Role,
      ml.FreeDefinedCurrency2Role,
      ml.FreeDefinedCurrency3Role,
      ml.FreeDefinedCurrency4Role,
      ml.FreeDefinedCurrency5Role,
      ml.FreeDefinedCurrency6Role,
      ml.FreeDefinedCurrency7Role,
      ml.FreeDefinedCurrency8Role,

      //----------------------------------------

      //KEY FIGURES

      //----------------------------------------

      @Semantics.currencyCode:true
      it.CompanyCodeCurrency,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      it.AmountInCompanyCodeCurrency,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      it.SlsPriceAmountInCoCodeCrcy,

      @Semantics.currencyCode:true
      it.GlobalCurrency                             as GroupCurrency,
      @Semantics: { amount : {currencyCode: 'GroupCurrency'} }
      it.AmountInGlobalCurrency                     as AmountInGroupCurrency,

      @Semantics.currencyCode:true
      it.FreeDefinedCurrency1,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
      it.AmountInFreeDefinedCurrency1,

      @Semantics.currencyCode:true
      it.FreeDefinedCurrency2,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
      it.AmountInFreeDefinedCurrency2,

      @Semantics.currencyCode:true
      it.FreeDefinedCurrency3,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
      it.AmountInFreeDefinedCurrency3,

      @Semantics.currencyCode:true
      it.FreeDefinedCurrency4,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
      it.AmountInFreeDefinedCurrency4,

      @Semantics.currencyCode:true
      it.FreeDefinedCurrency5,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
      it.AmountInFreeDefinedCurrency5,

      @Semantics.currencyCode:true
      it.FreeDefinedCurrency6,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
      it.AmountInFreeDefinedCurrency6,

      @Semantics.currencyCode:true
      it.FreeDefinedCurrency7,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
      it.AmountInFreeDefinedCurrency7,

      @Semantics.currencyCode:true
      it.FreeDefinedCurrency8,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
      it.AmountInFreeDefinedCurrency8,

      @Semantics.unitOfMeasure:true
      it.CostSourceUnit,
      @Semantics: { quantity : {unitOfMeasure: 'CostSourceUnit'} }
      it.ValuationQuantity                          as InventoryQty,

      //----------------------------------------

      //Associations

      //----------------------------------------

      it._GLAccountInChartOfAccounts,
      it._ChartOfAccounts,
      it._Segment,
      it._CompanyCode,
      it._Ledger,
      it._ProfitCenter,
      it._CostCenter,
      it._CompanyCodeCurrency,
      it._GlobalCurrency,
      it._FreeDefinedCurrency1,
      it._FreeDefinedCurrency2,
      it._FreeDefinedCurrency3,
      it._FreeDefinedCurrency4,
      it._FreeDefinedCurrency5,
      it._FreeDefinedCurrency6,
      it._FreeDefinedCurrency7,
      it._FreeDefinedCurrency8,
      it._CostSourceUnit,
      it._ControllingArea,
      it._Product,
      _BusinessTransactionType

}
where
      it.TransactionTypeDetermination = 'BSX'
  and it.CostEstimate                 > '000000000000'
  and it.GLRecordType                 = '0'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_GLACCOUNTLINEITEMRAWDATA",
"I_MATERIALVALUATION",
"P_ML_COCODE_LEDGER_BCF"
],
"ASSOCIATED":
[
"I_BUSINESSTRANSACTIONTYPE",
"I_CHARTOFACCOUNTS",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_CURRENCY",
"I_GLACCOUNTINCHARTOFACCOUNTS",
"I_LEDGER",
"I_MATERIALVALUATION",
"I_PRODUCT",
"I_PROFITCENTER",
"I_SEGMENT",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_GLACCOUNTLINEITEMRAWDATA"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/