I_VERSIONEDLOGISTICDOCUMENT

@AbapCatalog.sqlViewName: 'IVLOGP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@EndUserText.label: 'Versioned pricing data of logistic docs'
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

-- Returns versioned pricing data of logistic documents (vlogp)
define view I_VersionedLogisticDocument
  as select from cmm_vlogp
{
  key pricing_key                     as PricingKey,
  key version                         as Version,
  key kposn                           as PricingDocumentItem,
  key kschl                           as ConditionType,
  key kschl_subkey                    as SubConditionType,
      record_type                     as MTMDataSourceType,
      valid_from_date                 as ValidityStartDate,
      valid_from_time                 as ValidityStartDateTime,
      valid_to_date                   as ValidityEndDate,
      valid_to_time                   as ValidityEndDateTime,
      valid_from_tst                  as SourceTransactionEventDateTime,
      valid_to_tst                    as SourceTransacEventEndDateTime,
      entity_key                      as EndOfDayBusinessEntityKey,
      entity_key_mkt                  as MarketNormBusinessEntityKey,
      period_start_mkt                as DeliveryPeriodStartDate,
      period_end_mkt                  as DeliveryPeriodEndDate,
      entity_key_sprd                 as SpreadBusinessEntityKey,
      version_max                     as MaximumVersion,
      previous_version                as PreviousVersion,
      previous_subkey                 as PrevVersionSubConditionType,

      -- Business Document
      bukrs                           as CompanyCode,
      vkorg                           as SalesOrganization,
      vtweg                           as DistributionChannel,
      spart                           as Division,
      lifnr                           as Creditor,
      kunnr                           as SoldToParty,
      matnr                           as Material,
      commodity                       as PhysicalCommodity,
      werks                           as Plant,
      lgort                           as StorageLocation,
      charg                           as Batch,
      inco1                           as IncotermsClassification,
      inco2                           as IncotermsTransferLocation,
      kappl                           as ConditionApplication,
      document                        as SourceDocument,
      document_type                   as SourceDocumentBusObjType,
      root_doc                        as OriginReferenceDocument,
      root_doc_itm                    as OriginReferenceDocumentItem,
      root_doc_type                   as OriginReferenceDocBusObjType,
      predecessor_doc                 as ReferenceDocument,
      predecessor_doc_itm             as ReferenceDocumentItem,
      predecessor_doc_type            as ReferenceDocBusObjType,
      date_delivery                   as DeliveryDate,
      date_pymnt                      as ExpectedPaymentDate,
      stwae                           as StatisticsCurrency,
      waerk                           as DocumentCurrency,
      prctr                           as ProfitCenter,
      gsber                           as BusinessArea,
      ekorg                           as PurchasingOrganization,
      matkl                           as MaterialGroup,
      inter_company                   as IsIntercompanyTransfer,

      -- Pricing
      krech                           as ConditionCalculationType,
      kbetr                           as ConditionRate,
      waers                           as ConditionCurrency,
      kpein                           as ConditionQuantity,
      kmein                           as ConditionQuantityUnit,

      -- Commodity Pricing Engine
      pricetype                       as QuotationPriceType,
      @OData.v2.amount.noDecimalShift: true
      @Semantics.amount.currencyCode: 'ConditionTermRateCurrency'
      @DefaultAggregation:#NONE
      termrate                        as ConditionTermRate,
      @Semantics.currencyCode: true
      termcurr                        as ConditionTermRateCurrency,
      case when termprun <> 0
              then termprun
              else 1
      end                             as ConditionTermRateQuantity, --n_2348958
      @Semantics.unitOfMeasure: true
      termuom                         as ConditionTermRateQuantityUnit,
      @Semantics.amount.currencyCode: 'ConditionTermValueCurrency'
      @DefaultAggregation:#NONE
      termval                         as ConditionTermValue,
      @Semantics.currencyCode: true
      termcurr                        as ConditionTermValueCurrency,
      termcurr_m                      as ConditionTermRateMktCurrency,
      termtext                        as ConditionTermName,
      termstatus                      as ConditionTermStatus,
      numdec_rate                     as RoundingDecimalPlaces,
      round_rate                      as ConditionTermRateIsRounded,
      factor_num                      as ConditionTermRateNmrtr,
      factor_denom                    as ConditionTermRateDnmntr,
      term_extension_usage            as ConditionTermExtensionUsage,
      timing                          as CmmdtyForwardIndexTiming,
      dcs_selection_type              as MaturitySelectionType,
      date_reference                  as QuotationPeriodReferenceDate,
      curve                           as CommodityCurve,

      cast(latest_eval_keydate
       as cmm_latest_eval_keydatetime
       preserving type)               as CmmdtyLtstEvalKeyDateTime,

      -- Quotations / Commodity Curve
      quotkey                         as QuotationKeyType,
      quot_timeseries_key             as QuotationDateList,
      futures_ref_timeseries          as FutureRefQuotationDateList, --n_2416345
      quotperiod_begin                as QuotationPeriodStartDate,
      quotperiod_end                  as QuotationPeriodEndDate,
      --Fixed terms may still refer to DCSID, MIC etc.
      dcsid                           as DerivativeContrSpecification,
      mic                             as MarketIdentifierCode,
      futures_ref_mic                 as FutureRefMarketIdentifierCode,
      keydate                         as MaturityKeyDate,
      contract_code                   as DerivativeContractMaturityCode,
      basis_id                        as BasisID,
      basis_type                      as BasisType,
      quotgroup                       as QuotationGroup,
      quotgroup_op                    as QuotationGroupCalculationRule,
      fixation_id                     as ConditionTermRateFixation,
      fixgroup_status                 as PricingStatus,
      rate_fix_date                   as CndnTermRateFixationDate,
      rate_fix_time                   as CndnTermRateFixationTime,
      fx_fix_date                     as CndnTermExchRateFixationDate,
      fx_fix_time                     as CndnTermExchRateFixationTime,
      date_fwd_fx_freeze              as FixedExchRateDate,
      case
        when date_fwd_fx_maturity = '00000000'
          then date_pymnt
        else
          date_fwd_fx_maturity
      end                             as ExchRateMaturityDate,

      instrument                      as MarketDataAccessKey,

      calcmin                         as MinimumConditionTermLimitRate,
      calcmax                         as MaximumConditionTermLimitRate,
      calcmmcurr                      as ConditionTermLimitRateCurrency,
      calcmmprun                      as ConditionTermLimitRateQuantity,
      calcmmuom                       as CndnTermLimitRateQuantityUnit,

      -- Miscellanous fields
      @Semantics.quantity.unitOfMeasure: 'CommodityUnit'
      @DefaultAggregation:#NONE
      commodity_adj                   as CommodityQuantity,
      @Semantics.unitOfMeasure: true
      commodity_uom                   as CommodityUnit,
      signage_qty                     as QuantitySign,
      cgroup_cat                      as MTMConditionGroupCategory,
      cgroup                          as MTMConditionGroup,
      calc_group                      as MTMCalculationGroup,
      adjustment_type                 as MTMAdjustmentType,
      kschl_m                         as MTMCalcGrpMarketPriceCondition,
      fixed                           as ConditionTermRateIsFixed,
      fixed_fx                        as ConditionTermExchRateIsFixed,
      realized                        as PriceIsRealized,
      @Semantics.quantity.unitOfMeasure: 'ConditionTermRateQuantityUnit'
      @DefaultAggregation:#NONE
      case
        when commodity_adj_in_termuom <> 0
          then commodity_adj_in_termuom
        else
          case
            when commodity_uom = termuom
              then commodity_adj
            else commodity_adj_in_termuom
          end
      end                             as CommodityQuantityInTermUnit,  --n_3048166

      keydate1_sprd                   as OldMarketNormMaturityKeyDate, --n_2416345
      keydate2_sprd                   as NewMarketNormMaturityKeyDate, --n_2416345
      inverse_fix_sprd                as FixedSpreadIsInverted,        --n_2416345

      -- PnL
      event                           as PnLEventType,
      bp_eval_period                  as PnLEvaluationPeriod,
      previous_fixed                  as PrevVersCndnTermRateIsFixed,
      previous_fixed_fx               as PrevVersCndnTrmExchRateIsFixed,
      previous_commodity_adj          as PrevVersionCommodityQuantity,
      previous_signage_qty            as PreviousVersionQuantitySign,
      previous_termrate               as PrevVersionConditionTermRate,
      previous_termcurr               as PrevVersCndnTermRateCurrency,
      previous_waerk                  as PrevVersionDocumentCurrency,
      previous_md_factor_from         as PrevVersMktToDocSrceCnvrsnFctr,
      previous_md_factor_to           as PrevVersMktDocTgtCnvrsnFctr,
      previous_ds_factor_from         as PrevVersDocStstcSrceCnvrsnFctr,
      previous_ds_factor_to           as PrevVersDocStstcTgtCnvrsnFctr,
      previous_termval                as PrevVersionConditionTermValue,
      previous_comm_adj_in_termuom    as ComparativeCmmdtyQtyInTermUnit,
      previous_fixgroup_status        as ComparativePricingStatus, --n_2391424

      -- Treasury fields
      sgsart                          as FinancialInstrumentProductType,
      sfhaart                         as FinancialInstrTransactionType,
      kontrh                          as BusinessPartner,
      ranl                            as SecurityClass,
      astueck                         as NumberOfCommodityContracts,
      posacc                          as TreasuryPositionAccount,
      rantyp                          as TreasuryContractType,
      sshlng                          as TreasuryPositionLongShortCode,
      bp_eval_prd_start               as ReferenceEvaluationKeyDate,

      keydate_selection_rout          as MaturitySelectionRoutine, -- For NearBy Key Date
      dcs_period_type                 as DCSPeriodType,
      fixgroup_status                 as CommodityPriceFixationStatus,
      tenor                           as TimeToMaturity,
      executed                        as ContrPriceExposureIsExecuted,
      dcs_reporting_date              as DCSReportingDate,
      implicit_fixation_rel           as ImplicitFixationIsRelevant, -- Implicit relevant
      previous_termfact_comb_num      as ComparCndnTermFactorNumerator, -- Implicit relevant
      previous_termfact_comb_deno     as ComparCndnTrmFctrDenominator, -- Implicit relevant
      previous_calcmin                as ComparMinCndnTermLimitRate, -- Implicit relevant
      previous_calcmax                as ComparMaxCndnTermLimitRate, -- Implicit relevant
      previous_implc_fixed            as ComparImplicitFixationIsRlvt, -- Implicit relevant
      @Semantics.quantity.unitOfMeasure: 'CmmdtyPriceExpsrMassUnit'
      commodity_mass_adj              as CmmdtyPriceExpsrQtyInMassUnit,
      @Semantics.unitOfMeasure: true
      risk_mass_uom                   as CmmdtyPriceExpsrMassUnit,
      @Semantics.quantity.unitOfMeasure: 'CmmdtyPriceExpsrVolumeUnit'
      commodity_volume_adj            as CmmdtyPriceExpsrQtyInVolUnit,
      @Semantics.unitOfMeasure: true
      risk_volume_uom                 as CmmdtyPriceExpsrVolumeUnit,
      termfactor_combrout_num         as ConditionTermFactorNumerator,
      termfactor_combrout_deno        as ConditionTermFactorDenominator,
      psmethod                       as PriceSettingMethod, 
      psmstatus                      as PriceSettingMethodStatus,
      valid_to_tst                   as ValidToDateTime,
      kalsm                          as PricingProcedure,
      termno                         as PricingConditionTerm,
      uom_comm_to_term_factor_num    as CndnCmmdtyToTrmFctrNumerator,
      uom_comm_to_term_factor_den    as CndnCmmdtyToTrmFctrDenominator,
      root_ext_number                as CmmdtyRootDocExternalNumber,
      ext_number                     as CmmdtyDocumentExternalNumber
      

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"CMM_VLOGP"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/