I_ENGMNTPROJECTUNITDATAVERSION
Engment Project Unit Data
I_ENGMNTPROJECTUNITDATAVERSION is a CDS View in S/4HANA. Engment Project Unit Data. It contains 24 fields. 4 CDS views read from this table.
CDS Views using this table (4)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_WorkPackageUnitKPI | view | from | COMPOSITE | WorkPackage Unit KPI |
| P_EngmntProjectUnitDataVersion | view | from | COMPOSITE | |
| P_EngmntProjWrkPckgUnitKPI | view | inner | COMPOSITE | |
| P_WorkPackageUnitKPI | view | inner | COMPOSITE |
Fields (24)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | EngagementProject | EngagementProject | 1 |
| KEY | EngagementProjectResource | WorkPackageUnit | 1 |
| KEY | EngagementProjectResourceType | EngagementProjectResourceType | 1 |
| KEY | EngagementProjFinPlanUUID | EngagementProjFinPlanUUID | 1 |
| KEY | EngmtProjFinPlanVersion | EngmtProjFinPlanVersion | 1 |
| KEY | ResourceDemandUUID | ResourceDemandUUID | 1 |
| KEY | WorkPackage | WorkPackage | 1 |
| KEY | WorkPackageUUID | WorkPackageUUID | 1 |
| _EngagementProject | _EngagementProject | 1 | |
| _EngagementProjectResource | _EngagementProjectResource | 1 | |
| _EngagementProjectServiceOrg | _EngagementProjectServiceOrg | 1 | |
| _EngagementProjFinancialPlan | _EngagementProjFinancialPlan | 1 | |
| _EngmntProjResourceType | _EngmntProjResourceType | 1 | |
| _EngmtProjFinPlanVersion | _EngmtProjFinPlanVersion | 1 | |
| _UnitOfMeasure | _UnitOfMeasure | 1 | |
| _WorkPackage | _WorkPackage | 1 | |
| BillingControlCategory | BillingControlCategory | 1 | |
| Currency | Currency | 1 | |
| EngagementProjectServiceOrg | EngagementProjectServiceOrg | 1 | |
| EngmntProjPlanLineType | EngmntProjPlanLineType | 1 | |
| PlndCostAmt | PlndCostAmt | 1 | |
| PlndEffortQty | PlanUnitQuantity | 1 | |
| PlndRevnAmt | PlndRevnAmt | 1 | |
| UnitOfMeasure | WorkPackageUnitUoM | 1 |
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'IEPROJUNITDATVER'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Engment Project Unit Data'
@VDM.viewType: #BASIC
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
define view I_EngmntProjectUnitDataVersion
as select from /cpd/plandata as EngagementProjectUnitData
association [0..1] to I_EngagementProject as _EngagementProject on $projection.EngagementProject = _EngagementProject.EngagementProject
association [0..1] to I_EngagementProjFinancialPlan as _EngagementProjFinancialPlan on $projection.EngagementProjFinPlanUUID = _EngagementProjFinancialPlan.EngagementProjFinPlanUUID
association [1..1] to I_WorkPackage as _WorkPackage on $projection.WorkPackage = _WorkPackage.WorkPackage
association [0..1] to I_EngmtProjFinPlanVersion as _EngmtProjFinPlanVersion on $projection.EngagementProjFinPlanUUID = _EngmtProjFinPlanVersion.EngagementProjFinPlanUUID
and $projection.EngmtProjFinPlanVersion = _EngmtProjFinPlanVersion.EngmtProjFinPlanVersion
association [0..1] to I_EngmntProjResourceType as _EngmntProjResourceType on $projection.EngagementProjectResourceType = _EngmntProjResourceType.EngagementProjectResourceType
association [0..*] to I_EngagementProjectResource as _EngagementProjectResource on $projection.EngagementProjectResource = _EngagementProjectResource.EngagementProjectResource
association [0..1] to I_Currency as _Currency on $projection.Currency = _Currency.Currency
association [0..1] to I_UnitOfMeasure as _UnitOfMeasure on $projection.UnitOfMeasure = _UnitOfMeasure.UnitOfMeasure
association [0..1] to I_EngagementProjectSrvcOrg as _EngagementProjectServiceOrg on $projection.EngagementProjectServiceOrg = _EngagementProjectServiceOrg.EngagementProjectServiceOrg
association [0..1] to I_BillingControlCategory as _BillingControlCategory on $projection.BillingControlCategory = _BillingControlCategory.BillingControlCategory
{
key EngagementProjectUnitData.plan_line_guid as PlanLineItemUUID,
key cast(EngagementProjectUnitData.mp_id as /cpd/eng_mp_id preserving type) as EngagementProject,
key EngagementProjectUnitData.wp_id as WorkPackage,
key cast(EngagementProjectUnitData.fp_key as /cpd/eng_pfp_db_key preserving type ) as EngagementProjFinPlanUUID,
key cast(EngagementProjectUnitData.wp_key as /cpd/wp_db_key preserving type ) as WorkPackageUUID,
key EngagementProjectUnitData.version as EngmtProjFinPlanVersion,
@ObjectModel.foreignKey.association: '_EngmntProjResourceType'
key EngagementProjectUnitData.res_type as EngagementProjectResourceType,
@Semantics.fiscal.period: true
key EngagementProjectUnitData.period as FiscalPeriod,
@Semantics.fiscal.year: true
key EngagementProjectUnitData.fc_year as FiscalYear,
@ObjectModel.foreignKey.association: '_EngagementProjectResource'
key EngagementProjectUnitData.resource_id as EngagementProjectResource,
key EngagementProjectUnitData.demand_key as ResourceDemandUUID,
@ObjectModel.foreignKey: {
association: '_BillingControlCategory'
}
EngagementProjectUnitData.billgctrlcat as BillingControlCategory,
@ObjectModel.foreignKey.association:'_EngagementProjectServiceOrg'
EngagementProjectUnitData.delvry_serv_org as EngagementProjectServiceOrg,
@Semantics.currencyCode: true
EngagementProjectUnitData.currency as Currency,
@Semantics.amount.currencyCode: 'Currency'
@DefaultAggregation: #SUM
EngagementProjectUnitData.cost as PlndCostAmt,
@Semantics.unitOfMeasure: true
EngagementProjectUnitData.uom as UnitOfMeasure,
@Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
@DefaultAggregation: #SUM
EngagementProjectUnitData.effort as PlndEffortQty,
@Semantics.amount.currencyCode: 'Currency'
@DefaultAggregation: #SUM
EngagementProjectUnitData.revenue as PlndRevnAmt,
EngagementProjectUnitData.line_type as EngmntProjPlanLineType,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'SupplySource'
EngagementProjectUnitData.source_of_supply as SourceOfSupply,
EngagementProjectUnitData.source_of_supply as SupplySource,
EngagementProjectUnitData.is_unit_based as IsUnitBased,
EngagementProjectUnitData.parent_unit_demand_key as ParentUnitDemandUUID,
_EngagementProject,
_EngagementProjFinancialPlan,
_EngmtProjFinPlanVersion,
_WorkPackage,
_EngmntProjResourceType,
_EngagementProjectResource,
_Currency,
_EngagementProjectServiceOrg,
_UnitOfMeasure,
_BillingControlCategory
}
where
is_draft <> 'X'
and is_unit_based = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"/CPD/PLANDATA"
],
"ASSOCIATED":
[
"I_BILLINGCONTROLCATEGORY",
"I_CURRENCY",
"I_ENGAGEMENTPROJECT",
"I_ENGAGEMENTPROJECTRESOURCE",
"I_ENGAGEMENTPROJECTSRVCORG",
"I_ENGAGEMENTPROJFINANCIALPLAN",
"I_ENGMNTPROJRESOURCETYPE",
"I_ENGMTPROJFINPLANVERSION",
"I_UNITOFMEASURE",
"I_WORKPACKAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/