P_EngmntProjWrkPckgUnitKPI

@AbapCatalog.sqlViewName: 'PEPWPUNITKPI'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@VDM.private: true
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AbapCatalog.preserveKey:true
define view P_EngmntProjWrkPckgUnitKPI
  as select from I_EngmntProjAssgmtToSessionUsr as A
    inner join   I_EngmntProjectUnitDataVersion as B      on A.EngagementProject = B.EngagementProject
    inner join   I_Ledger                       as Ledger on Ledger.IsLeadingLedger = 'X'

{

      //I_EngmntProjectUnitDataVersion

  key A.EngagementProject,
  key WorkPackage,
  key A.EngagementProjFinPlanUUID,
  key WorkPackageUUID,
  key EngmtProjFinPlanVersion,
  key EngagementProjectResourceType,
  key EngagementProjectResource as WorkPackageUnit,
  key ResourceDemandUUID,
      BillingControlCategory,

      // Below fields are added to support filter pushdown in Review App

      A.EngagementProjectServiceOrg,
      A.Customer,
      A.EngmntProjReviewYearPeriod,
      A.EngagementProjectReviewStatus,
      A.EngagementProjectStage,
      A.EngagementProjectType,
      A.EngagementProjectCategory,
      A.IsMyProject,      
      A.ProjManagerUserID       as ProjectManager,
      A.ProjectManagerName,
      A.ProjectManagerExternalID,
      A.ProjAccountantUserID    as ProjectAccountant,
      A.ProjectAccountantName,
      A.ProjectAccountantExternalID,
      A.ProjControllerUserID    as ProjectController,
      A.ProjectControllerName,
      A.ProjectControllerExternalID,
      A.ProjPartnerUserID       as Projectpartner,
      A.ProjectPartnerName,
      A.ProjectPartnerExternalID,
      @Semantics.currencyCode: true
      A.Currency,
      @Semantics.unitOfMeasure: true
      UnitOfMeasure             as WorkPackageUnitUoM,

      @Semantics.quantity.unitOfMeasure:'WorkPackageUnitUoM'
      sum (PlndEffortQty)       as PlanUnitQuantity,
      EngmntProjPlanLineType,
      Ledger.Ledger,
      A.ProjectVisibility,
      A.ProjectProfileCode,
      A.EngmntProjectHeaderCompanyCode,
      A.EngagementProjectCostCenter,
      A.ProfitCenter
}
group by
  A.EngagementProject,
  WorkPackage,
  A.EngagementProjFinPlanUUID,
  WorkPackageUUID,
  EngmtProjFinPlanVersion,
  EngagementProjectResourceType,
  EngagementProjectResource,
  ResourceDemandUUID,
  BillingControlCategory,
  A.EngagementProjectServiceOrg,
  UnitOfMeasure,
  A.Currency,
  EngmntProjPlanLineType,
  A.Customer,
  A.EngmntProjReviewYearPeriod,
  A.EngagementProjectReviewStatus,
  A.EngagementProjectStage,
  A.EngagementProjectType,
  A.EngagementProjectCategory,
  A.IsMyProject, 
  A.ProjManagerUserID,
  A.ProjectManagerName,
  A.ProjectManagerExternalID,
  A.ProjAccountantUserID,
  A.ProjectAccountantName,
  A.ProjectAccountantExternalID,
  A.ProjControllerUserID,
  A.ProjectControllerName,
  A.ProjectControllerExternalID,
  A.ProjPartnerUserID,
  A.ProjectPartnerName,
  A.ProjectPartnerExternalID,
  Ledger.Ledger,
  A.ProjectVisibility,
  A.ProjectProfileCode,      
  A.EngmntProjectHeaderCompanyCode,
  A.EngagementProjectCostCenter,
  A.ProfitCenter  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ENGMNTPROJASSGMTTOSESSIONUSR",
"I_ENGMNTPROJECTUNITDATAVERSION",
"I_LEDGER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/