I_MaterialValuation

@AbapCatalog.sqlViewName: 'IMATVALUATION'
@EndUserText.label: 'Material Valuation'
@VDM.viewType: #BASIC
@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'CostEstimate'
 @AbapCatalog.preserveKey:true
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@Metadata.allowExtensions:true
@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_MaterialValuation as 

select from mbew 
{
   key kaln1 as CostEstimate,
   bklas as MaterialValuationClass,
   bwtty as InventoryValuationCategory,
   matnr as Material,
   bwtar as InventoryValuationType,
   mbew.bwkey as ValuationArea,
   cast('00000000' as ps_psp_pnr) as WBSElement,
   cast('' as sobkz) as InventorySpecialStockType,
   cast('' as vbeln) as SDDocument,
   cast('000000' as posnr) as SDDocumentItem,
   cast('' as lifnr) as Supplier,
   mlast as PriceDeterminationControl
}

union all 

select from ebew 
{
   key kaln1 as CostEstimate,
   bklas as MaterialValuationClass,
   bwtty as InventoryValuationCategory,
   matnr as Material,
   bwtar as InventoryValuationType,
   ebew.bwkey as ValuationArea,
   cast('00000000' as ps_psp_pnr) as WBSElement,
   sobkz as InventorySpecialStockType,
   vbeln as SDDocument,
   posnr as SDDocumentItem,
   cast('' as lifnr) as Supplier,
   mlast as PriceDeterminationControl
}

union all

select from obew 
{
   key kaln1 as CostEstimate,
   bklas as MaterialValuationClass,
   bwtty as InventoryValuationCategory,
   matnr as Material,
   bwtar as InventoryValuationType,
   obew.bwkey as ValuationArea,
   cast('00000000' as ps_psp_pnr) as WBSElement,
   sobkz as InventorySpecialStockType,
   cast('' as vbeln) as SDDocument,
   cast('000000' as posnr) as SDDocumentItem,
   lifnr as Supplier,
   mlast as PriceDeterminationControl
}

union all

select from qbew 
{
   key kaln1 as CostEstimate,
   bklas as MaterialValuationClass,
   bwtty as InventoryValuationCategory,
   matnr as Material,
   bwtar as InventoryValuationType,
   qbew.bwkey as ValuationArea,
   pspnr as WBSElement,
   sobkz as InventorySpecialStockType,
   cast('' as vbeln) as SDDocument,
   cast('000000' as posnr) as SDDocumentItem,
   cast('' as lifnr) as Supplier,
   mlast as PriceDeterminationControl
}  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"EBEW",
"MBEW",
"OBEW",
"QBEW"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/