P_Konvd_NetPosition_Prep_Data

//@EndUserText.label: 'Vers. pricing data (stock delta records)'

@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
//@Analytics.dataCategory: #FACT

@AbapCatalog: { sqlViewName: 'PKONVDNETPOSPD',
                compiler.compareFilter: true }
@VDM: { viewType: #COMPOSITE,
        private: true }
@ObjectModel.usageType:{  sizeCategory: #XL,
                          serviceQuality: #D,
                          dataClass: #TRANSACTIONAL }

define view P_Konvd_NetPosition_Prep_Data
  with parameters
    P_MTMDataSelectionType     : cmm_vlogp_consumptiontype,
    P_DisplayView              : cds_view_uom,
    P_EndOfDaySnapshotFromDate : cmm_dend_cutdate, -- Date of snapshot to be selected
    P_EndOfDaySnapshotToDate   : cmm_dend_cutdate  -- Date of snapshot to be selected
  as select from           P_Konvd_NetDry_SelectData_TF                      as Konvd

    left outer join        I_VersionedLogisticDocument                       as Vlogp      on  Vlogp.PricingKey          = Konvd.PricingKey
                                                                                           and Vlogp.Version             = '0000000000'
                                                                                           and Vlogp.PricingDocumentItem = Konvd.PricingDocumentItem
                                                                                           and Vlogp.ConditionType       = Konvd.ConditionType
                                                                                           and Vlogp.SubConditionType    = Konvd.SubConditionType

{
  key Konvd.PricingKey,
  key Konvd.PricingDocumentItem,
  key Konvd.ConditionType,
  key Konvd.SubConditionType,
  key Konvd.VersStockRecordUUID,
      Konvd.MTMDataSourceType,
      Konvd.SourceTransactionEventDateTime,
      Konvd.SourceTransacEventEndDateTime,

      -- Parameter Columns
      cast(:P_MTMDataSelectionType as  cmm_vlogp_consumptiontype preserving type) as MTMDataSelectionType,
      cast(:P_EndOfDaySnapshotFromDate as cds_evaluation_date preserving type)    as EndOfDaySnapshotFromDate,
      cast(:P_EndOfDaySnapshotToDate as cds_evaluation_date_comp preserving type) as EndOfDaySnapshotToDate,
      cast(:P_DisplayView as cds_view_uom preserving type)                        as DisplayView,


      @Semantics.unitOfMeasure: true
      Konvd.MaterialBaseUnit,
      @Semantics.unitOfMeasure: true
      Konvd.CommodityUnit,
      @Semantics.unitOfMeasure: true
      Konvd.CmmdtyPriceExpsrMassUnit,
      @Semantics.unitOfMeasure: true
      Konvd.CmmdtyPriceExpsrVolumeUnit,

      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @DefaultAggregation:#NONE
      Konvd.CommodityQuantityInBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'CommodityUnit'
      @DefaultAggregation:#NONE
      Konvd.CommodityQuantity,
      @Semantics.quantity.unitOfMeasure: 'CmmdtyPriceExpsrMassUnit'
      @DefaultAggregation:#NONE
      Konvd.CmmdtyPriceExpsrQtyInMassUnit,
      @Semantics.quantity.unitOfMeasure: 'CmmdtyPriceExpsrVolumeUnit'
      @DefaultAggregation:#NONE
      Konvd.CmmdtyPriceExpsrQtyInVolUnit,

      @Semantics.quantity.unitOfMeasure: 'CommodityExposureUnit'
      @DefaultAggregation:#NONE
      cast(case $parameters.P_DisplayView
        when 'P' -- Physical Commodity UoM
          then Konvd.CommodityQuantity
        when 'M' -- Mass UoM
           then Konvd.CmmdtyPriceExpsrQtyInMassUnit
        when 'V' -- Volume UoM
           then Konvd.CmmdtyPriceExpsrQtyInVolUnit
        else Konvd.CommodityQuantity
      end as abap.quan( 28, 14 ))                                                 as CommodityExposureQuantity,

      @Semantics.unitOfMeasure: true
   case $parameters.P_DisplayView
         when 'P' -- Physical Commodity UoM
           then Konvd.CommodityUnit
         when 'M' -- Mass Uom
           then    Konvd.CmmdtyPriceExpsrMassUnit
         when 'V' -- Volume Uom
      then   Konvd.CmmdtyPriceExpsrVolumeUnit
         else Konvd.CommodityUnit
      end                                                     as CommodityExposureUnit,

      Konvd.QuantitySign,

      Konvd.SourceDocument,
      Konvd.SourceDocumentItem,
      Konvd.SourceDocumentYear,
      Konvd.SourceDocumentBusObjType,
      Konvd.MTMConditionGroupCategory,
      Konvd.GoodsMovementType,
      Konvd.StockRefDocument,

      Konvd.LoadDataCaptureObjectID,
      Konvd.LoadDataCaptureEventType,
      Konvd.QuantityRepositoryUUID,
      Konvd.QuantityRepositoryVersion,

      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @DefaultAggregation:#NONE
      Konvd.NetPriceExpsrQtyInBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'CommodityUnit'
      @DefaultAggregation:#NONE
      Konvd.NetPriceExpsrQuantity,

      @Semantics.quantity.unitOfMeasure: 'CmmdtyPriceExpsrMassUnit'
      @DefaultAggregation:#NONE
      Konvd.NetPriceExpsrQtyInMassUnit,
      @Semantics.quantity.unitOfMeasure: 'CmmdtyPriceExpsrVolumeUnit'
      @DefaultAggregation:#NONE
      Konvd.NetPriceExpsrQtyInVolumeUnit,

      @Semantics.quantity.unitOfMeasure: 'CommodityExposureUnit'
      @DefaultAggregation:#NONE
      case $parameters.P_DisplayView
      when 'P' then Konvd.NetPriceExpsrQuantity
      when 'M' then Konvd.NetPriceExpsrQtyInMassUnit
      when 'V' then Konvd.NetPriceExpsrQtyInVolumeUnit
      when 'p' then Konvd.NetPriceExpsrQuantity
      when 'm' then Konvd.NetPriceExpsrQtyInMassUnit
      when 'v' then Konvd.NetPriceExpsrQtyInVolumeUnit
      else Konvd.NetPriceExpsrQuantity
      end                                                                         as NetExposureQuantity,
      Konvd.DiscPremQtyScheduleUniqueID,
      Konvd.DiscPremQtyScheduleVersion,
      Konvd.RecordIsLogicallyDeleted,
      Konvd.DiscPremQtyScheduleType,
      Konvd.NetDryErrorCode,

      -- CMM_VLOGP Data
      Vlogp.Plant,
      Vlogp.Material,
      Vlogp.StorageLocation,
      Vlogp.PhysicalCommodity,
      Vlogp.CompanyCode,
      Vlogp.EndOfDayBusinessEntityKey

}
//where

//  Konvd.RecordIsLogicallyDeleted <> 'X'

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_VERSIONEDLOGISTICDOCUMENT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/